| dnl dolt, a replacement for libtool |
| dnl Copyright © 2007-2008 Josh Triplett <josh@freedesktop.org> |
| dnl Copying and distribution of this file, with or without modification, |
| dnl are permitted in any medium without royalty provided the copyright |
| dnl notice and this notice are preserved. |
| dnl |
| dnl To use dolt, invoke the DOLT macro immediately after the libtool macros. |
| dnl Optionally, copy this file into acinclude.m4, to avoid the need to have it |
| dnl installed when running autoconf on your project. |
| |
| AC_DEFUN([DOLT], [ |
| AC_REQUIRE([AC_CANONICAL_HOST]) |
| # dolt, a replacement for libtool |
| # Josh Triplett <josh@freedesktop.org> |
| AC_PATH_PROG(DOLT_BASH, bash) |
| AC_MSG_CHECKING([if dolt supports this host]) |
| dolt_supported=yes |
| if test x$DOLT_BASH = x; then |
| dolt_supported=no |
| fi |
| if test x$GCC != xyes; then |
| dolt_supported=no |
| fi |
| case $host in |
| i?86-*-linux*|x86_64-*-linux*|powerpc-*-linux* \ |
| |amd64-*-freebsd*|i?86-*-freebsd*|ia64-*-freebsd*) |
| pic_options='-fPIC' |
| ;; |
| i?86-apple-darwin*) |
| pic_options='-fno-common' |
| ;; |
| *mingw32*) |
| pic_options='-DDLL_EXPORT' |
| ;; |
| *) |
| dolt_supported=no |
| ;; |
| esac |
| if test x$dolt_supported = xno ; then |
| AC_MSG_RESULT([no, falling back to libtool]) |
| LTCOMPILE='$(LIBTOOL) --tag=CC $(AM_LIBTOOLFLAGS) $(LIBTOOLFLAGS) --mode=compile $(COMPILE)' |
| LTCXXCOMPILE='$(LIBTOOL) --tag=CXX $(AM_LIBTOOLFLAGS) $(LIBTOOLFLAGS) --mode=compile $(CXXCOMPILE)' |
| else |
| AC_MSG_RESULT([yes, replacing libtool]) |
| |
| dnl Start writing out doltcompile. |
| cat <<__DOLTCOMPILE__EOF__ >doltcompile |
| #!$DOLT_BASH |
| __DOLTCOMPILE__EOF__ |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| args=("$[]@") |
| for ((arg=0; arg<${#args@<:@@@:>@}; arg++)) ; do |
| if test x"${args@<:@$arg@:>@}" = x-o ; then |
| objarg=$((arg+1)) |
| break |
| fi |
| done |
| if test x$objarg = x ; then |
| echo 'Error: no -o on compiler command line' 1>&2 |
| exit 1 |
| fi |
| lo="${args@<:@$objarg@:>@}" |
| obj="${lo%.lo}" |
| if test x"$lo" = x"$obj" ; then |
| echo "Error: libtool object file name \"$lo\" does not end in .lo" 1>&2 |
| exit 1 |
| fi |
| objbase="${obj##*/}" |
| __DOLTCOMPILE__EOF__ |
| |
| dnl Write out shared compilation code. |
| if test x$enable_shared = xyes; then |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| libobjdir="${obj%$objbase}.libs" |
| if test ! -d "$libobjdir" ; then |
| mkdir_out="$(mkdir "$libobjdir" 2>&1)" |
| mkdir_ret=$? |
| if test "$mkdir_ret" -ne 0 && test ! -d "$libobjdir" ; then |
| echo "$mkdir_out" 1>&2 |
| exit $mkdir_ret |
| fi |
| fi |
| pic_object="$libobjdir/$objbase.o" |
| args@<:@$objarg@:>@="$pic_object" |
| __DOLTCOMPILE__EOF__ |
| cat <<__DOLTCOMPILE__EOF__ >>doltcompile |
| "\${args@<:@@@:>@}" $pic_options -DPIC || exit \$? |
| __DOLTCOMPILE__EOF__ |
| fi |
| |
| dnl Write out static compilation code. |
| dnl Avoid duplicate compiler output if also building shared objects. |
| if test x$enable_static = xyes; then |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| non_pic_object="$obj.o" |
| args@<:@$objarg@:>@="$non_pic_object" |
| __DOLTCOMPILE__EOF__ |
| if test x$enable_shared = xyes; then |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| "${args@<:@@@:>@}" >/dev/null 2>&1 || exit $? |
| __DOLTCOMPILE__EOF__ |
| else |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| "${args@<:@@@:>@}" || exit $? |
| __DOLTCOMPILE__EOF__ |
| fi |
| fi |
| |
| dnl Write out the code to write the .lo file. |
| dnl The second line of the .lo file must match "^# Generated by .*libtool" |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| { |
| echo "# $lo - a libtool object file" |
| echo "# Generated by doltcompile, not libtool" |
| __DOLTCOMPILE__EOF__ |
| |
| if test x$enable_shared = xyes; then |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| echo "pic_object='.libs/${objbase}.o'" |
| __DOLTCOMPILE__EOF__ |
| else |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| echo pic_object=none |
| __DOLTCOMPILE__EOF__ |
| fi |
| |
| if test x$enable_static = xyes; then |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| echo "non_pic_object='${objbase}.o'" |
| __DOLTCOMPILE__EOF__ |
| else |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| echo non_pic_object=none |
| __DOLTCOMPILE__EOF__ |
| fi |
| |
| cat <<'__DOLTCOMPILE__EOF__' >>doltcompile |
| } > "$lo" |
| __DOLTCOMPILE__EOF__ |
| |
| dnl Done writing out doltcompile; substitute it for libtool compilation. |
| chmod +x doltcompile |
| LTCOMPILE='$(top_builddir)/doltcompile $(COMPILE)' |
| LTCXXCOMPILE='$(top_builddir)/doltcompile $(CXXCOMPILE)' |
| |
| dnl automake ignores LTCOMPILE and LTCXXCOMPILE when it has separate CFLAGS for |
| dnl a target, so write out a libtool wrapper to handle that case. |
| dnl Note that doltlibtool does not handle inferred tags or option arguments |
| dnl without '=', because automake does not use them. |
| cat <<__DOLTLIBTOOL__EOF__ > doltlibtool |
| #!$DOLT_BASH |
| __DOLTLIBTOOL__EOF__ |
| cat <<'__DOLTLIBTOOL__EOF__' >>doltlibtool |
| top_builddir_slash="${0%%doltlibtool}" |
| : ${top_builddir_slash:=./} |
| args=() |
| modeok=false |
| tagok=false |
| for arg in "$[]@"; do |
| case "$arg" in |
| --mode=compile) modeok=true ;; |
| --tag=CC|--tag=CXX) tagok=true ;; |
| *) args@<:@${#args[@]}@:>@="$arg" ;; |
| esac |
| done |
| if $modeok && $tagok ; then |
| . ${top_builddir_slash}doltcompile "${args@<:@@@:>@}" |
| else |
| exec ${top_builddir_slash}libtool "$[]@" |
| fi |
| __DOLTLIBTOOL__EOF__ |
| |
| dnl Done writing out doltlibtool; substitute it for libtool. |
| chmod +x doltlibtool |
| LIBTOOL='$(top_builddir)/doltlibtool' |
| fi |
| AC_SUBST(LTCOMPILE) |
| AC_SUBST(LTCXXCOMPILE) |
| # end dolt |
| ]) |
| |
| # =========================================================================== |
| # http://autoconf-archive.cryp.to/ax_compare_version.html |
| # =========================================================================== |
| # |
| # SYNOPSIS |
| # |
| # AX_COMPARE_VERSION(VERSION_A, OP, VERSION_B, [ACTION-IF-TRUE], [ACTION-IF-FALSE]) |
| # |
| # DESCRIPTION |
| # |
| # This macro compares two version strings. Due to the various number of |
| # minor-version numbers that can exist, and the fact that string |
| # comparisons are not compatible with numeric comparisons, this is not |
| # necessarily trivial to do in a autoconf script. This macro makes doing |
| # these comparisons easy. |
| # |
| # The six basic comparisons are available, as well as checking equality |
| # limited to a certain number of minor-version levels. |
| # |
| # The operator OP determines what type of comparison to do, and can be one |
| # of: |
| # |
| # eq - equal (test A == B) |
| # ne - not equal (test A != B) |
| # le - less than or equal (test A <= B) |
| # ge - greater than or equal (test A >= B) |
| # lt - less than (test A < B) |
| # gt - greater than (test A > B) |
| # |
| # Additionally, the eq and ne operator can have a number after it to limit |
| # the test to that number of minor versions. |
| # |
| # eq0 - equal up to the length of the shorter version |
| # ne0 - not equal up to the length of the shorter version |
| # eqN - equal up to N sub-version levels |
| # neN - not equal up to N sub-version levels |
| # |
| # When the condition is true, shell commands ACTION-IF-TRUE are run, |
| # otherwise shell commands ACTION-IF-FALSE are run. The environment |
| # variable 'ax_compare_version' is always set to either 'true' or 'false' |
| # as well. |
| # |
| # Examples: |
| # |
| # AX_COMPARE_VERSION([3.15.7],[lt],[3.15.8]) |
| # AX_COMPARE_VERSION([3.15],[lt],[3.15.8]) |
| # |
| # would both be true. |
| # |
| # AX_COMPARE_VERSION([3.15.7],[eq],[3.15.8]) |
| # AX_COMPARE_VERSION([3.15],[gt],[3.15.8]) |
| # |
| # would both be false. |
| # |
| # AX_COMPARE_VERSION([3.15.7],[eq2],[3.15.8]) |
| # |
| # would be true because it is only comparing two minor versions. |
| # |
| # AX_COMPARE_VERSION([3.15.7],[eq0],[3.15]) |
| # |
| # would be true because it is only comparing the lesser number of minor |
| # versions of the two values. |
| # |
| # Note: The characters that separate the version numbers do not matter. An |
| # empty string is the same as version 0. OP is evaluated by autoconf, not |
| # configure, so must be a string, not a variable. |
| # |
| # The author would like to acknowledge Guido Draheim whose advice about |
| # the m4_case and m4_ifvaln functions make this macro only include the |
| # portions necessary to perform the specific comparison specified by the |
| # OP argument in the final configure script. |
| # |
| # LAST MODIFICATION |
| # |
| # 2008-04-12 |
| # |
| # COPYLEFT |
| # |
| # Copyright (c) 2008 Tim Toolan <toolan@ele.uri.edu> |
| # |
| # Copying and distribution of this file, with or without modification, are |
| # permitted in any medium without royalty provided the copyright notice |
| # and this notice are preserved. |
| |
| dnl ######################################################################### |
| AC_DEFUN([AX_COMPARE_VERSION], [ |
| AC_PROG_AWK |
| |
| # Used to indicate true or false condition |
| ax_compare_version=false |
| |
| # Convert the two version strings to be compared into a format that |
| # allows a simple string comparison. The end result is that a version |
| # string of the form 1.12.5-r617 will be converted to the form |
| # 0001001200050617. In other words, each number is zero padded to four |
| # digits, and non digits are removed. |
| AS_VAR_PUSHDEF([A],[ax_compare_version_A]) |
| A=`echo "$1" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \ |
| -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \ |
| -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \ |
| -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \ |
| -e 's/[[^0-9]]//g'` |
| |
| AS_VAR_PUSHDEF([B],[ax_compare_version_B]) |
| B=`echo "$3" | sed -e 's/\([[0-9]]*\)/Z\1Z/g' \ |
| -e 's/Z\([[0-9]]\)Z/Z0\1Z/g' \ |
| -e 's/Z\([[0-9]][[0-9]]\)Z/Z0\1Z/g' \ |
| -e 's/Z\([[0-9]][[0-9]][[0-9]]\)Z/Z0\1Z/g' \ |
| -e 's/[[^0-9]]//g'` |
| |
| dnl # In the case of le, ge, lt, and gt, the strings are sorted as necessary |
| dnl # then the first line is used to determine if the condition is true. |
| dnl # The sed right after the echo is to remove any indented white space. |
| m4_case(m4_tolower($2), |
| [lt],[ |
| ax_compare_version=`echo "x$A |
| x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/false/;s/x${B}/true/;1q"` |
| ], |
| [gt],[ |
| ax_compare_version=`echo "x$A |
| x$B" | sed 's/^ *//' | sort | sed "s/x${A}/false/;s/x${B}/true/;1q"` |
| ], |
| [le],[ |
| ax_compare_version=`echo "x$A |
| x$B" | sed 's/^ *//' | sort | sed "s/x${A}/true/;s/x${B}/false/;1q"` |
| ], |
| [ge],[ |
| ax_compare_version=`echo "x$A |
| x$B" | sed 's/^ *//' | sort -r | sed "s/x${A}/true/;s/x${B}/false/;1q"` |
| ],[ |
| dnl Split the operator from the subversion count if present. |
| m4_bmatch(m4_substr($2,2), |
| [0],[ |
| # A count of zero means use the length of the shorter version. |
| # Determine the number of characters in A and B. |
| ax_compare_version_len_A=`echo "$A" | $AWK '{print(length)}'` |
| ax_compare_version_len_B=`echo "$B" | $AWK '{print(length)}'` |
| |
| # Set A to no more than B's length and B to no more than A's length. |
| A=`echo "$A" | sed "s/\(.\{$ax_compare_version_len_B\}\).*/\1/"` |
| B=`echo "$B" | sed "s/\(.\{$ax_compare_version_len_A\}\).*/\1/"` |
| ], |
| [[0-9]+],[ |
| # A count greater than zero means use only that many subversions |
| A=`echo "$A" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"` |
| B=`echo "$B" | sed "s/\(\([[0-9]]\{4\}\)\{m4_substr($2,2)\}\).*/\1/"` |
| ], |
| [.+],[ |
| AC_WARNING( |
| [illegal OP numeric parameter: $2]) |
| ],[]) |
| |
| # Pad zeros at end of numbers to make same length. |
| ax_compare_version_tmp_A="$A`echo $B | sed 's/./0/g'`" |
| B="$B`echo $A | sed 's/./0/g'`" |
| A="$ax_compare_version_tmp_A" |
| |
| # Check for equality or inequality as necessary. |
| m4_case(m4_tolower(m4_substr($2,0,2)), |
| [eq],[ |
| test "x$A" = "x$B" && ax_compare_version=true |
| ], |
| [ne],[ |
| test "x$A" != "x$B" && ax_compare_version=true |
| ],[ |
| AC_WARNING([illegal OP parameter: $2]) |
| ]) |
| ]) |
| |
| AS_VAR_POPDEF([A])dnl |
| AS_VAR_POPDEF([B])dnl |
| |
| dnl # Execute ACTION-IF-TRUE / ACTION-IF-FALSE. |
| if test "$ax_compare_version" = "true" ; then |
| m4_ifvaln([$4],[$4],[:])dnl |
| m4_ifvaln([$5],[else $5])dnl |
| fi |
| ]) dnl AX_COMPARE_VERSION |
