| # Copyright 1999-2015 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI="5" |
| GST_ORG_MODULE="gst-plugins-good" |
| |
| inherit eutils flag-o-matic gstreamer |
| |
| DESCRIPTION="Basepack of plugins for GStreamer" |
| HOMEPAGE="http://gstreamer.freedesktop.org/" |
| |
| LICENSE="LGPL-2.1+" |
| KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd" |
| IUSE="+orc" |
| |
| # dtmf plugin moved from bad to good in 1.2 |
| RDEPEND=" |
| >=dev-libs/glib-2.34.3:2[${MULTILIB_USEDEP}] |
| >=media-libs/gst-plugins-base-${PV}:${SLOT}[${MULTILIB_USEDEP}] |
| >=media-libs/gstreamer-${PV}:${SLOT}[${MULTILIB_USEDEP}] |
| >=app-arch/bzip2-1.0.6-r4[${MULTILIB_USEDEP}] |
| >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] |
| orc? ( >=dev-lang/orc-0.4.17[${MULTILIB_USEDEP}] ) |
| |
| !<media-libs/gst-plugins-bad-1.1:${SLOT} |
| " |
| DEPEND="${RDEPEND} |
| >=dev-util/gtk-doc-am-1.12 |
| " |
| |
| src_prepare() { |
| # Disable test due to missing files |
| # https://bugzilla.gnome.org/show_bug.cgi?id=757087 |
| sed -e 's:\(tcase_add_test.*test_splitmuxsrc\):// \1:' \ |
| -i tests/check/elements/splitmux.c || die |
| } |
| |
| multilib_src_configure() { |
| # Always enable optional bz2 support for matroska |
| # Always enable optional zlib support for qtdemux and matroska |
| # Many media files require these to work, as some container headers are often |
| # compressed, bug #291154 |
| gstreamer_multilib_src_configure \ |
| --enable-bz2 \ |
| --enable-zlib \ |
| --disable-examples \ |
| --with-default-audiosink=autoaudiosink \ |
| --with-default-visualizer=goom |
| |
| if multilib_is_native_abi; then |
| ln -s "${S}"/docs/plugins/html docs/plugins/html || die |
| fi |
| |
| } |
| |
| multilib_src_install_all() { |
| DOCS="AUTHORS ChangeLog NEWS README RELEASE" |
| einstalldocs |
| prune_libtool_files --modules |
| } |