adservices/apk/build.gradle

/*
 * Copyright (C) 2022 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

repositories {
    google()
    jcenter()
}

buildscript {
    repositories {
        mavenCentral()
        google()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:7.0.4'
    }
}
apply plugin: 'com.android.application'

android {
    compileSdkVersion 30
    defaultConfig {
        targetSdkVersion 30
        minSdkVersion 30

        testInstrumentationRunner "androidx.test.runner.AndroidJUnitRunner"
    }
    sourceSets {
        main {
            manifest.srcFile 'AndroidManifest.xml'
            java.srcDirs = [
                    'java',
                    '../service-core/java',
                    '../framework/java',
                    '../../../../../external/guava/guava/src',
                    '../../../../../frameworks/base/packages/SettingsLib/' +
                            'ActionBarShadow/src',
            ]
            java.setIncludes(new HashSet([
                    'com/android/adservices/ui/**/*.java',
                    'com/android/adservices/service/consent/*.java',
                    'com/android/adservices/*.java',
                    'com/android/settingslib/widget/**/*.java',
                    'com/google/common/collect/*.java',
            ]))
            res.srcDirs = [
                    'res',
                    '../../../../../frameworks/base/packages/SettingsLib/' +
                            'SettingsTheme/res',
                    '../../../../../frameworks/base/core/res/res',
            ]
            resources.setIncludes(new HashSet([
                    'drawable/*',
                    'drawable24/*',
                    'layout/*',
                    'mipmap-*/*',
                    'values/*',
                    'xml/*',
            ]))
        }

        androidTest {
            java.srcDirs = [
                'tests/src',
                'unittest/src',
            ]
            java.setIncludes(new HashSet([
                'com/android/adservices/ui/**/*.java',
            ]))
        }
    }
    buildToolsVersion '30.0.2'
}

dependencies {
    implementation 'androidx.preference:preference:1.1.1'

    // test dependencies
    testImplementation 'junit:junit:4.+'
    androidTestImplementation 'androidx.test.espresso:espresso-contrib:3.3.0'
    androidTestImplementation 'androidx.test.ext:junit:1.1.3'
    androidTestImplementation 'androidx.test:runner:1.4.0'
    androidTestImplementation 'androidx.test:rules:1.4.0'
    androidTestImplementation 'org.mockito:mockito-core:1.10.19'
}