sqlite/sqlite-framework/build.gradle

/*
 * Copyright (C) 2016 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `createProject` gradle task (./gradlew createProject)
 *
 * Please use the task when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */


import androidx.build.KotlinTarget
import androidx.build.PlatformIdentifier
import androidx.build.SoftwareType
import org.jetbrains.kotlin.gradle.plugin.KotlinPlatformType
import org.jetbrains.kotlin.konan.target.Family

plugins {
    id("AndroidXPlugin")
}

configurations {
    // Configuration for resolving shared archive file of androidx's SQLite compilation
    sqliteSharedArchive {
        canBeConsumed = false
        canBeResolved = true
        attributes {
            attribute(Usage.USAGE_ATTRIBUTE, objects.named(Usage, Usage.NATIVE_LINK))
        }
    }
    // Configuration for resolving SQLite sources from sqlite-bundled.
    sqliteSources {
        canBeConsumed = false
        canBeResolved = true
        attributes {
            attribute(Usage.USAGE_ATTRIBUTE, objects.named(Usage, "sqlite-amalgamation"))
        }
    }
}

androidXMultiplatform {
    androidLibrary {
        namespace = "androidx.sqlite.db.framework"
    }
    ios() {
        // Link to sqlite3 available in iOS
        binaries.configureEach {
            linkerOpts += ["-lsqlite3"]
        }
    }
    linux()
    mac()
    tvos()
    watchos()

    defaultPlatform(PlatformIdentifier.ANDROID)

    sourceSets {
        configureEach {
            if (!it.name.contains("android") && !it.name.contains("common") ) {
                // For usage of C interop APIs
                // See: https://kotlinlang.org/docs/whatsnew19.html#explicit-c-interoperability-stability-guarantees
                languageSettings.optIn("kotlinx.cinterop.ExperimentalForeignApi")
            }
        }
        commonMain.dependencies {
            api("androidx.annotation:annotation:1.8.1")
            api(project(":sqlite:sqlite"))
        }
        commonTest.dependencies {
            implementation(libs.kotlinTest)
            implementation(project(":kruth:kruth"))
        }
        androidDeviceTest.dependencies {
            implementation(libs.kotlinTestJunit)
            implementation(libs.testRunner)
            implementation(libs.testCore)
        }
        targets.configureEach { target ->
            if (target.platformType == KotlinPlatformType.native) {
                def main = target.compilations["main"]
                main.cinterops {
                    sqlite3 { cInteropSettings ->
                        includeDirs(configurations.sqliteSources.incoming.files)
                        // TODO KT-62795 We shouldn't need this dependency once that issue is fixed.
                        tasks.named(cInteropSettings.interopProcessingTaskName).configure {
                            it.dependsOn(configurations.sqliteSources)
                        }
                    }
                }

                def test = target.compilations["test"]
                if (target.konanTarget.family == Family.LINUX) {
                    // For tests in Linux host, statically include androidx's compiled SQLite
                    // via a generated C interop definition
                    createCinteropFromArchiveConfiguration(test, configurations["sqliteSharedArchive"])
                } else if (target.konanTarget.family == Family.OSX) {
                    // For tests in Mac host, link to shared SQLite library included in MacOS
                    test.kotlinOptions.freeCompilerArgs += [
                        "-linker-options", "-lsqlite3"
                    ]
                }
            }
        }
    }
}

dependencies {
    sqliteSharedArchive(project(":sqlite:sqlite-bundled"))
    sqliteSources(project(":sqlite:sqlite-bundled"))
}

androidx {
    name = "SQLite Framework Integration"
    type = SoftwareType.PUBLISHED_LIBRARY
    inceptionYear = "2017"
    description = "The implementation of SQLite library using the framework code."
}

// b/446711395
// IDE Sync only error:
// Reason: Task ':sqlite:sqlite-framework:linuxArm64TestCinterop-sqliteSharedArchiveKlib' uses this output of task ':sqlite:sqlite-framework:cinteropTestSqliteSharedArchiveLinuxArm64'
// without declaring an explicit or implicit dependency. This can lead to incorrect results being produced, depending on what order the tasks are executed.
tasks.withType(Zip).configureEach {
    if (name == "linuxX64TestCinterop-sqliteSharedArchiveKlib") {
        mustRunAfter(tasks.named("cinteropTestSqliteSharedArchiveLinuxX64"))
    }
    if (name == "linuxArm64TestCinterop-sqliteSharedArchiveKlib") {
        mustRunAfter(tasks.named("cinteropTestSqliteSharedArchiveLinuxArm64"))
    }
}