Android.bp

//
// Copyright (C) 2022 The Android Open Source Project
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//      http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.
//

package {
    default_applicable_licenses: ["Android-Apache-2.0"],
}

cc_defaults {
    name: "dmesgd_defaults",
    cflags: [
        "-Wall",
        "-Wextra",
        "-Werror",
        "-Wno-unused-argument",
        "-Wno-unused-function",
        "-Wno-nullability-completeness",
        "-Os",
    ],
}

cc_binary {
    name: "dmesgd",
    srcs: [
        "dmesgd.cpp",
        "dmesg_parser.cpp",
    ],
    defaults: ["dmesgd_defaults"],
    shared_libs: [
        "libbase",
        "libevent",
        "liblog",
        "libservices",
        "libutils",
    ],
    init_rc: ["dmesgd.rc"],
}

cc_test {
    name: "dmesg_parser_test",
    defaults: ["dmesgd_defaults"],
    require_root: false,
    srcs: [
        "dmesg_parser.cpp",
        "dmesg_parser_test.cpp",
    ],
}