src/perfetto_cmd/BUILD.gn

# Copyright (C) 2018 The Android Open Source Project
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("../../gn/perfetto.gni")
import("../../gn/proto_library.gni")

source_set("perfetto_cmd") {
  public_deps = [
    ":protos",
    "../../include/perfetto/traced",
  ]
  deps = [
    ":trigger_producer",
    "../../buildtools:protobuf_lite",
    "../../gn:default_deps",
    "../../gn:zlib_deps",
    "../../protos/perfetto/common:lite",
    "../../protos/perfetto/config:lite",
    "../android_internal:headers",
    "../base",
    "../protozero",
    "../tracing:ipc",
  ]
  sources = [
    "config.cc",
    "config.h",
    "packet_writer.cc",
    "packet_writer.h",
    "pbtxt_to_pb.cc",
    "pbtxt_to_pb.h",
    "perfetto_cmd.cc",
    "perfetto_cmd.h",
    "perfetto_config.descriptor.h",
    "rate_limiter.cc",
    "rate_limiter.h",
  ]
  if (perfetto_build_with_android) {
    deps += [ "../base:android_task_runner" ]
    libs = [
      "binder",
      "services",
      "utils",
    ]
  }
}

source_set("trigger_perfetto_cmd") {
  public_deps = [
    ":protos",
    "../../include/perfetto/traced",
  ]
  deps = [
    ":trigger_producer",
    "../../gn:default_deps",
    "../base",
    "../tracing:ipc",
  ]
  sources = [
    "trigger_perfetto.cc",
  ]
}

source_set("trigger_producer") {
  sources = [
    "trigger_producer.cc",
    "trigger_producer.h",
  ]
  deps = [
    "../../buildtools:protobuf_lite",
    "../../gn:default_deps",
    "../../protos/perfetto/config:lite",
    "../base",
    "../tracing:ipc",
  ]
}

proto_library("protos") {
  generate_python = false
  deps = []
  sources = [
    "perfetto_cmd_state.proto",
  ]
  proto_in_dir = perfetto_root_path
  proto_out_dir = perfetto_root_path
}

source_set("unittests") {
  testonly = true
  public_deps = []
  deps = [
    ":perfetto_cmd",
    "../../gn:default_deps",
    "../../gn:gtest_deps",
    "../../gn:zlib_deps",
    "../../include/perfetto/base",
    "../../protos/perfetto/config:lite",
    "../../protos/perfetto/trace:lite",
    "../protozero",
    "../tracing",
  ]
  sources = [
    "config_unittest.cc",
    "packet_writer_unittest.cc",
    "pbtxt_to_pb_unittest.cc",
    "rate_limiter_unittest.cc",
  ]
}