| # Copyright 1999-2014 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI="4" |
| |
| inherit multilib |
| if [[ ${PV} == "9999" ]] ; then |
| inherit git-2 autotools |
| EGIT_REPO_URI="git://anongit.freedesktop.org/libqmi" |
| else |
| KEYWORDS="amd64 arm ~mips x86" |
| SRC_URI="http://www.freedesktop.org/software/libqmi/${P}.tar.xz" |
| fi |
| |
| DESCRIPTION="QMI modem protocol helper library" |
| HOMEPAGE="http://cgit.freedesktop.org/libqmi/" |
| |
| LICENSE="LGPL-2" |
| SLOT="0" |
| IUSE="doc static-libs test" |
| |
| RDEPEND=">=dev-libs/glib-2.32" |
| DEPEND="${RDEPEND} |
| doc? ( dev-util/gtk-doc ) |
| virtual/pkgconfig" |
| [[ ${PV} == "9999" ]] && DEPEND+=" dev-util/gtk-doc" #469214 |
| |
| src_prepare() { |
| [[ -e configure ]] || eautoreconf |
| } |
| |
| src_configure() { |
| econf \ |
| --disable-more-warnings \ |
| $(use_enable static{-libs,}) \ |
| $(use_enable {,gtk-}doc) \ |
| $(use_with test{,s}) |
| } |
| |
| src_install() { |
| default |
| use static-libs || rm -f "${ED}"/usr/$(get_libdir)/libqmi-glib.la |
| } |
