datastore/datastore-preferences-proto/build.gradle

/*
 * Copyright 2020 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `create_project.py` script located in the
 * `<AndroidX root>/development/project-creator` directory.
 *
 * Please use that script when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */
import androidx.build.LibraryType
import androidx.build.RunApiTasks

plugins {
    id("AndroidXPlugin")
    id("AndroidXRepackagePlugin")
    id("kotlin")
    id("com.google.protobuf")
}

repackage {
    // Must match what is in datastore/datastore-preferences-external-protobuf/build.gradle
    addRelocation {
        sourcePackage = "com.google.protobuf"
        targetPackage =  "androidx.datastore.preferences.protobuf"
    }
}

dependencies {
    api(project(":datastore:datastore-preferences-external-protobuf"))
    // Must be compileOnly to not bring in protobufLite in runtime
    // Repackaged protobufLite brought in by
    // project(":datastore:datastore-preferences-external-protobuf") and used at runtime
    compileOnly(libs.protobufLite)
    compileOnly(project(":datastore:datastore-core"))
}

protobuf {
    protoc {
        artifact = libs.protobufCompiler.get()
    }
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                java {
                    option "lite"
                }
            }
        }
    }
}

afterEvaluate {
    lint {
        lintOptions {
            // protobuf generates unannotated methods
            disable("UnknownNullness")
        }
    }
}

androidx {
    name = "Preferences DataStore Proto"
    type = LibraryType.PUBLISHED_LIBRARY
    inceptionYear = "2020"
    description = "Jarjar the generated proto for use by datastore-preferences."
    runApiTasks = new RunApiTasks.No("Metalava doesn't properly parse the proto sources " +
            "(b/180579063)")
}