lifecycle/lifecycle-runtime-compose/build.gradle

/*
 * Copyright 2022 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `createProject` gradle task (./gradlew createProject)
 *
 * Please use the task when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */


import androidx.build.PlatformIdentifier
import androidx.build.SoftwareType

plugins {
    id("AndroidXPlugin")
    id("AndroidXComposePlugin")
}

androidXMultiplatform {
    androidLibrary {
        namespace = "androidx.lifecycle.runtime.compose"
    }
    desktop()
    mingwX64()
    linux()
    mac()
    ios()
    tvos()
    watchos()
    js()
    wasmJs()

    defaultPlatform(PlatformIdentifier.ANDROID)

    sourceSets {
        commonMain.dependencies {
            api(project(":lifecycle:lifecycle-runtime"))
            api("androidx.annotation:annotation:1.9.1")
            api("androidx.compose.runtime:runtime:1.11.0")
        }

        commonTest.dependencies {
            implementation(libs.kotlinTest)
        }

        androidMain.dependencies {
            // Although this artifact is empty, it ensures that upgrading
            // `lifecycle-runtime-compose` also updates `lifecycle-runtime-ktx`
            // in cases where our constraints fail (e.g., internally in AndroidX
            // when using project dependencies).
            api(project(":lifecycle:lifecycle-runtime-ktx"))
        }

        androidDeviceTest.dependencies {
            implementation(project(":lifecycle:lifecycle-runtime-testing"))
            implementation(project(":compose:ui:ui-test"))
            implementation(project(":compose:test-utils"))
            implementation(libs.testRules)
            implementation(libs.testRunner)
            implementation(libs.kotlinTest)
            implementation(project(":kruth:kruth"))
        }

        create("nonAndroidMain").dependsOn(commonMain)
        create("nonAndroidTest").dependsOn(commonTest)

        desktopMain.dependsOn(nonAndroidMain)
        desktopTest.dependsOn(nonAndroidTest)

        nonJvmMain.dependsOn(nonAndroidMain)
        nonJvmTest.dependsOn(nonAndroidTest)
    }
}

dependencies {
    lintPublish(project(":lifecycle:lifecycle-runtime-compose-lint"))

    constraints {
        // Prevents runtime resolution failures. The reflection fallback for Compose 1.6.*
        // was removed to eliminate brittle cross-package coupling. This constraint ensures
        // the runtime provides the statically defined LocalLifecycleOwner.
        androidMainImplementation("androidx.compose.ui:ui:1.7.0") {
            because "Requires Compose 1.7+ to resolve LocalLifecycleOwner without reflection"
        }

        // Prevents symbols duplication with old versions of JetBrains' fork.
        // Starting with version 2.9.5, this module is published as empty artifact with dependency
        // to this androidx module.
        commonMainImplementation("org.jetbrains.androidx.lifecycle:lifecycle-runtime-compose:2.9.5") {
            because "prevents symbols duplication"
        }
    }
}

androidx {
    name = "Lifecycle Runtime Compose"
    type = SoftwareType.PUBLISHED_LIBRARY_ONLY_USED_BY_KOTLIN_CONSUMERS
    inceptionYear = "2021"
    description = "Compose integration with Lifecycle"
    samples(project(":lifecycle:lifecycle-runtime-compose:lifecycle-runtime-compose-samples"))
}