| # Copyright 1999-2015 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI="5" |
| GCONF_DEBUG="yes" |
| GNOME2_LA_PUNT="yes" |
| |
| inherit eutils gnome2 |
| |
| DESCRIPTION="The Eye of GNOME image viewer" |
| HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome" |
| |
| LICENSE="GPL-2+" |
| SLOT="1" |
| IUSE="+exif +introspection +jpeg lcms +svg tiff xmp" |
| KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd" |
| |
| REQUIRED_USE="exif? ( jpeg )" |
| |
| RDEPEND=" |
| >=dev-libs/glib-2.38:2 |
| >=dev-libs/libpeas-0.7.4:=[gtk] |
| >=gnome-base/gnome-desktop-2.91.2:3= |
| >=gnome-base/gsettings-desktop-schemas-2.91.92 |
| >=x11-libs/gtk+-3.14:3[introspection,X] |
| >=x11-misc/shared-mime-info-0.20 |
| |
| x11-libs/gdk-pixbuf:2[jpeg?,tiff?] |
| x11-libs/libX11 |
| |
| exif? ( >=media-libs/libexif-0.6.14 ) |
| introspection? ( >=dev-libs/gobject-introspection-0.9.3 ) |
| jpeg? ( virtual/jpeg:0 ) |
| lcms? ( media-libs/lcms:2 ) |
| svg? ( >=gnome-base/librsvg-2.36.2:2 ) |
| xmp? ( media-libs/exempi:2 ) |
| " |
| DEPEND="${RDEPEND} |
| >=dev-util/gtk-doc-am-1.16 |
| >=dev-util/intltool-0.50.1 |
| sys-devel/gettext |
| virtual/pkgconfig |
| " |
| |
| src_prepare() { |
| # https://bugzilla.gnome.org/show_bug.cgi?id=751007 |
| epatch "${FILESDIR}"/${PN}-3.16.2-without-libexif.patch |
| |
| gnome2_src_prepare |
| } |
| |
| src_configure() { |
| DOCS="AUTHORS ChangeLog HACKING MAINTAINERS NEWS README THANKS TODO" |
| gnome2_src_configure \ |
| $(use_enable introspection) \ |
| $(use_with jpeg libjpeg) \ |
| $(use_with exif libexif) \ |
| $(use_with lcms cms) \ |
| $(use_with xmp) \ |
| $(use_with svg librsvg) \ |
| ITSTOOL=$(type -P true) |
| } |