| # Copyright 1999-2014 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI=5 |
| inherit autotools eutils user |
| |
| DESCRIPTION="Network traffic analyzer with cute web interface" |
| HOMEPAGE="http://unix4lyfe.org/darkstat/" |
| SRC_URI="http://unix4lyfe.org/${PN}/${P}.tar.bz2" |
| |
| LICENSE="GPL-2" |
| SLOT="0" |
| KEYWORDS="amd64 ppc x86" |
| |
| DEPEND="net-libs/libpcap" |
| RDEPEND="${DEPEND}" |
| |
| DARKSTAT_CHROOT_DIR=${DARKSTAT_CHROOT_DIR:-/var/lib/darkstat} |
| |
| DOCS=( AUTHORS ChangeLog README NEWS ) |
| |
| src_prepare() { |
| sed -i -e 's|-flto||g' configure.ac || die |
| epatch_user |
| eautoreconf |
| } |
| |
| src_configure() { |
| econf --disable-debug --with-privdrop-user=darkstat |
| } |
| |
| src_install() { |
| default |
| |
| newinitd "${FILESDIR}"/darkstat-initd darkstat |
| newconfd "${FILESDIR}"/darkstat-confd darkstat |
| |
| sed -i -e "s:__CHROOT__:${DARKSTAT_CHROOT_DIR}:g" "${D}"/etc/conf.d/darkstat || die |
| sed -i -e "s:__CHROOT__:${DARKSTAT_CHROOT_DIR}:g" "${D}"/etc/init.d/darkstat || die |
| |
| keepdir "${DARKSTAT_CHROOT_DIR}" |
| chown darkstat:0 "${D}${DARKSTAT_CHROOT_DIR}" |
| } |
| |
| pkg_preinst() { |
| enewuser darkstat |
| } |
| |
| pkg_postinst() { |
| # Workaround bug #141619 |
| DARKSTAT_CHROOT_DIR=`sed -n 's/^#CHROOT=\(.*\)/\1/p' "${ROOT}"etc/conf.d/darkstat` |
| chown darkstat:0 "${ROOT}${DARKSTAT_CHROOT_DIR}" |
| |
| elog "To start different darkstat instances which will listen on a different" |
| elog "interfaces create in /etc/init.d directory the 'darkstat.if' symlink to" |
| elog "darkstat script where 'if' is the name of the interface." |
| elog "Also in /etc/conf.d directory copy darkstat to darkstat.if" |
| elog "and edit it to change default values." |
| elog |
| elog "darkstat's default chroot directory is: \"${ROOT}${DARKSTAT_CHROOT_DIR}\"" |
| } |