| # Copyright 1999-2016 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI=5 |
| |
| inherit cmake-utils systemd |
| |
| MY_PN=gsad |
| |
| DL_ID=2287 |
| |
| DESCRIPTION="Greenbone Security Assistant for openvas" |
| HOMEPAGE="http://www.openvas.org/" |
| SRC_URI="http://wald.intevation.org/frs/download.php/${DL_ID}/${P}.tar.gz" |
| |
| SLOT="0" |
| LICENSE="GPL-2+ BSD MIT" |
| KEYWORDS=" ~amd64 ~arm ~ppc ~x86" |
| IUSE="" |
| |
| RDEPEND=" |
| dev-libs/libgcrypt:0 |
| dev-libs/libxslt |
| >=net-analyzer/openvas-libraries-8.0.3 |
| net-libs/libmicrohttpd[messages]" |
| DEPEND="${RDEPEND} |
| virtual/pkgconfig" |
| |
| PATCHES=( |
| "${FILESDIR}"/${PN}-5.0.3-run.patch |
| ) |
| |
| S="${WORKDIR}"/${P} |
| |
| src_prepare() { |
| sed \ |
| -e '/^install.*OPENVAS_CACHE_DIR.*/d' \ |
| -i CMakeLists.txt || die |
| cmake-utils_src_prepare |
| } |
| |
| src_configure() { |
| local mycmakeargs=( |
| -DLOCALSTATEDIR="${EPREFIX}/var" |
| -DSYSCONFDIR="${EPREFIX}/etc" |
| ) |
| cmake-utils_src_configure |
| } |
| |
| src_install() { |
| cmake-utils_src_install |
| newinitd "${FILESDIR}"/${MY_PN}.init ${MY_PN} |
| |
| insinto /etc/openvas |
| doins "${FILESDIR}"/${MY_PN}-daemon.conf |
| dosym ../openvas/${MY_PN}-daemon.conf /etc/conf.d/${MY_PN} |
| |
| insinto /etc/logrotate.d |
| doins "${FILESDIR}"/${MY_PN}.logrotate |
| |
| systemd_newtmpfilesd "${FILESDIR}"/${MY_PN}.tmpfiles.d ${MY_PN}.conf |
| systemd_dounit "${FILESDIR}"/${MY_PN}.service |
| } |
