power-libperfmgr/Android.bp

//
// Copyright (C) 2018 The Android Open Source Project
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//      http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

package {
    default_applicable_licenses: ["Android-Apache-2.0"],
}

cc_library {
    name: "libdisppower-pixel",
    proprietary: true,
    srcs: [
        "disp-power/DisplayLowPower.cpp",
        "disp-power/InteractionHandler.cpp",
    ],
    cpp_std: "gnu++20",
    shared_libs: [
        "libbase",
        "libcutils",
        "liblog",
        "libperfmgr",
        "libutils",
    ],
}

// Deprecated, do not use
// Use pixel-power-ext for vendor extension
cc_library_headers {
    name: "pixel_power_headers",
    vendor: true,
    export_include_dirs: ["hidl"],
}

cc_test {
    name: "libadpf_test",
    defaults: ["android.hardware.power-ndk_static"],
    proprietary: true,
    vendor: true,
    require_root: true,
    srcs: [
        "aidl/tests/BackgroundWorkerTest.cpp",
        "aidl/tests/PowerHintSessionTest.cpp",
        "aidl/tests/SessionTaskMapTest.cpp",
        "aidl/tests/UClampVoterTest.cpp",
        "aidl/BackgroundWorker.cpp",
        "aidl/PowerHintSession.cpp",
        "aidl/PowerSessionManager.cpp",
        "aidl/SessionTaskMap.cpp",
        "aidl/SessionValueEntry.cpp",
        "aidl/UClampVoter.cpp",
    ],
    cpp_std: "gnu++20",
    static_libs: [
        "libgmock",
    ],
    shared_libs: [
        "liblog",
        "libbase",
        "libcutils",
        "libutils",
        "libperfmgr",
        "libbinder_ndk",
        "libprocessgroup",
        "pixel-power-ext-V1-ndk",
    ],
    test_suites: ["device-tests"],
}

cc_binary {
    name: "android.hardware.power-service.pixel-libperfmgr",
    defaults: ["android.hardware.power-ndk_shared"],
    relative_install_path: "hw",
    init_rc: ["aidl/android.hardware.power-service.pixel-libperfmgr.rc"],
    vintf_fragments: ["aidl/android.hardware.power-service.pixel.xml"],
    vendor: true,
    shared_libs: [
        "libbase",
        "libcutils",
        "liblog",
        "libutils",
        "libbinder_ndk",
        "libdisppower-pixel",
        "libperfmgr",
        "libprocessgroup",
        "pixel-power-ext-V1-ndk",
    ],
    srcs: [
        "aidl/BackgroundWorker.cpp",
        "aidl/service.cpp",
        "aidl/Power.cpp",
        "aidl/PowerExt.cpp",
        "aidl/PowerHintSession.cpp",
        "aidl/PowerSessionManager.cpp",
        "aidl/UClampVoter.cpp",
        "aidl/SessionTaskMap.cpp",
        "aidl/SessionValueEntry.cpp",
    ],
    cpp_std: "gnu++20",
}

cc_binary {
    name: "sendhint",
    defaults: ["android.hardware.power-ndk_shared"],
    vendor: true,
    shared_libs: [
        "libbase",
        "libcutils",
        "liblog",
        "libutils",
        "libbinder_ndk",
        "pixel-power-ext-V1-ndk",
    ],
    srcs: [
        "utilities/sendhint.cc",
    ],
}