compiler/build.gradle

import org.gradle.internal.jvm.Jvm

/*
 * Copyright (C) 2014 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
apply plugin: 'java'
apply plugin: 'kotlin'

sourceCompatibility = dataBindingConfig.compilerJavaTargetCompatibility
targetCompatibility = dataBindingConfig.compilerJavaSourceCompatibility

sourceSets {
    main.java.srcDirs += 'src/main/kotlin'
}

buildscript {
    dependencies {
        classpath libs.apache_commons_io
        classpath libs.kotlin_gradle_plugin
    }
}

dependencies {
    compile project(':dataBinding:compilerCommon')
    compile project(':dataBinding:baseLibrary')
    compile libs.kotlin_stdlib
    compile libs.auto_common

    compile libs.apache_commons_io
    compile libs.apache_commons_codec
    compile libs.antlr4
    compile libs.juniversalchardet
    testCompile libs.junit
    testCompile libs.mockito_core
    testImplementation libs.compile_testing
    testImplementation libs.truth

    if (!Jvm.current().javaVersion.isJava9Compatible()) {
        testImplementation files(Jvm.current().getToolsJar())
    }
}

uploadArchives {
    repositories {
        mavenDeployer {
            pom.artifactId = 'compiler'
            pom.project {
                licenses {
                    license {
                        name dataBindingConfig.licenseName
                        url dataBindingConfig.licenseUrl
                        distribution dataBindingConfig.licenseDistribution
                    }
                }
            }
        }
    }
}

javadoc {
   options.addStringOption('Xdoclint:none', '-quiet')
}

archivesBaseName = "databinding-compiler"
project.ext.pomName = 'Data Binding Annotation Processor'
project.ext.pomDesc = 'The annotation processor for Data Binding. Generates binding classes for runtime.'
enablePublishing(this, true)
fullJar(project)
test.enabled = !System.getProperty("java.version").startsWith("1.6")