gn/standalone/libc++/BUILD.gn

# Copyright (C) 2017 The Android Open Source Project
#
# Licensed under the Apache License, Version 2.0 (the "License");
# you may not use this file except in compliance with the License.
# You may obtain a copy of the License at
#
#      http://www.apache.org/licenses/LICENSE-2.0
#
# Unless required by applicable law or agreed to in writing, software
# distributed under the License is distributed on an "AS IS" BASIS,
# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
# See the License for the specific language governing permissions and
# limitations under the License.

import("libc++.gni")

config("config") {
  if (use_custom_libcxx) {
    defines = [
      "_LIBCPP_DISABLE_VISIBILITY_ANNOTATIONS",
      "_LIBCXXABI_DISABLE_VISIBILITY_ANNOTATIONS",
    ]
    cflags_cc = [
      "-nostdinc++",
      "-isystem" + rebase_path("$libcxx_prefix/include", root_build_dir),
      "-isystem" + rebase_path("$libcxxabi_prefix/include", root_build_dir),
    ]

    # In theory here we want just -nostdlib++ to avoid linking both libc++ and
    # libstdc++. Unfortunately the -nostdlib++ switch is available only in
    # bleeding edge versions of clang. So, in order to get rid of libstdc++
    # we have to remove all libs and then re-add the core ones like libc.
    ldflags = [ "-nodefaultlibs" ]
    libs = [
      "c",  # libc: the core C library.
      "m",  # libm: math library.
      "dl",  # libdl: dynamic linking.
      "gcc_eh",  # gcc exception handling, required by libunwind.
    ]
  }
}

group("deps") {
  if (use_custom_libcxx) {
    public_deps = [ "//buildtools:libc++" ]
  }
}