| # Copyright 1999-2015 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI=5 |
| USE_RUBY="ruby19 ruby20 ruby21 ruby22" |
| |
| RUBY_FAKEGEM_TASK_DOC="" |
| RUBY_FAKEGEM_TASK_TEST="" |
| |
| RUBY_FAKEGEM_EXTRADOC="ChangeLog.rdoc AUTHORS.rdoc README.rdoc" |
| |
| inherit multilib ruby-fakegem |
| |
| DESCRIPTION="A Ruby class for processing XSLT" |
| HOMEPAGE="http://www.rubyfr.net/" |
| |
| LICENSE="GPL-2" |
| SLOT="0" |
| KEYWORDS="amd64 ~ppc64 x86" |
| IUSE="" |
| |
| DEPEND+=" >=dev-libs/libxslt-1.1.12" |
| RDEPEND+=" >=dev-libs/libxslt-1.1.12" |
| |
| all_ruby_prepare() { |
| # Remove forced -g compiler flag. |
| sed -i -e 's/-g //' ext/xslt_lib/extconf.rb || die |
| |
| # One test fails but we have installed this code already for a long |
| # time so this probably isn't a regression. No upstream bug tracker |
| # to report the problem :-( |
| sed -i -e '/test_transformation_error/,/^ end/ s:^:#:' test/test.rb || die |
| } |
| |
| each_ruby_configure() { |
| ${RUBY} -C ext/xslt_lib extconf.rb || die |
| } |
| |
| each_ruby_compile() { |
| emake -C ext/xslt_lib V=1 |
| cp ext/xslt_lib/xslt_lib$(get_modname) lib/xml/ || die |
| } |
| |
| each_ruby_test() { |
| ${RUBY} -I../lib:lib -Ctest test.rb || die |
| } |