| # Copyright 1999-2015 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI="4" |
| inherit eutils java-pkg-2 java-ant-2 |
| |
| DESCRIPTION="Netbeans Ergonomics Cluster" |
| HOMEPAGE="http://netbeans.org/" |
| SLOT="8.1" |
| SOURCE_URL="http://download.netbeans.org/netbeans/8.1/final/zip/netbeans-8.1-201510222201-src.zip" |
| SRC_URI="${SOURCE_URL} |
| http://dev.gentoo.org/~fordfrog/distfiles/netbeans-8.1-build.xml.patch.bz2" |
| LICENSE="|| ( CDDL GPL-2-with-linking-exception )" |
| KEYWORDS="~amd64 ~x86" |
| IUSE="" |
| S="${WORKDIR}" |
| |
| CDEPEND="~dev-java/netbeans-ide-${PV} |
| ~dev-java/netbeans-nb-${PV} |
| ~dev-java/netbeans-platform-${PV}" |
| DEPEND=">=virtual/jdk-1.7 |
| app-arch/unzip |
| ${CDEPEND} |
| dev-java/javahelp:0" |
| RDEPEND=">=virtual/jdk-1.7 |
| ${CDEPEND}" |
| |
| INSTALL_DIR="/usr/share/${PN}-${SLOT}" |
| |
| EANT_BUILD_XML="nbbuild/build.xml" |
| EANT_BUILD_TARGET="rebuild-cluster" |
| EANT_EXTRA_ARGS="-Drebuild.cluster.name=nb.cluster.ergonomics -Dext.binaries.downloaded=true -Dpermit.jdk8.builds=true" |
| EANT_FILTER_COMPILER="ecj-3.3 ecj-3.4 ecj-3.5 ecj-3.6 ecj-3.7" |
| JAVA_PKG_BSFIX="off" |
| |
| src_unpack() { |
| unpack $(basename ${SOURCE_URL}) |
| |
| einfo "Deleting bundled jars..." |
| find -name "*.jar" -type f -delete |
| |
| unpack netbeans-8.1-build.xml.patch.bz2 |
| } |
| |
| src_prepare() { |
| einfo "Deleting bundled class files..." |
| find -name "*.class" -type f | xargs rm -vf |
| |
| epatch netbeans-8.1-build.xml.patch |
| |
| # Support for custom patches |
| if [ -n "${NETBEANS9999_PATCHES_DIR}" -a -d "${NETBEANS9999_PATCHES_DIR}" ] ; then |
| local files=`find "${NETBEANS9999_PATCHES_DIR}" -type f` |
| |
| if [ -n "${files}" ] ; then |
| einfo "Applying custom patches:" |
| |
| for file in ${files} ; do |
| epatch "${file}" |
| done |
| fi |
| fi |
| |
| einfo "Symlinking external libraries..." |
| java-pkg_jar-from --build-only --into javahelp/external javahelp jhall.jar jhall-2.0_05.jar |
| |
| einfo "Linking in other clusters..." |
| mkdir "${S}"/nbbuild/netbeans || die |
| pushd "${S}"/nbbuild/netbeans >/dev/null || die |
| |
| ln -s /usr/share/netbeans-ide-${SLOT} ide || die |
| cat /usr/share/netbeans-ide-${SLOT}/moduleCluster.properties >> moduleCluster.properties || die |
| touch nb.cluster.ide.built |
| |
| ln -s /usr/share/netbeans-nb-${SLOT}/nb nb || die |
| cat /usr/share/netbeans-nb-${SLOT}/nb/moduleCluster.properties >> moduleCluster.properties || die |
| touch nb.cluster.nb.built |
| |
| ln -s /usr/share/netbeans-platform-${SLOT} platform || die |
| cat /usr/share/netbeans-platform-${SLOT}/moduleCluster.properties >> moduleCluster.properties || die |
| touch nb.cluster.platform.built |
| |
| popd >/dev/null || die |
| |
| java-pkg-2_src_prepare |
| } |
| |
| src_install() { |
| pushd nbbuild/netbeans/ergonomics >/dev/null || die |
| |
| insinto ${INSTALL_DIR} |
| |
| grep -E "/ergonomics$" ../moduleCluster.properties > "${D}"/${INSTALL_DIR}/moduleCluster.properties || die |
| |
| doins -r * |
| |
| popd >/dev/null || die |
| |
| dosym ${INSTALL_DIR} /usr/share/netbeans-nb-${SLOT}/ergonomics |
| } |