| # Copyright 1999-2015 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI=5 |
| PYTHON_COMPAT=( python{2_7,3_3,3_4} ) |
| inherit distutils-r1 |
| |
| DESCRIPTION="Python bindings for iptables" |
| HOMEPAGE="https://github.com/ldx/python-iptables" |
| SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz" |
| |
| LICENSE="Apache-2.0" |
| SLOT="0" |
| KEYWORDS="~amd64 ~x86" |
| IUSE="doc" |
| |
| DEPEND="net-firewall/iptables |
| doc? ( dev-python/sphinx[${PYTHON_USEDEP}] )" |
| RDEPEND="${DEPEND}" |
| |
| # tests manipulate live iptables rules, so disable them by default |
| RESTRICT=test |
| |
| python_prepare_all() { |
| # Prevent un-needed d'loading during doc build |
| sed -e "s/, 'sphinx.ext.intersphinx'//" -i doc/conf.py || die |
| distutils-r1_python_prepare_all |
| } |
| |
| python_compile_all() { |
| use doc && emake -C doc html |
| } |
| |
| python_test() { |
| ${PYTHON} test.py || die "tests fail with ${EPYTHON}" |
| } |
| |
| python_install_all() { |
| use doc && local HTML_DOCS=( doc/_build/html/. ) |
| distutils-r1_python_install_all |
| } |
