health/health-connect-client/build.gradle

/*
 * Copyright (C) 2021 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import androidx.build.BundleInsideHelper
import androidx.build.LibraryType
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("org.jetbrains.kotlin.android")
}

BundleInsideHelper.forInsideAar(
        project,
        /* from = */ "com.google.protobuf",
        /* to =   */ "androidx.health.platform.client.proto"
)

dependencies {
    api(libs.kotlinStdlib)
    // Add dependencies here
    api("androidx.activity:activity:1.2.0")
    api("androidx.annotation:annotation:1.2.0")
    bundleInside(project(
            path: ":health:health-connect-client-proto",
            configuration: "export"
    ))
    implementation(libs.guavaListenableFuture)
    implementation(libs.guavaAndroid)
    implementation(libs.kotlinCoroutinesAndroid)
    implementation(libs.kotlinCoroutinesGuava)

    testImplementation(libs.testCore)
    testImplementation(libs.testRunner)
    testImplementation(libs.junit)
    testImplementation(libs.truth)
    testImplementation(libs.kotlinCoroutinesTest)
    androidTestImplementation(libs.testRules)
    testImplementation(libs.mockitoCore)
    testImplementation(libs.robolectric)
    testImplementation(libs.testExtJunit)
    testImplementation(libs.kotlinTest)
    testImplementation(libs.espressoCore)
    testImplementation(libs.espressoIntents)

    samples(project(":health:health-connect-client-samples"))
}

android {
    defaultConfig {
        minSdkVersion 26
    }
    buildFeatures {
        aidl = true
    }
    testOptions.unitTests.includeAndroidResources = true
    namespace "androidx.health.connect.client"
}

androidx {
    name = "AndroidX Health Connect Client Library"
    type = LibraryType.PUBLISHED_LIBRARY
    mavenVersion = LibraryVersions.HEALTH_CONNECT_CLIENT
    mavenGroup = LibraryGroups.HEALTH
    inceptionYear = "2022"
    description = "read or write user's health and fitness records."
}

// Allow usage of Kotlin's @OptIn.
tasks.withType(KotlinCompile).configureEach {
    kotlinOptions {
        freeCompilerArgs += ["-opt-in=kotlin.RequiresOptIn"]
    }
}