datastore/datastore-proto/build.gradle

/*
 * Copyright (C) 2020 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

import androidx.build.dependencies.DependenciesKt
import androidx.build.LibraryGroups
import androidx.build.Publish
import androidx.build.RunApiTasks

plugins {
    id("AndroidXPlugin")
    id("com.android.library")
    id("kotlin-android")
    id("com.google.protobuf")

}

dependencies {
    api(project(":datastore:datastore-core"))
    api(libs.protobufLite)
    implementation(libs.kotlinCoroutinesCore)

    testImplementation(libs.truth)
    testImplementation(libs.junit)
    testImplementation(project(":internal-testutils-truth"))
    testImplementation(libs.kotlinCoroutinesTest)
}

protobuf {
    protoc {
        artifact = DependenciesKt.getDependencyAsString(libs.protobufCompiler)
    }
    // Generates the java proto-lite code for the protos in this project. See
    // https://github.com/google/protobuf-gradle-plugin#customizing-protobuf-compilation
    // for more information.
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                java {
                    option "lite"
                }
            }
        }
    }
}

androidx {
    name = "Android Proto DataStore"
    publish = Publish.NONE
    mavenGroup = LibraryGroups.DATASTORE
    inceptionYear = "2020"
    description = "Android Proto DataStore"
    runApiTasks = new RunApiTasks.No("Unreleased library.")
}