| # generated automatically by aclocal 1.16.3 -*- Autoconf -*- |
| |
| # Copyright (C) 1996-2020 Free Software Foundation, Inc. |
| |
| # This file is free software; the Free Software Foundation |
| # gives unlimited permission to copy and/or distribute it, |
| # with or without modifications, as long as this notice is preserved. |
| |
| # This program is distributed in the hope that it will be useful, |
| # but WITHOUT ANY WARRANTY, to the extent permitted by law; without |
| # even the implied warranty of MERCHANTABILITY or FITNESS FOR A |
| # PARTICULAR PURPOSE. |
| |
| m4_ifndef([AC_CONFIG_MACRO_DIRS], [m4_defun([_AM_CONFIG_MACRO_DIRS], [])m4_defun([AC_CONFIG_MACRO_DIRS], [_AM_CONFIG_MACRO_DIRS($@)])]) |
| # =========================================================================== |
| # https://www.gnu.org/software/autoconf-archive/ax_pthread.html |
| # =========================================================================== |
| # |
| # SYNOPSIS |
| # |
| # AX_PTHREAD([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]]) |
| # |
| # DESCRIPTION |
| # |
| # This macro figures out how to build C programs using POSIX threads. It |
| # sets the PTHREAD_LIBS output variable to the threads library and linker |
| # flags, and the PTHREAD_CFLAGS output variable to any special C compiler |
| # flags that are needed. (The user can also force certain compiler |
| # flags/libs to be tested by setting these environment variables.) |
| # |
| # Also sets PTHREAD_CC to any special C compiler that is needed for |
| # multi-threaded programs (defaults to the value of CC otherwise). (This |
| # is necessary on AIX to use the special cc_r compiler alias.) |
| # |
| # NOTE: You are assumed to not only compile your program with these flags, |
| # but also to link with them as well. For example, you might link with |
| # $PTHREAD_CC $CFLAGS $PTHREAD_CFLAGS $LDFLAGS ... $PTHREAD_LIBS $LIBS |
| # |
| # If you are only building threaded programs, you may wish to use these |
| # variables in your default LIBS, CFLAGS, and CC: |
| # |
| # LIBS="$PTHREAD_LIBS $LIBS" |
| # CFLAGS="$CFLAGS $PTHREAD_CFLAGS" |
| # CC="$PTHREAD_CC" |
| # |
| # In addition, if the PTHREAD_CREATE_JOINABLE thread-attribute constant |
| # has a nonstandard name, this macro defines PTHREAD_CREATE_JOINABLE to |
| # that name (e.g. PTHREAD_CREATE_UNDETACHED on AIX). |
| # |
| # Also HAVE_PTHREAD_PRIO_INHERIT is defined if pthread is found and the |
| # PTHREAD_PRIO_INHERIT symbol is defined when compiling with |
| # PTHREAD_CFLAGS. |
| # |
| # ACTION-IF-FOUND is a list of shell commands to run if a threads library |
| # is found, and ACTION-IF-NOT-FOUND is a list of commands to run it if it |
| # is not found. If ACTION-IF-FOUND is not specified, the default action |
| # will define HAVE_PTHREAD. |
| # |
| # Please let the authors know if this macro fails on any platform, or if |
| # you have any other suggestions or comments. This macro was based on work |
| # by SGJ on autoconf scripts for FFTW (http://www.fftw.org/) (with help |
| # from M. Frigo), as well as ac_pthread and hb_pthread macros posted by |
| # Alejandro Forero Cuervo to the autoconf macro repository. We are also |
| # grateful for the helpful feedback of numerous users. |
| # |
| # Updated for Autoconf 2.68 by Daniel Richard G. |
| # |
| # LICENSE |
| # |
| # Copyright (c) 2008 Steven G. Johnson <stevenj@alum.mit.edu> |
| # Copyright (c) 2011 Daniel Richard G. <skunk@iSKUNK.ORG> |
| # |
| # This program is free software: you can redistribute it and/or modify it |
| # under the terms of the GNU General Public License as published by the |
| # Free Software Foundation, either version 3 of the License, or (at your |
| # option) any later version. |
| # |
| # This program is distributed in the hope that it will be useful, but |
| # WITHOUT ANY WARRANTY; without even the implied warranty of |
| # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU General |
| # Public License for more details. |
| # |
| # You should have received a copy of the GNU General Public License along |
| # with this program. If not, see <https://www.gnu.org/licenses/>. |
| # |
| # As a special exception, the respective Autoconf Macro's copyright owner |
| # gives unlimited permission to copy, distribute and modify the configure |
| # scripts that are the output of Autoconf when processing the Macro. You |
| # need not follow the terms of the GNU General Public License when using |
| # or distributing such scripts, even though portions of the text of the |
| # Macro appear in them. The GNU General Public License (GPL) does govern |
| # all other use of the material that constitutes the Autoconf Macro. |
| # |
| # This special exception to the GPL applies to versions of the Autoconf |
| # Macro released by the Autoconf Archive. When you make and distribute a |
| # modified version of the Autoconf Macro, you may extend this special |
| # exception to the GPL to apply to your modified version as well. |
| |
| #serial 24 |
| |
| AU_ALIAS([ACX_PTHREAD], [AX_PTHREAD]) |
| AC_DEFUN([AX_PTHREAD], [ |
| AC_REQUIRE([AC_CANONICAL_HOST]) |
| AC_REQUIRE([AC_PROG_CC]) |
| AC_REQUIRE([AC_PROG_SED]) |
| AC_LANG_PUSH([C]) |
| ax_pthread_ok=no |
| |
| # We used to check for pthread.h first, but this fails if pthread.h |
| # requires special compiler flags (e.g. on Tru64 or Sequent). |
| # It gets checked for in the link test anyway. |
| |
| # First of all, check if the user has set any of the PTHREAD_LIBS, |
| # etcetera environment variables, and if threads linking works using |
| # them: |
| if test "x$PTHREAD_CFLAGS$PTHREAD_LIBS" != "x"; then |
| ax_pthread_save_CC="$CC" |
| ax_pthread_save_CFLAGS="$CFLAGS" |
| ax_pthread_save_LIBS="$LIBS" |
| AS_IF([test "x$PTHREAD_CC" != "x"], [CC="$PTHREAD_CC"]) |
| CFLAGS="$CFLAGS $PTHREAD_CFLAGS" |
| LIBS="$PTHREAD_LIBS $LIBS" |
| AC_MSG_CHECKING([for pthread_join using $CC $PTHREAD_CFLAGS $PTHREAD_LIBS]) |
| AC_LINK_IFELSE([AC_LANG_CALL([], [pthread_join])], [ax_pthread_ok=yes]) |
| AC_MSG_RESULT([$ax_pthread_ok]) |
| if test "x$ax_pthread_ok" = "xno"; then |
| PTHREAD_LIBS="" |
| PTHREAD_CFLAGS="" |
| fi |
| CC="$ax_pthread_save_CC" |
| CFLAGS="$ax_pthread_save_CFLAGS" |
| LIBS="$ax_pthread_save_LIBS" |
| fi |
| |
| # We must check for the threads library under a number of different |
| # names; the ordering is very important because some systems |
| # (e.g. DEC) have both -lpthread and -lpthreads, where one of the |
| # libraries is broken (non-POSIX). |
| |
| # Create a list of thread flags to try. Items starting with a "-" are |
| # C compiler flags, and other items are library names, except for "none" |
| # which indicates that we try without any flags at all, and "pthread-config" |
| # which is a program returning the flags for the Pth emulation library. |
| |
| ax_pthread_flags="pthreads none -Kthread -pthread -pthreads -mthreads pthread --thread-safe -mt pthread-config" |
| |
| # The ordering *is* (sometimes) important. Some notes on the |
| # individual items follow: |
| |
| # pthreads: AIX (must check this before -lpthread) |
| # none: in case threads are in libc; should be tried before -Kthread and |
| # other compiler flags to prevent continual compiler warnings |
| # -Kthread: Sequent (threads in libc, but -Kthread needed for pthread.h) |
| # -pthread: Linux/gcc (kernel threads), BSD/gcc (userland threads), Tru64 |
| # (Note: HP C rejects this with "bad form for `-t' option") |
| # -pthreads: Solaris/gcc (Note: HP C also rejects) |
| # -mt: Sun Workshop C (may only link SunOS threads [-lthread], but it |
| # doesn't hurt to check since this sometimes defines pthreads and |
| # -D_REENTRANT too), HP C (must be checked before -lpthread, which |
| # is present but should not be used directly; and before -mthreads, |
| # because the compiler interprets this as "-mt" + "-hreads") |
| # -mthreads: Mingw32/gcc, Lynx/gcc |
| # pthread: Linux, etcetera |
| # --thread-safe: KAI C++ |
| # pthread-config: use pthread-config program (for GNU Pth library) |
| |
| case $host_os in |
| |
| freebsd*) |
| |
| # -kthread: FreeBSD kernel threads (preferred to -pthread since SMP-able) |
| # lthread: LinuxThreads port on FreeBSD (also preferred to -pthread) |
| |
| ax_pthread_flags="-kthread lthread $ax_pthread_flags" |
| ;; |
| |
| hpux*) |
| |
| # From the cc(1) man page: "[-mt] Sets various -D flags to enable |
| # multi-threading and also sets -lpthread." |
| |
| ax_pthread_flags="-mt -pthread pthread $ax_pthread_flags" |
| ;; |
| |
| openedition*) |
| |
| # IBM z/OS requires a feature-test macro to be defined in order to |
| # enable POSIX threads at all, so give the user a hint if this is |
| # not set. (We don't define these ourselves, as they can affect |
| # other portions of the system API in unpredictable ways.) |
| |
| AC_EGREP_CPP([AX_PTHREAD_ZOS_MISSING], |
| [ |
| # if !defined(_OPEN_THREADS) && !defined(_UNIX03_THREADS) |
| AX_PTHREAD_ZOS_MISSING |
| # endif |
| ], |
| [AC_MSG_WARN([IBM z/OS requires -D_OPEN_THREADS or -D_UNIX03_THREADS to enable pthreads support.])]) |
| ;; |
| |
| solaris*) |
| |
| # On Solaris (at least, for some versions), libc contains stubbed |
| # (non-functional) versions of the pthreads routines, so link-based |
| # tests will erroneously succeed. (N.B.: The stubs are missing |
| # pthread_cleanup_push, or rather a function called by this macro, |
| # so we could check for that, but who knows whether they'll stub |
| # that too in a future libc.) So we'll check first for the |
| # standard Solaris way of linking pthreads (-mt -lpthread). |
| |
| ax_pthread_flags="-mt,pthread pthread $ax_pthread_flags" |
| ;; |
| esac |
| |
| # GCC generally uses -pthread, or -pthreads on some platforms (e.g. SPARC) |
| |
| AS_IF([test "x$GCC" = "xyes"], |
| [ax_pthread_flags="-pthread -pthreads $ax_pthread_flags"]) |
| |
| # The presence of a feature test macro requesting re-entrant function |
| # definitions is, on some systems, a strong hint that pthreads support is |
| # correctly enabled |
| |
| case $host_os in |
| darwin* | hpux* | linux* | osf* | solaris*) |
| ax_pthread_check_macro="_REENTRANT" |
| ;; |
| |
| aix*) |
| ax_pthread_check_macro="_THREAD_SAFE" |
| ;; |
| |
| *) |
| ax_pthread_check_macro="--" |
| ;; |
| esac |
| AS_IF([test "x$ax_pthread_check_macro" = "x--"], |
| [ax_pthread_check_cond=0], |
| [ax_pthread_check_cond="!defined($ax_pthread_check_macro)"]) |
| |
| # Are we compiling with Clang? |
| |
| AC_CACHE_CHECK([whether $CC is Clang], |
| [ax_cv_PTHREAD_CLANG], |
| [ax_cv_PTHREAD_CLANG=no |
| # Note that Autoconf sets GCC=yes for Clang as well as GCC |
| if test "x$GCC" = "xyes"; then |
| AC_EGREP_CPP([AX_PTHREAD_CC_IS_CLANG], |
| [/* Note: Clang 2.7 lacks __clang_[a-z]+__ */ |
| # if defined(__clang__) && defined(__llvm__) |
| AX_PTHREAD_CC_IS_CLANG |
| # endif |
| ], |
| [ax_cv_PTHREAD_CLANG=yes]) |
| fi |
| ]) |
| ax_pthread_clang="$ax_cv_PTHREAD_CLANG" |
| |
| ax_pthread_clang_warning=no |
| |
| # Clang needs special handling, because older versions handle the -pthread |
| # option in a rather... idiosyncratic way |
| |
| if test "x$ax_pthread_clang" = "xyes"; then |
| |
| # Clang takes -pthread; it has never supported any other flag |
| |
| # (Note 1: This will need to be revisited if a system that Clang |
| # supports has POSIX threads in a separate library. This tends not |
| # to be the way of modern systems, but it's conceivable.) |
| |
| # (Note 2: On some systems, notably Darwin, -pthread is not needed |
| # to get POSIX threads support; the API is always present and |
| # active. We could reasonably leave PTHREAD_CFLAGS empty. But |
| # -pthread does define _REENTRANT, and while the Darwin headers |
| # ignore this macro, third-party headers might not.) |
| |
| PTHREAD_CFLAGS="-pthread" |
| PTHREAD_LIBS= |
| |
| ax_pthread_ok=yes |
| |
| # However, older versions of Clang make a point of warning the user |
| # that, in an invocation where only linking and no compilation is |
| # taking place, the -pthread option has no effect ("argument unused |
| # during compilation"). They expect -pthread to be passed in only |
| # when source code is being compiled. |
| # |
| # Problem is, this is at odds with the way Automake and most other |
| # C build frameworks function, which is that the same flags used in |
| # compilation (CFLAGS) are also used in linking. Many systems |
| # supported by AX_PTHREAD require exactly this for POSIX threads |
| # support, and in fact it is often not straightforward to specify a |
| # flag that is used only in the compilation phase and not in |
| # linking. Such a scenario is extremely rare in practice. |
| # |
| # Even though use of the -pthread flag in linking would only print |
| # a warning, this can be a nuisance for well-run software projects |
| # that build with -Werror. So if the active version of Clang has |
| # this misfeature, we search for an option to squash it. |
| |
| AC_CACHE_CHECK([whether Clang needs flag to prevent "argument unused" warning when linking with -pthread], |
| [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG], |
| [ax_cv_PTHREAD_CLANG_NO_WARN_FLAG=unknown |
| # Create an alternate version of $ac_link that compiles and |
| # links in two steps (.c -> .o, .o -> exe) instead of one |
| # (.c -> exe), because the warning occurs only in the second |
| # step |
| ax_pthread_save_ac_link="$ac_link" |
| ax_pthread_sed='s/conftest\.\$ac_ext/conftest.$ac_objext/g' |
| ax_pthread_link_step=`$as_echo "$ac_link" | sed "$ax_pthread_sed"` |
| ax_pthread_2step_ac_link="($ac_compile) && (echo ==== >&5) && ($ax_pthread_link_step)" |
| ax_pthread_save_CFLAGS="$CFLAGS" |
| for ax_pthread_try in '' -Qunused-arguments -Wno-unused-command-line-argument unknown; do |
| AS_IF([test "x$ax_pthread_try" = "xunknown"], [break]) |
| CFLAGS="-Werror -Wunknown-warning-option $ax_pthread_try -pthread $ax_pthread_save_CFLAGS" |
| ac_link="$ax_pthread_save_ac_link" |
| AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])], |
| [ac_link="$ax_pthread_2step_ac_link" |
| AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(void){return 0;}]])], |
| [break]) |
| ]) |
| done |
| ac_link="$ax_pthread_save_ac_link" |
| CFLAGS="$ax_pthread_save_CFLAGS" |
| AS_IF([test "x$ax_pthread_try" = "x"], [ax_pthread_try=no]) |
| ax_cv_PTHREAD_CLANG_NO_WARN_FLAG="$ax_pthread_try" |
| ]) |
| |
| case "$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG" in |
| no | unknown) ;; |
| *) PTHREAD_CFLAGS="$ax_cv_PTHREAD_CLANG_NO_WARN_FLAG $PTHREAD_CFLAGS" ;; |
| esac |
| |
| fi # $ax_pthread_clang = yes |
| |
| if test "x$ax_pthread_ok" = "xno"; then |
| for ax_pthread_try_flag in $ax_pthread_flags; do |
| |
| case $ax_pthread_try_flag in |
| none) |
| AC_MSG_CHECKING([whether pthreads work without any flags]) |
| ;; |
| |
| -mt,pthread) |
| AC_MSG_CHECKING([whether pthreads work with -mt -lpthread]) |
| PTHREAD_CFLAGS="-mt" |
| PTHREAD_LIBS="-lpthread" |
| ;; |
| |
| -*) |
| AC_MSG_CHECKING([whether pthreads work with $ax_pthread_try_flag]) |
| PTHREAD_CFLAGS="$ax_pthread_try_flag" |
| ;; |
| |
| pthread-config) |
| AC_CHECK_PROG([ax_pthread_config], [pthread-config], [yes], [no]) |
| AS_IF([test "x$ax_pthread_config" = "xno"], [continue]) |
| PTHREAD_CFLAGS="`pthread-config --cflags`" |
| PTHREAD_LIBS="`pthread-config --ldflags` `pthread-config --libs`" |
| ;; |
| |
| *) |
| AC_MSG_CHECKING([for the pthreads library -l$ax_pthread_try_flag]) |
| PTHREAD_LIBS="-l$ax_pthread_try_flag" |
| ;; |
| esac |
| |
| ax_pthread_save_CFLAGS="$CFLAGS" |
| ax_pthread_save_LIBS="$LIBS" |
| CFLAGS="$CFLAGS $PTHREAD_CFLAGS" |
| LIBS="$PTHREAD_LIBS $LIBS" |
| |
| # Check for various functions. We must include pthread.h, |
| # since some functions may be macros. (On the Sequent, we |
| # need a special flag -Kthread to make this header compile.) |
| # We check for pthread_join because it is in -lpthread on IRIX |
| # while pthread_create is in libc. We check for pthread_attr_init |
| # due to DEC craziness with -lpthreads. We check for |
| # pthread_cleanup_push because it is one of the few pthread |
| # functions on Solaris that doesn't have a non-functional libc stub. |
| # We try pthread_create on general principles. |
| |
| AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h> |
| # if $ax_pthread_check_cond |
| # error "$ax_pthread_check_macro must be defined" |
| # endif |
| static void routine(void *a) { a = 0; } |
| static void *start_routine(void *a) { return a; }], |
| [pthread_t th; pthread_attr_t attr; |
| pthread_create(&th, 0, start_routine, 0); |
| pthread_join(th, 0); |
| pthread_attr_init(&attr); |
| pthread_cleanup_push(routine, 0); |
| pthread_cleanup_pop(0) /* ; */])], |
| [ax_pthread_ok=yes], |
| []) |
| |
| CFLAGS="$ax_pthread_save_CFLAGS" |
| LIBS="$ax_pthread_save_LIBS" |
| |
| AC_MSG_RESULT([$ax_pthread_ok]) |
| AS_IF([test "x$ax_pthread_ok" = "xyes"], [break]) |
| |
| PTHREAD_LIBS="" |
| PTHREAD_CFLAGS="" |
| done |
| fi |
| |
| # Various other checks: |
| if test "x$ax_pthread_ok" = "xyes"; then |
| ax_pthread_save_CFLAGS="$CFLAGS" |
| ax_pthread_save_LIBS="$LIBS" |
| CFLAGS="$CFLAGS $PTHREAD_CFLAGS" |
| LIBS="$PTHREAD_LIBS $LIBS" |
| |
| # Detect AIX lossage: JOINABLE attribute is called UNDETACHED. |
| AC_CACHE_CHECK([for joinable pthread attribute], |
| [ax_cv_PTHREAD_JOINABLE_ATTR], |
| [ax_cv_PTHREAD_JOINABLE_ATTR=unknown |
| for ax_pthread_attr in PTHREAD_CREATE_JOINABLE PTHREAD_CREATE_UNDETACHED; do |
| AC_LINK_IFELSE([AC_LANG_PROGRAM([#include <pthread.h>], |
| [int attr = $ax_pthread_attr; return attr /* ; */])], |
| [ax_cv_PTHREAD_JOINABLE_ATTR=$ax_pthread_attr; break], |
| []) |
| done |
| ]) |
| AS_IF([test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xunknown" && \ |
| test "x$ax_cv_PTHREAD_JOINABLE_ATTR" != "xPTHREAD_CREATE_JOINABLE" && \ |
| test "x$ax_pthread_joinable_attr_defined" != "xyes"], |
| [AC_DEFINE_UNQUOTED([PTHREAD_CREATE_JOINABLE], |
| [$ax_cv_PTHREAD_JOINABLE_ATTR], |
| [Define to necessary symbol if this constant |
| uses a non-standard name on your system.]) |
| ax_pthread_joinable_attr_defined=yes |
| ]) |
| |
| AC_CACHE_CHECK([whether more special flags are required for pthreads], |
| [ax_cv_PTHREAD_SPECIAL_FLAGS], |
| [ax_cv_PTHREAD_SPECIAL_FLAGS=no |
| case $host_os in |
| solaris*) |
| ax_cv_PTHREAD_SPECIAL_FLAGS="-D_POSIX_PTHREAD_SEMANTICS" |
| ;; |
| esac |
| ]) |
| AS_IF([test "x$ax_cv_PTHREAD_SPECIAL_FLAGS" != "xno" && \ |
| test "x$ax_pthread_special_flags_added" != "xyes"], |
| [PTHREAD_CFLAGS="$ax_cv_PTHREAD_SPECIAL_FLAGS $PTHREAD_CFLAGS" |
| ax_pthread_special_flags_added=yes]) |
| |
| AC_CACHE_CHECK([for PTHREAD_PRIO_INHERIT], |
| [ax_cv_PTHREAD_PRIO_INHERIT], |
| [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], |
| [[int i = PTHREAD_PRIO_INHERIT;]])], |
| [ax_cv_PTHREAD_PRIO_INHERIT=yes], |
| [ax_cv_PTHREAD_PRIO_INHERIT=no]) |
| ]) |
| AS_IF([test "x$ax_cv_PTHREAD_PRIO_INHERIT" = "xyes" && \ |
| test "x$ax_pthread_prio_inherit_defined" != "xyes"], |
| [AC_DEFINE([HAVE_PTHREAD_PRIO_INHERIT], [1], [Have PTHREAD_PRIO_INHERIT.]) |
| ax_pthread_prio_inherit_defined=yes |
| ]) |
| |
| CFLAGS="$ax_pthread_save_CFLAGS" |
| LIBS="$ax_pthread_save_LIBS" |
| |
| # More AIX lossage: compile with *_r variant |
| if test "x$GCC" != "xyes"; then |
| case $host_os in |
| aix*) |
| AS_CASE(["x/$CC"], |
| [x*/c89|x*/c89_128|x*/c99|x*/c99_128|x*/cc|x*/cc128|x*/xlc|x*/xlc_v6|x*/xlc128|x*/xlc128_v6], |
| [#handle absolute path differently from PATH based program lookup |
| AS_CASE(["x$CC"], |
| [x/*], |
| [AS_IF([AS_EXECUTABLE_P([${CC}_r])],[PTHREAD_CC="${CC}_r"])], |
| [AC_CHECK_PROGS([PTHREAD_CC],[${CC}_r],[$CC])])]) |
| ;; |
| esac |
| fi |
| fi |
| |
| test -n "$PTHREAD_CC" || PTHREAD_CC="$CC" |
| |
| AC_SUBST([PTHREAD_LIBS]) |
| AC_SUBST([PTHREAD_CFLAGS]) |
| AC_SUBST([PTHREAD_CC]) |
| |
| # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND: |
| if test "x$ax_pthread_ok" = "xyes"; then |
| ifelse([$1],,[AC_DEFINE([HAVE_PTHREAD],[1],[Define if you have POSIX threads libraries and header files.])],[$1]) |
| : |
| else |
| ax_pthread_ok=no |
| $2 |
| fi |
| AC_LANG_POP |
| ])dnl AX_PTHREAD |
| |
| # gettext.m4 serial 71 (gettext-0.20.2) |
| dnl Copyright (C) 1995-2014, 2016, 2018-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| dnl |
| dnl This file can be used in projects which are not available under |
| dnl the GNU General Public License or the GNU Lesser General Public |
| dnl License but which still want to provide support for the GNU gettext |
| dnl functionality. |
| dnl Please note that the actual code of the GNU gettext library is covered |
| dnl by the GNU Lesser General Public License, and the rest of the GNU |
| dnl gettext package is covered by the GNU General Public License. |
| dnl They are *not* in the public domain. |
| |
| dnl Authors: |
| dnl Ulrich Drepper <drepper@cygnus.com>, 1995-2000. |
| dnl Bruno Haible <haible@clisp.cons.org>, 2000-2006, 2008-2010. |
| |
| dnl Macro to add for using GNU gettext. |
| |
| dnl Usage: AM_GNU_GETTEXT([INTLSYMBOL], [NEEDSYMBOL], [INTLDIR]). |
| dnl INTLSYMBOL must be one of 'external', 'use-libtool'. |
| dnl INTLSYMBOL should be 'external' for packages other than GNU gettext, and |
| dnl 'use-libtool' for the packages 'gettext-runtime' and 'gettext-tools'. |
| dnl If INTLSYMBOL is 'use-libtool', then a libtool library |
| dnl $(top_builddir)/intl/libintl.la will be created (shared and/or static, |
| dnl depending on --{enable,disable}-{shared,static} and on the presence of |
| dnl AM-DISABLE-SHARED). |
| dnl If NEEDSYMBOL is specified and is 'need-ngettext', then GNU gettext |
| dnl implementations (in libc or libintl) without the ngettext() function |
| dnl will be ignored. If NEEDSYMBOL is specified and is |
| dnl 'need-formatstring-macros', then GNU gettext implementations that don't |
| dnl support the ISO C 99 <inttypes.h> formatstring macros will be ignored. |
| dnl INTLDIR is used to find the intl libraries. If empty, |
| dnl the value '$(top_builddir)/intl/' is used. |
| dnl |
| dnl The result of the configuration is one of three cases: |
| dnl 1) GNU gettext, as included in the intl subdirectory, will be compiled |
| dnl and used. |
| dnl Catalog format: GNU --> install in $(datadir) |
| dnl Catalog extension: .mo after installation, .gmo in source tree |
| dnl 2) GNU gettext has been found in the system's C library. |
| dnl Catalog format: GNU --> install in $(datadir) |
| dnl Catalog extension: .mo after installation, .gmo in source tree |
| dnl 3) No internationalization, always use English msgid. |
| dnl Catalog format: none |
| dnl Catalog extension: none |
| dnl If INTLSYMBOL is 'external', only cases 2 and 3 can occur. |
| dnl The use of .gmo is historical (it was needed to avoid overwriting the |
| dnl GNU format catalogs when building on a platform with an X/Open gettext), |
| dnl but we keep it in order not to force irrelevant filename changes on the |
| dnl maintainers. |
| dnl |
| AC_DEFUN([AM_GNU_GETTEXT], |
| [ |
| dnl Argument checking. |
| ifelse([$1], [], , [ifelse([$1], [external], , [ifelse([$1], [use-libtool], , |
| [errprint([ERROR: invalid first argument to AM_GNU_GETTEXT |
| ])])])]) |
| ifelse(ifelse([$1], [], [old])[]ifelse([$1], [no-libtool], [old]), [old], |
| [errprint([ERROR: Use of AM_GNU_GETTEXT without [external] argument is no longer supported. |
| ])]) |
| ifelse([$2], [], , [ifelse([$2], [need-ngettext], , [ifelse([$2], [need-formatstring-macros], , |
| [errprint([ERROR: invalid second argument to AM_GNU_GETTEXT |
| ])])])]) |
| define([gt_included_intl], |
| ifelse([$1], [external], [no], [yes])) |
| gt_NEEDS_INIT |
| AM_GNU_GETTEXT_NEED([$2]) |
| |
| AC_REQUIRE([AM_PO_SUBDIRS])dnl |
| ifelse(gt_included_intl, yes, [ |
| AC_REQUIRE([AM_INTL_SUBDIR])dnl |
| ]) |
| |
| dnl Prerequisites of AC_LIB_LINKFLAGS_BODY. |
| AC_REQUIRE([AC_LIB_PREPARE_PREFIX]) |
| AC_REQUIRE([AC_LIB_RPATH]) |
| |
| dnl Sometimes libintl requires libiconv, so first search for libiconv. |
| dnl Ideally we would do this search only after the |
| dnl if test "$USE_NLS" = "yes"; then |
| dnl if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" != "yes"; }; then |
| dnl tests. But if configure.in invokes AM_ICONV after AM_GNU_GETTEXT |
| dnl the configure script would need to contain the same shell code |
| dnl again, outside any 'if'. There are two solutions: |
| dnl - Invoke AM_ICONV_LINKFLAGS_BODY here, outside any 'if'. |
| dnl - Control the expansions in more detail using AC_PROVIDE_IFELSE. |
| dnl Since AC_PROVIDE_IFELSE is not documented, we avoid it. |
| ifelse(gt_included_intl, yes, , [ |
| AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY]) |
| ]) |
| |
| dnl Sometimes, on Mac OS X, libintl requires linking with CoreFoundation. |
| gt_INTL_MACOSX |
| |
| dnl Set USE_NLS. |
| AC_REQUIRE([AM_NLS]) |
| |
| ifelse(gt_included_intl, yes, [ |
| BUILD_INCLUDED_LIBINTL=no |
| USE_INCLUDED_LIBINTL=no |
| ]) |
| LIBINTL= |
| LTLIBINTL= |
| POSUB= |
| |
| dnl Add a version number to the cache macros. |
| case " $gt_needs " in |
| *" need-formatstring-macros "*) gt_api_version=3 ;; |
| *" need-ngettext "*) gt_api_version=2 ;; |
| *) gt_api_version=1 ;; |
| esac |
| gt_func_gnugettext_libc="gt_cv_func_gnugettext${gt_api_version}_libc" |
| gt_func_gnugettext_libintl="gt_cv_func_gnugettext${gt_api_version}_libintl" |
| |
| dnl If we use NLS figure out what method |
| if test "$USE_NLS" = "yes"; then |
| gt_use_preinstalled_gnugettext=no |
| ifelse(gt_included_intl, yes, [ |
| AC_MSG_CHECKING([whether included gettext is requested]) |
| AC_ARG_WITH([included-gettext], |
| [ --with-included-gettext use the GNU gettext library included here], |
| nls_cv_force_use_gnu_gettext=$withval, |
| nls_cv_force_use_gnu_gettext=no) |
| AC_MSG_RESULT([$nls_cv_force_use_gnu_gettext]) |
| |
| nls_cv_use_gnu_gettext="$nls_cv_force_use_gnu_gettext" |
| if test "$nls_cv_force_use_gnu_gettext" != "yes"; then |
| ]) |
| dnl User does not insist on using GNU NLS library. Figure out what |
| dnl to use. If GNU gettext is available we use this. Else we have |
| dnl to fall back to GNU NLS library. |
| |
| if test $gt_api_version -ge 3; then |
| gt_revision_test_code=' |
| #ifndef __GNU_GETTEXT_SUPPORTED_REVISION |
| #define __GNU_GETTEXT_SUPPORTED_REVISION(major) ((major) == 0 ? 0 : -1) |
| #endif |
| changequote(,)dnl |
| typedef int array [2 * (__GNU_GETTEXT_SUPPORTED_REVISION(0) >= 1) - 1]; |
| changequote([,])dnl |
| ' |
| else |
| gt_revision_test_code= |
| fi |
| if test $gt_api_version -ge 2; then |
| gt_expression_test_code=' + * ngettext ("", "", 0)' |
| else |
| gt_expression_test_code= |
| fi |
| |
| AC_CACHE_CHECK([for GNU gettext in libc], [$gt_func_gnugettext_libc], |
| [AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[ |
| #include <libintl.h> |
| #ifndef __GNU_GETTEXT_SUPPORTED_REVISION |
| extern int _nl_msg_cat_cntr; |
| extern int *_nl_domain_bindings; |
| #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_domain_bindings) |
| #else |
| #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0 |
| #endif |
| $gt_revision_test_code |
| ]], |
| [[ |
| bindtextdomain ("", ""); |
| return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION |
| ]])], |
| [eval "$gt_func_gnugettext_libc=yes"], |
| [eval "$gt_func_gnugettext_libc=no"])]) |
| |
| if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" != "yes"; }; then |
| dnl Sometimes libintl requires libiconv, so first search for libiconv. |
| ifelse(gt_included_intl, yes, , [ |
| AM_ICONV_LINK |
| ]) |
| dnl Search for libintl and define LIBINTL, LTLIBINTL and INCINTL |
| dnl accordingly. Don't use AC_LIB_LINKFLAGS_BODY([intl],[iconv]) |
| dnl because that would add "-liconv" to LIBINTL and LTLIBINTL |
| dnl even if libiconv doesn't exist. |
| AC_LIB_LINKFLAGS_BODY([intl]) |
| AC_CACHE_CHECK([for GNU gettext in libintl], |
| [$gt_func_gnugettext_libintl], |
| [gt_save_CPPFLAGS="$CPPFLAGS" |
| CPPFLAGS="$CPPFLAGS $INCINTL" |
| gt_save_LIBS="$LIBS" |
| LIBS="$LIBS $LIBINTL" |
| dnl Now see whether libintl exists and does not depend on libiconv. |
| AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[ |
| #include <libintl.h> |
| #ifndef __GNU_GETTEXT_SUPPORTED_REVISION |
| extern int _nl_msg_cat_cntr; |
| extern |
| #ifdef __cplusplus |
| "C" |
| #endif |
| const char *_nl_expand_alias (const char *); |
| #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_expand_alias ("")) |
| #else |
| #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0 |
| #endif |
| $gt_revision_test_code |
| ]], |
| [[ |
| bindtextdomain ("", ""); |
| return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION |
| ]])], |
| [eval "$gt_func_gnugettext_libintl=yes"], |
| [eval "$gt_func_gnugettext_libintl=no"]) |
| dnl Now see whether libintl exists and depends on libiconv. |
| if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" != yes; } && test -n "$LIBICONV"; then |
| LIBS="$LIBS $LIBICONV" |
| AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[ |
| #include <libintl.h> |
| #ifndef __GNU_GETTEXT_SUPPORTED_REVISION |
| extern int _nl_msg_cat_cntr; |
| extern |
| #ifdef __cplusplus |
| "C" |
| #endif |
| const char *_nl_expand_alias (const char *); |
| #define __GNU_GETTEXT_SYMBOL_EXPRESSION (_nl_msg_cat_cntr + *_nl_expand_alias ("")) |
| #else |
| #define __GNU_GETTEXT_SYMBOL_EXPRESSION 0 |
| #endif |
| $gt_revision_test_code |
| ]], |
| [[ |
| bindtextdomain ("", ""); |
| return * gettext ("")$gt_expression_test_code + __GNU_GETTEXT_SYMBOL_EXPRESSION |
| ]])], |
| [LIBINTL="$LIBINTL $LIBICONV" |
| LTLIBINTL="$LTLIBINTL $LTLIBICONV" |
| eval "$gt_func_gnugettext_libintl=yes" |
| ]) |
| fi |
| CPPFLAGS="$gt_save_CPPFLAGS" |
| LIBS="$gt_save_LIBS"]) |
| fi |
| |
| dnl If an already present or preinstalled GNU gettext() is found, |
| dnl use it. But if this macro is used in GNU gettext, and GNU |
| dnl gettext is already preinstalled in libintl, we update this |
| dnl libintl. (Cf. the install rule in intl/Makefile.in.) |
| if { eval "gt_val=\$$gt_func_gnugettext_libc"; test "$gt_val" = "yes"; } \ |
| || { { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; } \ |
| && test "$PACKAGE" != gettext-runtime \ |
| && test "$PACKAGE" != gettext-tools; }; then |
| gt_use_preinstalled_gnugettext=yes |
| else |
| dnl Reset the values set by searching for libintl. |
| LIBINTL= |
| LTLIBINTL= |
| INCINTL= |
| fi |
| |
| ifelse(gt_included_intl, yes, [ |
| if test "$gt_use_preinstalled_gnugettext" != "yes"; then |
| dnl GNU gettext is not found in the C library. |
| dnl Fall back on included GNU gettext library. |
| nls_cv_use_gnu_gettext=yes |
| fi |
| fi |
| |
| if test "$nls_cv_use_gnu_gettext" = "yes"; then |
| dnl Mark actions used to generate GNU NLS library. |
| BUILD_INCLUDED_LIBINTL=yes |
| USE_INCLUDED_LIBINTL=yes |
| LIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.la $LIBICONV $LIBTHREAD" |
| LTLIBINTL="ifelse([$3],[],\${top_builddir}/intl,[$3])/libintl.la $LTLIBICONV $LTLIBTHREAD" |
| LIBS=`echo " $LIBS " | sed -e 's/ -lintl / /' -e 's/^ //' -e 's/ $//'` |
| fi |
| |
| CATOBJEXT= |
| if test "$gt_use_preinstalled_gnugettext" = "yes" \ |
| || test "$nls_cv_use_gnu_gettext" = "yes"; then |
| dnl Mark actions to use GNU gettext tools. |
| CATOBJEXT=.gmo |
| fi |
| ]) |
| |
| if test -n "$INTL_MACOSX_LIBS"; then |
| if test "$gt_use_preinstalled_gnugettext" = "yes" \ |
| || test "$nls_cv_use_gnu_gettext" = "yes"; then |
| dnl Some extra flags are needed during linking. |
| LIBINTL="$LIBINTL $INTL_MACOSX_LIBS" |
| LTLIBINTL="$LTLIBINTL $INTL_MACOSX_LIBS" |
| fi |
| fi |
| |
| if test "$gt_use_preinstalled_gnugettext" = "yes" \ |
| || test "$nls_cv_use_gnu_gettext" = "yes"; then |
| AC_DEFINE([ENABLE_NLS], [1], |
| [Define to 1 if translation of program messages to the user's native language |
| is requested.]) |
| else |
| USE_NLS=no |
| fi |
| fi |
| |
| AC_MSG_CHECKING([whether to use NLS]) |
| AC_MSG_RESULT([$USE_NLS]) |
| if test "$USE_NLS" = "yes"; then |
| AC_MSG_CHECKING([where the gettext function comes from]) |
| if test "$gt_use_preinstalled_gnugettext" = "yes"; then |
| if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; }; then |
| gt_source="external libintl" |
| else |
| gt_source="libc" |
| fi |
| else |
| gt_source="included intl directory" |
| fi |
| AC_MSG_RESULT([$gt_source]) |
| fi |
| |
| if test "$USE_NLS" = "yes"; then |
| |
| if test "$gt_use_preinstalled_gnugettext" = "yes"; then |
| if { eval "gt_val=\$$gt_func_gnugettext_libintl"; test "$gt_val" = "yes"; }; then |
| AC_MSG_CHECKING([how to link with libintl]) |
| AC_MSG_RESULT([$LIBINTL]) |
| AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCINTL]) |
| fi |
| |
| dnl For backward compatibility. Some packages may be using this. |
| AC_DEFINE([HAVE_GETTEXT], [1], |
| [Define if the GNU gettext() function is already present or preinstalled.]) |
| AC_DEFINE([HAVE_DCGETTEXT], [1], |
| [Define if the GNU dcgettext() function is already present or preinstalled.]) |
| fi |
| |
| dnl We need to process the po/ directory. |
| POSUB=po |
| fi |
| |
| ifelse(gt_included_intl, yes, [ |
| dnl In GNU gettext we have to set BUILD_INCLUDED_LIBINTL to 'yes' |
| dnl because some of the testsuite requires it. |
| BUILD_INCLUDED_LIBINTL=yes |
| |
| dnl Make all variables we use known to autoconf. |
| AC_SUBST([BUILD_INCLUDED_LIBINTL]) |
| AC_SUBST([USE_INCLUDED_LIBINTL]) |
| AC_SUBST([CATOBJEXT]) |
| ]) |
| |
| dnl For backward compatibility. Some Makefiles may be using this. |
| INTLLIBS="$LIBINTL" |
| AC_SUBST([INTLLIBS]) |
| |
| dnl Make all documented variables known to autoconf. |
| AC_SUBST([LIBINTL]) |
| AC_SUBST([LTLIBINTL]) |
| AC_SUBST([POSUB]) |
| ]) |
| |
| |
| dnl gt_NEEDS_INIT ensures that the gt_needs variable is initialized. |
| m4_define([gt_NEEDS_INIT], |
| [ |
| m4_divert_text([DEFAULTS], [gt_needs=]) |
| m4_define([gt_NEEDS_INIT], []) |
| ]) |
| |
| |
| dnl Usage: AM_GNU_GETTEXT_NEED([NEEDSYMBOL]) |
| AC_DEFUN([AM_GNU_GETTEXT_NEED], |
| [ |
| m4_divert_text([INIT_PREPARE], [gt_needs="$gt_needs $1"]) |
| ]) |
| |
| |
| dnl Usage: AM_GNU_GETTEXT_VERSION([gettext-version]) |
| AC_DEFUN([AM_GNU_GETTEXT_VERSION], []) |
| |
| |
| dnl Usage: AM_GNU_GETTEXT_REQUIRE_VERSION([gettext-version]) |
| AC_DEFUN([AM_GNU_GETTEXT_REQUIRE_VERSION], []) |
| |
| # host-cpu-c-abi.m4 serial 13 |
| dnl Copyright (C) 2002-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| |
| dnl From Bruno Haible and Sam Steingold. |
| |
| dnl Sets the HOST_CPU variable to the canonical name of the CPU. |
| dnl Sets the HOST_CPU_C_ABI variable to the canonical name of the CPU with its |
| dnl C language ABI (application binary interface). |
| dnl Also defines __${HOST_CPU}__ and __${HOST_CPU_C_ABI}__ as C macros in |
| dnl config.h. |
| dnl |
| dnl This canonical name can be used to select a particular assembly language |
| dnl source file that will interoperate with C code on the given host. |
| dnl |
| dnl For example: |
| dnl * 'i386' and 'sparc' are different canonical names, because code for i386 |
| dnl will not run on SPARC CPUs and vice versa. They have different |
| dnl instruction sets. |
| dnl * 'sparc' and 'sparc64' are different canonical names, because code for |
| dnl 'sparc' and code for 'sparc64' cannot be linked together: 'sparc' code |
| dnl contains 32-bit instructions, whereas 'sparc64' code contains 64-bit |
| dnl instructions. A process on a SPARC CPU can be in 32-bit mode or in 64-bit |
| dnl mode, but not both. |
| dnl * 'mips' and 'mipsn32' are different canonical names, because they use |
| dnl different argument passing and return conventions for C functions, and |
| dnl although the instruction set of 'mips' is a large subset of the |
| dnl instruction set of 'mipsn32'. |
| dnl * 'mipsn32' and 'mips64' are different canonical names, because they use |
| dnl different sizes for the C types like 'int' and 'void *', and although |
| dnl the instruction sets of 'mipsn32' and 'mips64' are the same. |
| dnl * The same canonical name is used for different endiannesses. You can |
| dnl determine the endianness through preprocessor symbols: |
| dnl - 'arm': test __ARMEL__. |
| dnl - 'mips', 'mipsn32', 'mips64': test _MIPSEB vs. _MIPSEL. |
| dnl - 'powerpc64': test _BIG_ENDIAN vs. _LITTLE_ENDIAN. |
| dnl * The same name 'i386' is used for CPUs of type i386, i486, i586 |
| dnl (Pentium), AMD K7, Pentium II, Pentium IV, etc., because |
| dnl - Instructions that do not exist on all of these CPUs (cmpxchg, |
| dnl MMX, SSE, SSE2, 3DNow! etc.) are not frequently used. If your |
| dnl assembly language source files use such instructions, you will |
| dnl need to make the distinction. |
| dnl - Speed of execution of the common instruction set is reasonable across |
| dnl the entire family of CPUs. If you have assembly language source files |
| dnl that are optimized for particular CPU types (like GNU gmp has), you |
| dnl will need to make the distinction. |
| dnl See <https://en.wikipedia.org/wiki/X86_instruction_listings>. |
| AC_DEFUN([gl_HOST_CPU_C_ABI], |
| [ |
| AC_REQUIRE([AC_CANONICAL_HOST]) |
| AC_REQUIRE([gl_C_ASM]) |
| AC_CACHE_CHECK([host CPU and C ABI], [gl_cv_host_cpu_c_abi], |
| [case "$host_cpu" in |
| |
| changequote(,)dnl |
| i[34567]86 ) |
| changequote([,])dnl |
| gl_cv_host_cpu_c_abi=i386 |
| ;; |
| |
| x86_64 ) |
| # On x86_64 systems, the C compiler may be generating code in one of |
| # these ABIs: |
| # - 64-bit instruction set, 64-bit pointers, 64-bit 'long': x86_64. |
| # - 64-bit instruction set, 64-bit pointers, 32-bit 'long': x86_64 |
| # with native Windows (mingw, MSVC). |
| # - 64-bit instruction set, 32-bit pointers, 32-bit 'long': x86_64-x32. |
| # - 32-bit instruction set, 32-bit pointers, 32-bit 'long': i386. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if (defined __x86_64__ || defined __amd64__ \ |
| || defined _M_X64 || defined _M_AMD64) |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __ILP32__ || defined _ILP32 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=x86_64-x32], |
| [gl_cv_host_cpu_c_abi=x86_64])], |
| [gl_cv_host_cpu_c_abi=i386]) |
| ;; |
| |
| changequote(,)dnl |
| alphaev[4-8] | alphaev56 | alphapca5[67] | alphaev6[78] ) |
| changequote([,])dnl |
| gl_cv_host_cpu_c_abi=alpha |
| ;; |
| |
| arm* | aarch64 ) |
| # Assume arm with EABI. |
| # On arm64 systems, the C compiler may be generating code in one of |
| # these ABIs: |
| # - aarch64 instruction set, 64-bit pointers, 64-bit 'long': arm64. |
| # - aarch64 instruction set, 32-bit pointers, 32-bit 'long': arm64-ilp32. |
| # - 32-bit instruction set, 32-bit pointers, 32-bit 'long': arm or armhf. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#ifdef __aarch64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __ILP32__ || defined _ILP32 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=arm64-ilp32], |
| [gl_cv_host_cpu_c_abi=arm64])], |
| [# Don't distinguish little-endian and big-endian arm, since they |
| # don't require different machine code for simple operations and |
| # since the user can distinguish them through the preprocessor |
| # defines __ARMEL__ vs. __ARMEB__. |
| # But distinguish arm which passes floating-point arguments and |
| # return values in integer registers (r0, r1, ...) - this is |
| # gcc -mfloat-abi=soft or gcc -mfloat-abi=softfp - from arm which |
| # passes them in float registers (s0, s1, ...) and double registers |
| # (d0, d1, ...) - this is gcc -mfloat-abi=hard. GCC 4.6 or newer |
| # sets the preprocessor defines __ARM_PCS (for the first case) and |
| # __ARM_PCS_VFP (for the second case), but older GCC does not. |
| echo 'double ddd; void func (double dd) { ddd = dd; }' > conftest.c |
| # Look for a reference to the register d0 in the .s file. |
| AC_TRY_COMMAND(${CC-cc} $CFLAGS $CPPFLAGS $gl_c_asm_opt conftest.c) >/dev/null 2>&1 |
| if LC_ALL=C grep 'd0,' conftest.$gl_asmext >/dev/null; then |
| gl_cv_host_cpu_c_abi=armhf |
| else |
| gl_cv_host_cpu_c_abi=arm |
| fi |
| rm -f conftest* |
| ]) |
| ;; |
| |
| hppa1.0 | hppa1.1 | hppa2.0* | hppa64 ) |
| # On hppa, the C compiler may be generating 32-bit code or 64-bit |
| # code. In the latter case, it defines _LP64 and __LP64__. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#ifdef __LP64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=hppa64], |
| [gl_cv_host_cpu_c_abi=hppa]) |
| ;; |
| |
| ia64* ) |
| # On ia64 on HP-UX, the C compiler may be generating 64-bit code or |
| # 32-bit code. In the latter case, it defines _ILP32. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#ifdef _ILP32 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=ia64-ilp32], |
| [gl_cv_host_cpu_c_abi=ia64]) |
| ;; |
| |
| mips* ) |
| # We should also check for (_MIPS_SZPTR == 64), but gcc keeps this |
| # at 32. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined _MIPS_SZLONG && (_MIPS_SZLONG == 64) |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=mips64], |
| [# In the n32 ABI, _ABIN32 is defined, _ABIO32 is not defined (but |
| # may later get defined by <sgidefs.h>), and _MIPS_SIM == _ABIN32. |
| # In the 32 ABI, _ABIO32 is defined, _ABIN32 is not defined (but |
| # may later get defined by <sgidefs.h>), and _MIPS_SIM == _ABIO32. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if (_MIPS_SIM == _ABIN32) |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=mipsn32], |
| [gl_cv_host_cpu_c_abi=mips])]) |
| ;; |
| |
| powerpc* ) |
| # Different ABIs are in use on AIX vs. Mac OS X vs. Linux,*BSD. |
| # No need to distinguish them here; the caller may distinguish |
| # them based on the OS. |
| # On powerpc64 systems, the C compiler may still be generating |
| # 32-bit code. And on powerpc-ibm-aix systems, the C compiler may |
| # be generating 64-bit code. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __powerpc64__ || defined _ARCH_PPC64 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [# On powerpc64, there are two ABIs on Linux: The AIX compatible |
| # one and the ELFv2 one. The latter defines _CALL_ELF=2. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined _CALL_ELF && _CALL_ELF == 2 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=powerpc64-elfv2], |
| [gl_cv_host_cpu_c_abi=powerpc64]) |
| ], |
| [gl_cv_host_cpu_c_abi=powerpc]) |
| ;; |
| |
| rs6000 ) |
| gl_cv_host_cpu_c_abi=powerpc |
| ;; |
| |
| riscv32 | riscv64 ) |
| # There are 2 architectures (with variants): rv32* and rv64*. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if __riscv_xlen == 64 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [cpu=riscv64], |
| [cpu=riscv32]) |
| # There are 6 ABIs: ilp32, ilp32f, ilp32d, lp64, lp64f, lp64d. |
| # Size of 'long' and 'void *': |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __LP64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [main_abi=lp64], |
| [main_abi=ilp32]) |
| # Float ABIs: |
| # __riscv_float_abi_double: |
| # 'float' and 'double' are passed in floating-point registers. |
| # __riscv_float_abi_single: |
| # 'float' are passed in floating-point registers. |
| # __riscv_float_abi_soft: |
| # No values are passed in floating-point registers. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __riscv_float_abi_double |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [float_abi=d], |
| [AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __riscv_float_abi_single |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [float_abi=f], |
| [float_abi='']) |
| ]) |
| gl_cv_host_cpu_c_abi="${cpu}-${main_abi}${float_abi}" |
| ;; |
| |
| s390* ) |
| # On s390x, the C compiler may be generating 64-bit (= s390x) code |
| # or 31-bit (= s390) code. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __LP64__ || defined __s390x__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=s390x], |
| [gl_cv_host_cpu_c_abi=s390]) |
| ;; |
| |
| sparc | sparc64 ) |
| # UltraSPARCs running Linux have `uname -m` = "sparc64", but the |
| # C compiler still generates 32-bit code. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __sparcv9 || defined __arch64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi=sparc64], |
| [gl_cv_host_cpu_c_abi=sparc]) |
| ;; |
| |
| *) |
| gl_cv_host_cpu_c_abi="$host_cpu" |
| ;; |
| esac |
| ]) |
| |
| dnl In most cases, $HOST_CPU and $HOST_CPU_C_ABI are the same. |
| HOST_CPU=`echo "$gl_cv_host_cpu_c_abi" | sed -e 's/-.*//'` |
| HOST_CPU_C_ABI="$gl_cv_host_cpu_c_abi" |
| AC_SUBST([HOST_CPU]) |
| AC_SUBST([HOST_CPU_C_ABI]) |
| |
| # This was |
| # AC_DEFINE_UNQUOTED([__${HOST_CPU}__]) |
| # AC_DEFINE_UNQUOTED([__${HOST_CPU_C_ABI}__]) |
| # earlier, but KAI C++ 3.2d doesn't like this. |
| sed -e 's/-/_/g' >> confdefs.h <<EOF |
| #ifndef __${HOST_CPU}__ |
| #define __${HOST_CPU}__ 1 |
| #endif |
| #ifndef __${HOST_CPU_C_ABI}__ |
| #define __${HOST_CPU_C_ABI}__ 1 |
| #endif |
| EOF |
| AH_TOP([/* CPU and C ABI indicator */ |
| #ifndef __i386__ |
| #undef __i386__ |
| #endif |
| #ifndef __x86_64_x32__ |
| #undef __x86_64_x32__ |
| #endif |
| #ifndef __x86_64__ |
| #undef __x86_64__ |
| #endif |
| #ifndef __alpha__ |
| #undef __alpha__ |
| #endif |
| #ifndef __arm__ |
| #undef __arm__ |
| #endif |
| #ifndef __armhf__ |
| #undef __armhf__ |
| #endif |
| #ifndef __arm64_ilp32__ |
| #undef __arm64_ilp32__ |
| #endif |
| #ifndef __arm64__ |
| #undef __arm64__ |
| #endif |
| #ifndef __hppa__ |
| #undef __hppa__ |
| #endif |
| #ifndef __hppa64__ |
| #undef __hppa64__ |
| #endif |
| #ifndef __ia64_ilp32__ |
| #undef __ia64_ilp32__ |
| #endif |
| #ifndef __ia64__ |
| #undef __ia64__ |
| #endif |
| #ifndef __m68k__ |
| #undef __m68k__ |
| #endif |
| #ifndef __mips__ |
| #undef __mips__ |
| #endif |
| #ifndef __mipsn32__ |
| #undef __mipsn32__ |
| #endif |
| #ifndef __mips64__ |
| #undef __mips64__ |
| #endif |
| #ifndef __powerpc__ |
| #undef __powerpc__ |
| #endif |
| #ifndef __powerpc64__ |
| #undef __powerpc64__ |
| #endif |
| #ifndef __powerpc64_elfv2__ |
| #undef __powerpc64_elfv2__ |
| #endif |
| #ifndef __riscv32__ |
| #undef __riscv32__ |
| #endif |
| #ifndef __riscv64__ |
| #undef __riscv64__ |
| #endif |
| #ifndef __riscv32_ilp32__ |
| #undef __riscv32_ilp32__ |
| #endif |
| #ifndef __riscv32_ilp32f__ |
| #undef __riscv32_ilp32f__ |
| #endif |
| #ifndef __riscv32_ilp32d__ |
| #undef __riscv32_ilp32d__ |
| #endif |
| #ifndef __riscv64_ilp32__ |
| #undef __riscv64_ilp32__ |
| #endif |
| #ifndef __riscv64_ilp32f__ |
| #undef __riscv64_ilp32f__ |
| #endif |
| #ifndef __riscv64_ilp32d__ |
| #undef __riscv64_ilp32d__ |
| #endif |
| #ifndef __riscv64_lp64__ |
| #undef __riscv64_lp64__ |
| #endif |
| #ifndef __riscv64_lp64f__ |
| #undef __riscv64_lp64f__ |
| #endif |
| #ifndef __riscv64_lp64d__ |
| #undef __riscv64_lp64d__ |
| #endif |
| #ifndef __s390__ |
| #undef __s390__ |
| #endif |
| #ifndef __s390x__ |
| #undef __s390x__ |
| #endif |
| #ifndef __sh__ |
| #undef __sh__ |
| #endif |
| #ifndef __sparc__ |
| #undef __sparc__ |
| #endif |
| #ifndef __sparc64__ |
| #undef __sparc64__ |
| #endif |
| ]) |
| |
| ]) |
| |
| |
| dnl Sets the HOST_CPU_C_ABI_32BIT variable to 'yes' if the C language ABI |
| dnl (application binary interface) is a 32-bit one, to 'no' if it is a 64-bit |
| dnl one, or to 'unknown' if unknown. |
| dnl This is a simplified variant of gl_HOST_CPU_C_ABI. |
| AC_DEFUN([gl_HOST_CPU_C_ABI_32BIT], |
| [ |
| AC_REQUIRE([AC_CANONICAL_HOST]) |
| AC_CACHE_CHECK([32-bit host C ABI], [gl_cv_host_cpu_c_abi_32bit], |
| [if test -n "$gl_cv_host_cpu_c_abi"; then |
| case "$gl_cv_host_cpu_c_abi" in |
| i386 | x86_64-x32 | arm | armhf | arm64-ilp32 | hppa | ia64-ilp32 | mips | mipsn32 | powerpc | riscv*-ilp32* | s390 | sparc) |
| gl_cv_host_cpu_c_abi_32bit=yes ;; |
| x86_64 | alpha | arm64 | hppa64 | ia64 | mips64 | powerpc64 | powerpc64-elfv2 | riscv*-lp64* | s390x | sparc64 ) |
| gl_cv_host_cpu_c_abi_32bit=no ;; |
| *) |
| gl_cv_host_cpu_c_abi_32bit=unknown ;; |
| esac |
| else |
| case "$host_cpu" in |
| |
| # CPUs that only support a 32-bit ABI. |
| arc \ |
| | bfin \ |
| | cris* \ |
| | csky \ |
| | epiphany \ |
| | ft32 \ |
| | h8300 \ |
| | m68k \ |
| | microblaze | microblazeel \ |
| | nds32 | nds32le | nds32be \ |
| | nios2 | nios2eb | nios2el \ |
| | or1k* \ |
| | or32 \ |
| | sh | sh[1234] | sh[1234]e[lb] \ |
| | tic6x \ |
| | xtensa* ) |
| gl_cv_host_cpu_c_abi_32bit=yes |
| ;; |
| |
| # CPUs that only support a 64-bit ABI. |
| changequote(,)dnl |
| alpha | alphaev[4-8] | alphaev56 | alphapca5[67] | alphaev6[78] \ |
| | mmix ) |
| changequote([,])dnl |
| gl_cv_host_cpu_c_abi_32bit=no |
| ;; |
| |
| changequote(,)dnl |
| i[34567]86 ) |
| changequote([,])dnl |
| gl_cv_host_cpu_c_abi_32bit=yes |
| ;; |
| |
| x86_64 ) |
| # On x86_64 systems, the C compiler may be generating code in one of |
| # these ABIs: |
| # - 64-bit instruction set, 64-bit pointers, 64-bit 'long': x86_64. |
| # - 64-bit instruction set, 64-bit pointers, 32-bit 'long': x86_64 |
| # with native Windows (mingw, MSVC). |
| # - 64-bit instruction set, 32-bit pointers, 32-bit 'long': x86_64-x32. |
| # - 32-bit instruction set, 32-bit pointers, 32-bit 'long': i386. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if (defined __x86_64__ || defined __amd64__ \ |
| || defined _M_X64 || defined _M_AMD64) \ |
| && !(defined __ILP32__ || defined _ILP32) |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| arm* | aarch64 ) |
| # Assume arm with EABI. |
| # On arm64 systems, the C compiler may be generating code in one of |
| # these ABIs: |
| # - aarch64 instruction set, 64-bit pointers, 64-bit 'long': arm64. |
| # - aarch64 instruction set, 32-bit pointers, 32-bit 'long': arm64-ilp32. |
| # - 32-bit instruction set, 32-bit pointers, 32-bit 'long': arm or armhf. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __aarch64__ && !(defined __ILP32__ || defined _ILP32) |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| hppa1.0 | hppa1.1 | hppa2.0* | hppa64 ) |
| # On hppa, the C compiler may be generating 32-bit code or 64-bit |
| # code. In the latter case, it defines _LP64 and __LP64__. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#ifdef __LP64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| ia64* ) |
| # On ia64 on HP-UX, the C compiler may be generating 64-bit code or |
| # 32-bit code. In the latter case, it defines _ILP32. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#ifdef _ILP32 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=yes], |
| [gl_cv_host_cpu_c_abi_32bit=no]) |
| ;; |
| |
| mips* ) |
| # We should also check for (_MIPS_SZPTR == 64), but gcc keeps this |
| # at 32. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined _MIPS_SZLONG && (_MIPS_SZLONG == 64) |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| powerpc* ) |
| # Different ABIs are in use on AIX vs. Mac OS X vs. Linux,*BSD. |
| # No need to distinguish them here; the caller may distinguish |
| # them based on the OS. |
| # On powerpc64 systems, the C compiler may still be generating |
| # 32-bit code. And on powerpc-ibm-aix systems, the C compiler may |
| # be generating 64-bit code. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __powerpc64__ || defined _ARCH_PPC64 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| rs6000 ) |
| gl_cv_host_cpu_c_abi_32bit=yes |
| ;; |
| |
| riscv32 | riscv64 ) |
| # There are 6 ABIs: ilp32, ilp32f, ilp32d, lp64, lp64f, lp64d. |
| # Size of 'long' and 'void *': |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __LP64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| s390* ) |
| # On s390x, the C compiler may be generating 64-bit (= s390x) code |
| # or 31-bit (= s390) code. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __LP64__ || defined __s390x__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| sparc | sparc64 ) |
| # UltraSPARCs running Linux have `uname -m` = "sparc64", but the |
| # C compiler still generates 32-bit code. |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __sparcv9 || defined __arch64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [gl_cv_host_cpu_c_abi_32bit=no], |
| [gl_cv_host_cpu_c_abi_32bit=yes]) |
| ;; |
| |
| *) |
| gl_cv_host_cpu_c_abi_32bit=unknown |
| ;; |
| esac |
| fi |
| ]) |
| |
| HOST_CPU_C_ABI_32BIT="$gl_cv_host_cpu_c_abi_32bit" |
| ]) |
| |
| # iconv.m4 serial 21 |
| dnl Copyright (C) 2000-2002, 2007-2014, 2016-2020 Free Software Foundation, |
| dnl Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| |
| dnl From Bruno Haible. |
| |
| AC_DEFUN([AM_ICONV_LINKFLAGS_BODY], |
| [ |
| dnl Prerequisites of AC_LIB_LINKFLAGS_BODY. |
| AC_REQUIRE([AC_LIB_PREPARE_PREFIX]) |
| AC_REQUIRE([AC_LIB_RPATH]) |
| |
| dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV |
| dnl accordingly. |
| AC_LIB_LINKFLAGS_BODY([iconv]) |
| ]) |
| |
| AC_DEFUN([AM_ICONV_LINK], |
| [ |
| dnl Some systems have iconv in libc, some have it in libiconv (OSF/1 and |
| dnl those with the standalone portable GNU libiconv installed). |
| AC_REQUIRE([AC_CANONICAL_HOST]) dnl for cross-compiles |
| |
| dnl Search for libiconv and define LIBICONV, LTLIBICONV and INCICONV |
| dnl accordingly. |
| AC_REQUIRE([AM_ICONV_LINKFLAGS_BODY]) |
| |
| dnl Add $INCICONV to CPPFLAGS before performing the following checks, |
| dnl because if the user has installed libiconv and not disabled its use |
| dnl via --without-libiconv-prefix, he wants to use it. The first |
| dnl AC_LINK_IFELSE will then fail, the second AC_LINK_IFELSE will succeed. |
| am_save_CPPFLAGS="$CPPFLAGS" |
| AC_LIB_APPENDTOVAR([CPPFLAGS], [$INCICONV]) |
| |
| AC_CACHE_CHECK([for iconv], [am_cv_func_iconv], [ |
| am_cv_func_iconv="no, consider installing GNU libiconv" |
| am_cv_lib_iconv=no |
| AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[ |
| #include <stdlib.h> |
| #include <iconv.h> |
| ]], |
| [[iconv_t cd = iconv_open("",""); |
| iconv(cd,NULL,NULL,NULL,NULL); |
| iconv_close(cd);]])], |
| [am_cv_func_iconv=yes]) |
| if test "$am_cv_func_iconv" != yes; then |
| am_save_LIBS="$LIBS" |
| LIBS="$LIBS $LIBICONV" |
| AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[ |
| #include <stdlib.h> |
| #include <iconv.h> |
| ]], |
| [[iconv_t cd = iconv_open("",""); |
| iconv(cd,NULL,NULL,NULL,NULL); |
| iconv_close(cd);]])], |
| [am_cv_lib_iconv=yes] |
| [am_cv_func_iconv=yes]) |
| LIBS="$am_save_LIBS" |
| fi |
| ]) |
| if test "$am_cv_func_iconv" = yes; then |
| AC_CACHE_CHECK([for working iconv], [am_cv_func_iconv_works], [ |
| dnl This tests against bugs in AIX 5.1, AIX 6.1..7.1, HP-UX 11.11, |
| dnl Solaris 10. |
| am_save_LIBS="$LIBS" |
| if test $am_cv_lib_iconv = yes; then |
| LIBS="$LIBS $LIBICONV" |
| fi |
| am_cv_func_iconv_works=no |
| for ac_iconv_const in '' 'const'; do |
| AC_RUN_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[ |
| #include <iconv.h> |
| #include <string.h> |
| |
| #ifndef ICONV_CONST |
| # define ICONV_CONST $ac_iconv_const |
| #endif |
| ]], |
| [[int result = 0; |
| /* Test against AIX 5.1 bug: Failures are not distinguishable from successful |
| returns. */ |
| { |
| iconv_t cd_utf8_to_88591 = iconv_open ("ISO8859-1", "UTF-8"); |
| if (cd_utf8_to_88591 != (iconv_t)(-1)) |
| { |
| static ICONV_CONST char input[] = "\342\202\254"; /* EURO SIGN */ |
| char buf[10]; |
| ICONV_CONST char *inptr = input; |
| size_t inbytesleft = strlen (input); |
| char *outptr = buf; |
| size_t outbytesleft = sizeof (buf); |
| size_t res = iconv (cd_utf8_to_88591, |
| &inptr, &inbytesleft, |
| &outptr, &outbytesleft); |
| if (res == 0) |
| result |= 1; |
| iconv_close (cd_utf8_to_88591); |
| } |
| } |
| /* Test against Solaris 10 bug: Failures are not distinguishable from |
| successful returns. */ |
| { |
| iconv_t cd_ascii_to_88591 = iconv_open ("ISO8859-1", "646"); |
| if (cd_ascii_to_88591 != (iconv_t)(-1)) |
| { |
| static ICONV_CONST char input[] = "\263"; |
| char buf[10]; |
| ICONV_CONST char *inptr = input; |
| size_t inbytesleft = strlen (input); |
| char *outptr = buf; |
| size_t outbytesleft = sizeof (buf); |
| size_t res = iconv (cd_ascii_to_88591, |
| &inptr, &inbytesleft, |
| &outptr, &outbytesleft); |
| if (res == 0) |
| result |= 2; |
| iconv_close (cd_ascii_to_88591); |
| } |
| } |
| /* Test against AIX 6.1..7.1 bug: Buffer overrun. */ |
| { |
| iconv_t cd_88591_to_utf8 = iconv_open ("UTF-8", "ISO-8859-1"); |
| if (cd_88591_to_utf8 != (iconv_t)(-1)) |
| { |
| static ICONV_CONST char input[] = "\304"; |
| static char buf[2] = { (char)0xDE, (char)0xAD }; |
| ICONV_CONST char *inptr = input; |
| size_t inbytesleft = 1; |
| char *outptr = buf; |
| size_t outbytesleft = 1; |
| size_t res = iconv (cd_88591_to_utf8, |
| &inptr, &inbytesleft, |
| &outptr, &outbytesleft); |
| if (res != (size_t)(-1) || outptr - buf > 1 || buf[1] != (char)0xAD) |
| result |= 4; |
| iconv_close (cd_88591_to_utf8); |
| } |
| } |
| #if 0 /* This bug could be worked around by the caller. */ |
| /* Test against HP-UX 11.11 bug: Positive return value instead of 0. */ |
| { |
| iconv_t cd_88591_to_utf8 = iconv_open ("utf8", "iso88591"); |
| if (cd_88591_to_utf8 != (iconv_t)(-1)) |
| { |
| static ICONV_CONST char input[] = "\304rger mit b\366sen B\374bchen ohne Augenma\337"; |
| char buf[50]; |
| ICONV_CONST char *inptr = input; |
| size_t inbytesleft = strlen (input); |
| char *outptr = buf; |
| size_t outbytesleft = sizeof (buf); |
| size_t res = iconv (cd_88591_to_utf8, |
| &inptr, &inbytesleft, |
| &outptr, &outbytesleft); |
| if ((int)res > 0) |
| result |= 8; |
| iconv_close (cd_88591_to_utf8); |
| } |
| } |
| #endif |
| /* Test against HP-UX 11.11 bug: No converter from EUC-JP to UTF-8 is |
| provided. */ |
| { |
| /* Try standardized names. */ |
| iconv_t cd1 = iconv_open ("UTF-8", "EUC-JP"); |
| /* Try IRIX, OSF/1 names. */ |
| iconv_t cd2 = iconv_open ("UTF-8", "eucJP"); |
| /* Try AIX names. */ |
| iconv_t cd3 = iconv_open ("UTF-8", "IBM-eucJP"); |
| /* Try HP-UX names. */ |
| iconv_t cd4 = iconv_open ("utf8", "eucJP"); |
| if (cd1 == (iconv_t)(-1) && cd2 == (iconv_t)(-1) |
| && cd3 == (iconv_t)(-1) && cd4 == (iconv_t)(-1)) |
| result |= 16; |
| if (cd1 != (iconv_t)(-1)) |
| iconv_close (cd1); |
| if (cd2 != (iconv_t)(-1)) |
| iconv_close (cd2); |
| if (cd3 != (iconv_t)(-1)) |
| iconv_close (cd3); |
| if (cd4 != (iconv_t)(-1)) |
| iconv_close (cd4); |
| } |
| return result; |
| ]])], |
| [am_cv_func_iconv_works=yes], , |
| [case "$host_os" in |
| aix* | hpux*) am_cv_func_iconv_works="guessing no" ;; |
| *) am_cv_func_iconv_works="guessing yes" ;; |
| esac]) |
| test "$am_cv_func_iconv_works" = no || break |
| done |
| LIBS="$am_save_LIBS" |
| ]) |
| case "$am_cv_func_iconv_works" in |
| *no) am_func_iconv=no am_cv_lib_iconv=no ;; |
| *) am_func_iconv=yes ;; |
| esac |
| else |
| am_func_iconv=no am_cv_lib_iconv=no |
| fi |
| if test "$am_func_iconv" = yes; then |
| AC_DEFINE([HAVE_ICONV], [1], |
| [Define if you have the iconv() function and it works.]) |
| fi |
| if test "$am_cv_lib_iconv" = yes; then |
| AC_MSG_CHECKING([how to link with libiconv]) |
| AC_MSG_RESULT([$LIBICONV]) |
| else |
| dnl If $LIBICONV didn't lead to a usable library, we don't need $INCICONV |
| dnl either. |
| CPPFLAGS="$am_save_CPPFLAGS" |
| LIBICONV= |
| LTLIBICONV= |
| fi |
| AC_SUBST([LIBICONV]) |
| AC_SUBST([LTLIBICONV]) |
| ]) |
| |
| dnl Define AM_ICONV using AC_DEFUN_ONCE for Autoconf >= 2.64, in order to |
| dnl avoid warnings like |
| dnl "warning: AC_REQUIRE: `AM_ICONV' was expanded before it was required". |
| dnl This is tricky because of the way 'aclocal' is implemented: |
| dnl - It requires defining an auxiliary macro whose name ends in AC_DEFUN. |
| dnl Otherwise aclocal's initial scan pass would miss the macro definition. |
| dnl - It requires a line break inside the AC_DEFUN_ONCE and AC_DEFUN expansions. |
| dnl Otherwise aclocal would emit many "Use of uninitialized value $1" |
| dnl warnings. |
| m4_define([gl_iconv_AC_DEFUN], |
| m4_version_prereq([2.64], |
| [[AC_DEFUN_ONCE( |
| [$1], [$2])]], |
| [m4_ifdef([gl_00GNULIB], |
| [[AC_DEFUN_ONCE( |
| [$1], [$2])]], |
| [[AC_DEFUN( |
| [$1], [$2])]])])) |
| gl_iconv_AC_DEFUN([AM_ICONV], |
| [ |
| AM_ICONV_LINK |
| if test "$am_cv_func_iconv" = yes; then |
| AC_MSG_CHECKING([for iconv declaration]) |
| AC_CACHE_VAL([am_cv_proto_iconv], [ |
| AC_COMPILE_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[ |
| #include <stdlib.h> |
| #include <iconv.h> |
| extern |
| #ifdef __cplusplus |
| "C" |
| #endif |
| #if defined(__STDC__) || defined(_MSC_VER) || defined(__cplusplus) |
| size_t iconv (iconv_t cd, char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft); |
| #else |
| size_t iconv(); |
| #endif |
| ]], |
| [[]])], |
| [am_cv_proto_iconv_arg1=""], |
| [am_cv_proto_iconv_arg1="const"]) |
| am_cv_proto_iconv="extern size_t iconv (iconv_t cd, $am_cv_proto_iconv_arg1 char * *inbuf, size_t *inbytesleft, char * *outbuf, size_t *outbytesleft);"]) |
| am_cv_proto_iconv=`echo "[$]am_cv_proto_iconv" | tr -s ' ' | sed -e 's/( /(/'` |
| AC_MSG_RESULT([ |
| $am_cv_proto_iconv]) |
| else |
| dnl When compiling GNU libiconv on a system that does not have iconv yet, |
| dnl pick the POSIX compliant declaration without 'const'. |
| am_cv_proto_iconv_arg1="" |
| fi |
| AC_DEFINE_UNQUOTED([ICONV_CONST], [$am_cv_proto_iconv_arg1], |
| [Define as const if the declaration of iconv() needs const.]) |
| dnl Also substitute ICONV_CONST in the gnulib generated <iconv.h>. |
| m4_ifdef([gl_ICONV_H_DEFAULTS], |
| [AC_REQUIRE([gl_ICONV_H_DEFAULTS]) |
| if test -n "$am_cv_proto_iconv_arg1"; then |
| ICONV_CONST="const" |
| fi |
| ]) |
| ]) |
| |
| # intlmacosx.m4 serial 8 (gettext-0.20.2) |
| dnl Copyright (C) 2004-2014, 2016, 2019-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| dnl |
| dnl This file can be used in projects which are not available under |
| dnl the GNU General Public License or the GNU Lesser General Public |
| dnl License but which still want to provide support for the GNU gettext |
| dnl functionality. |
| dnl Please note that the actual code of the GNU gettext library is covered |
| dnl by the GNU Lesser General Public License, and the rest of the GNU |
| dnl gettext package is covered by the GNU General Public License. |
| dnl They are *not* in the public domain. |
| |
| dnl Checks for special options needed on Mac OS X. |
| dnl Defines INTL_MACOSX_LIBS. |
| AC_DEFUN([gt_INTL_MACOSX], |
| [ |
| dnl Check for API introduced in Mac OS X 10.4. |
| AC_CACHE_CHECK([for CFPreferencesCopyAppValue], |
| [gt_cv_func_CFPreferencesCopyAppValue], |
| [gt_save_LIBS="$LIBS" |
| LIBS="$LIBS -Wl,-framework -Wl,CoreFoundation" |
| AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[#include <CoreFoundation/CFPreferences.h>]], |
| [[CFPreferencesCopyAppValue(NULL, NULL)]])], |
| [gt_cv_func_CFPreferencesCopyAppValue=yes], |
| [gt_cv_func_CFPreferencesCopyAppValue=no]) |
| LIBS="$gt_save_LIBS"]) |
| if test $gt_cv_func_CFPreferencesCopyAppValue = yes; then |
| AC_DEFINE([HAVE_CFPREFERENCESCOPYAPPVALUE], [1], |
| [Define to 1 if you have the Mac OS X function CFPreferencesCopyAppValue in the CoreFoundation framework.]) |
| fi |
| dnl Don't check for the API introduced in Mac OS X 10.5, CFLocaleCopyCurrent, |
| dnl because in macOS 10.13.4 it has the following behaviour: |
| dnl When two or more languages are specified in the |
| dnl "System Preferences > Language & Region > Preferred Languages" panel, |
| dnl it returns en_CC where CC is the territory (even when English is not among |
| dnl the preferred languages!). What we want instead is what |
| dnl CFLocaleCopyCurrent returned in earlier macOS releases and what |
| dnl CFPreferencesCopyAppValue still returns, namely ll_CC where ll is the |
| dnl first among the preferred languages and CC is the territory. |
| AC_CACHE_CHECK([for CFLocaleCopyPreferredLanguages], [gt_cv_func_CFLocaleCopyPreferredLanguages], |
| [gt_save_LIBS="$LIBS" |
| LIBS="$LIBS -Wl,-framework -Wl,CoreFoundation" |
| AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM( |
| [[#include <CoreFoundation/CFLocale.h>]], |
| [[CFLocaleCopyPreferredLanguages();]])], |
| [gt_cv_func_CFLocaleCopyPreferredLanguages=yes], |
| [gt_cv_func_CFLocaleCopyPreferredLanguages=no]) |
| LIBS="$gt_save_LIBS"]) |
| if test $gt_cv_func_CFLocaleCopyPreferredLanguages = yes; then |
| AC_DEFINE([HAVE_CFLOCALECOPYPREFERREDLANGUAGES], [1], |
| [Define to 1 if you have the Mac OS X function CFLocaleCopyPreferredLanguages in the CoreFoundation framework.]) |
| fi |
| INTL_MACOSX_LIBS= |
| if test $gt_cv_func_CFPreferencesCopyAppValue = yes \ |
| || test $gt_cv_func_CFLocaleCopyPreferredLanguages = yes; then |
| INTL_MACOSX_LIBS="-Wl,-framework -Wl,CoreFoundation" |
| fi |
| AC_SUBST([INTL_MACOSX_LIBS]) |
| ]) |
| |
| # lib-ld.m4 serial 9 |
| dnl Copyright (C) 1996-2003, 2009-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| |
| dnl Subroutines of libtool.m4, |
| dnl with replacements s/_*LT_PATH/AC_LIB_PROG/ and s/lt_/acl_/ to avoid |
| dnl collision with libtool.m4. |
| |
| dnl From libtool-2.4. Sets the variable with_gnu_ld to yes or no. |
| AC_DEFUN([AC_LIB_PROG_LD_GNU], |
| [AC_CACHE_CHECK([if the linker ($LD) is GNU ld], [acl_cv_prog_gnu_ld], |
| [# I'd rather use --version here, but apparently some GNU lds only accept -v. |
| case `$LD -v 2>&1 </dev/null` in |
| *GNU* | *'with BFD'*) |
| acl_cv_prog_gnu_ld=yes |
| ;; |
| *) |
| acl_cv_prog_gnu_ld=no |
| ;; |
| esac]) |
| with_gnu_ld=$acl_cv_prog_gnu_ld |
| ]) |
| |
| dnl From libtool-2.4. Sets the variable LD. |
| AC_DEFUN([AC_LIB_PROG_LD], |
| [AC_REQUIRE([AC_PROG_CC])dnl |
| AC_REQUIRE([AC_CANONICAL_HOST])dnl |
| |
| AC_ARG_WITH([gnu-ld], |
| [AS_HELP_STRING([--with-gnu-ld], |
| [assume the C compiler uses GNU ld [default=no]])], |
| [test "$withval" = no || with_gnu_ld=yes], |
| [with_gnu_ld=no])dnl |
| |
| # Prepare PATH_SEPARATOR. |
| # The user is always right. |
| if test "${PATH_SEPARATOR+set}" != set; then |
| # Determine PATH_SEPARATOR by trying to find /bin/sh in a PATH which |
| # contains only /bin. Note that ksh looks also at the FPATH variable, |
| # so we have to set that as well for the test. |
| PATH_SEPARATOR=: |
| (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \ |
| && { (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \ |
| || PATH_SEPARATOR=';' |
| } |
| fi |
| |
| if test -n "$LD"; then |
| AC_MSG_CHECKING([for ld]) |
| elif test "$GCC" = yes; then |
| AC_MSG_CHECKING([for ld used by $CC]) |
| elif test "$with_gnu_ld" = yes; then |
| AC_MSG_CHECKING([for GNU ld]) |
| else |
| AC_MSG_CHECKING([for non-GNU ld]) |
| fi |
| if test -n "$LD"; then |
| # Let the user override the test with a path. |
| : |
| else |
| AC_CACHE_VAL([acl_cv_path_LD], |
| [ |
| acl_cv_path_LD= # Final result of this test |
| ac_prog=ld # Program to search in $PATH |
| if test "$GCC" = yes; then |
| # Check if gcc -print-prog-name=ld gives a path. |
| case $host in |
| *-*-mingw*) |
| # gcc leaves a trailing carriage return which upsets mingw |
| acl_output=`($CC -print-prog-name=ld) 2>&5 | tr -d '\015'` ;; |
| *) |
| acl_output=`($CC -print-prog-name=ld) 2>&5` ;; |
| esac |
| case $acl_output in |
| # Accept absolute paths. |
| [[\\/]]* | ?:[[\\/]]*) |
| re_direlt='/[[^/]][[^/]]*/\.\./' |
| # Canonicalize the pathname of ld |
| acl_output=`echo "$acl_output" | sed 's%\\\\%/%g'` |
| while echo "$acl_output" | grep "$re_direlt" > /dev/null 2>&1; do |
| acl_output=`echo $acl_output | sed "s%$re_direlt%/%"` |
| done |
| # Got the pathname. No search in PATH is needed. |
| acl_cv_path_LD="$acl_output" |
| ac_prog= |
| ;; |
| "") |
| # If it fails, then pretend we aren't using GCC. |
| ;; |
| *) |
| # If it is relative, then search for the first ld in PATH. |
| with_gnu_ld=unknown |
| ;; |
| esac |
| fi |
| if test -n "$ac_prog"; then |
| # Search for $ac_prog in $PATH. |
| acl_save_ifs="$IFS"; IFS=$PATH_SEPARATOR |
| for ac_dir in $PATH; do |
| IFS="$acl_save_ifs" |
| test -z "$ac_dir" && ac_dir=. |
| if test -f "$ac_dir/$ac_prog" || test -f "$ac_dir/$ac_prog$ac_exeext"; then |
| acl_cv_path_LD="$ac_dir/$ac_prog" |
| # Check to see if the program is GNU ld. I'd rather use --version, |
| # but apparently some variants of GNU ld only accept -v. |
| # Break only if it was the GNU/non-GNU ld that we prefer. |
| case `"$acl_cv_path_LD" -v 2>&1 </dev/null` in |
| *GNU* | *'with BFD'*) |
| test "$with_gnu_ld" != no && break |
| ;; |
| *) |
| test "$with_gnu_ld" != yes && break |
| ;; |
| esac |
| fi |
| done |
| IFS="$acl_save_ifs" |
| fi |
| case $host in |
| *-*-aix*) |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __powerpc64__ || defined _ARCH_PPC64 |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [# The compiler produces 64-bit code. Add option '-b64' so that the |
| # linker groks 64-bit object files. |
| case "$acl_cv_path_LD " in |
| *" -b64 "*) ;; |
| *) acl_cv_path_LD="$acl_cv_path_LD -b64" ;; |
| esac |
| ], []) |
| ;; |
| sparc64-*-netbsd*) |
| AC_COMPILE_IFELSE( |
| [AC_LANG_SOURCE( |
| [[#if defined __sparcv9 || defined __arch64__ |
| int ok; |
| #else |
| error fail |
| #endif |
| ]])], |
| [], |
| [# The compiler produces 32-bit code. Add option '-m elf32_sparc' |
| # so that the linker groks 32-bit object files. |
| case "$acl_cv_path_LD " in |
| *" -m elf32_sparc "*) ;; |
| *) acl_cv_path_LD="$acl_cv_path_LD -m elf32_sparc" ;; |
| esac |
| ]) |
| ;; |
| esac |
| ]) |
| LD="$acl_cv_path_LD" |
| fi |
| if test -n "$LD"; then |
| AC_MSG_RESULT([$LD]) |
| else |
| AC_MSG_RESULT([no]) |
| AC_MSG_ERROR([no acceptable ld found in \$PATH]) |
| fi |
| AC_LIB_PROG_LD_GNU |
| ]) |
| |
| # lib-link.m4 serial 31 |
| dnl Copyright (C) 2001-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| |
| dnl From Bruno Haible. |
| |
| AC_PREREQ([2.61]) |
| |
| dnl AC_LIB_LINKFLAGS(name [, dependencies]) searches for libname and |
| dnl the libraries corresponding to explicit and implicit dependencies. |
| dnl Sets and AC_SUBSTs the LIB${NAME} and LTLIB${NAME} variables and |
| dnl augments the CPPFLAGS variable. |
| dnl Sets and AC_SUBSTs the LIB${NAME}_PREFIX variable to nonempty if libname |
| dnl was found in ${LIB${NAME}_PREFIX}/$acl_libdirstem. |
| AC_DEFUN([AC_LIB_LINKFLAGS], |
| [ |
| AC_REQUIRE([AC_LIB_PREPARE_PREFIX]) |
| AC_REQUIRE([AC_LIB_RPATH]) |
| pushdef([Name],[m4_translit([$1],[./+-], [____])]) |
| pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-], |
| [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])]) |
| AC_CACHE_CHECK([how to link with lib[]$1], [ac_cv_lib[]Name[]_libs], [ |
| AC_LIB_LINKFLAGS_BODY([$1], [$2]) |
| ac_cv_lib[]Name[]_libs="$LIB[]NAME" |
| ac_cv_lib[]Name[]_ltlibs="$LTLIB[]NAME" |
| ac_cv_lib[]Name[]_cppflags="$INC[]NAME" |
| ac_cv_lib[]Name[]_prefix="$LIB[]NAME[]_PREFIX" |
| ]) |
| LIB[]NAME="$ac_cv_lib[]Name[]_libs" |
| LTLIB[]NAME="$ac_cv_lib[]Name[]_ltlibs" |
| INC[]NAME="$ac_cv_lib[]Name[]_cppflags" |
| LIB[]NAME[]_PREFIX="$ac_cv_lib[]Name[]_prefix" |
| AC_LIB_APPENDTOVAR([CPPFLAGS], [$INC]NAME) |
| AC_SUBST([LIB]NAME) |
| AC_SUBST([LTLIB]NAME) |
| AC_SUBST([LIB]NAME[_PREFIX]) |
| dnl Also set HAVE_LIB[]NAME so that AC_LIB_HAVE_LINKFLAGS can reuse the |
| dnl results of this search when this library appears as a dependency. |
| HAVE_LIB[]NAME=yes |
| popdef([NAME]) |
| popdef([Name]) |
| ]) |
| |
| dnl AC_LIB_HAVE_LINKFLAGS(name, dependencies, includes, testcode, [missing-message]) |
| dnl searches for libname and the libraries corresponding to explicit and |
| dnl implicit dependencies, together with the specified include files and |
| dnl the ability to compile and link the specified testcode. The missing-message |
| dnl defaults to 'no' and may contain additional hints for the user. |
| dnl If found, it sets and AC_SUBSTs HAVE_LIB${NAME}=yes and the LIB${NAME} |
| dnl and LTLIB${NAME} variables and augments the CPPFLAGS variable, and |
| dnl #defines HAVE_LIB${NAME} to 1. Otherwise, it sets and AC_SUBSTs |
| dnl HAVE_LIB${NAME}=no and LIB${NAME} and LTLIB${NAME} to empty. |
| dnl Sets and AC_SUBSTs the LIB${NAME}_PREFIX variable to nonempty if libname |
| dnl was found in ${LIB${NAME}_PREFIX}/$acl_libdirstem. |
| AC_DEFUN([AC_LIB_HAVE_LINKFLAGS], |
| [ |
| AC_REQUIRE([AC_LIB_PREPARE_PREFIX]) |
| AC_REQUIRE([AC_LIB_RPATH]) |
| pushdef([Name],[m4_translit([$1],[./+-], [____])]) |
| pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-], |
| [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])]) |
| |
| dnl Search for lib[]Name and define LIB[]NAME, LTLIB[]NAME and INC[]NAME |
| dnl accordingly. |
| AC_LIB_LINKFLAGS_BODY([$1], [$2]) |
| |
| dnl Add $INC[]NAME to CPPFLAGS before performing the following checks, |
| dnl because if the user has installed lib[]Name and not disabled its use |
| dnl via --without-lib[]Name-prefix, he wants to use it. |
| ac_save_CPPFLAGS="$CPPFLAGS" |
| AC_LIB_APPENDTOVAR([CPPFLAGS], [$INC]NAME) |
| |
| AC_CACHE_CHECK([for lib[]$1], [ac_cv_lib[]Name], [ |
| ac_save_LIBS="$LIBS" |
| dnl If $LIB[]NAME contains some -l options, add it to the end of LIBS, |
| dnl because these -l options might require -L options that are present in |
| dnl LIBS. -l options benefit only from the -L options listed before it. |
| dnl Otherwise, add it to the front of LIBS, because it may be a static |
| dnl library that depends on another static library that is present in LIBS. |
| dnl Static libraries benefit only from the static libraries listed after |
| dnl it. |
| case " $LIB[]NAME" in |
| *" -l"*) LIBS="$LIBS $LIB[]NAME" ;; |
| *) LIBS="$LIB[]NAME $LIBS" ;; |
| esac |
| AC_LINK_IFELSE( |
| [AC_LANG_PROGRAM([[$3]], [[$4]])], |
| [ac_cv_lib[]Name=yes], |
| [ac_cv_lib[]Name='m4_if([$5], [], [no], [[$5]])']) |
| LIBS="$ac_save_LIBS" |
| ]) |
| if test "$ac_cv_lib[]Name" = yes; then |
| HAVE_LIB[]NAME=yes |
| AC_DEFINE([HAVE_LIB]NAME, 1, [Define if you have the lib][$1 library.]) |
| AC_MSG_CHECKING([how to link with lib[]$1]) |
| AC_MSG_RESULT([$LIB[]NAME]) |
| else |
| HAVE_LIB[]NAME=no |
| dnl If $LIB[]NAME didn't lead to a usable library, we don't need |
| dnl $INC[]NAME either. |
| CPPFLAGS="$ac_save_CPPFLAGS" |
| LIB[]NAME= |
| LTLIB[]NAME= |
| LIB[]NAME[]_PREFIX= |
| fi |
| AC_SUBST([HAVE_LIB]NAME) |
| AC_SUBST([LIB]NAME) |
| AC_SUBST([LTLIB]NAME) |
| AC_SUBST([LIB]NAME[_PREFIX]) |
| popdef([NAME]) |
| popdef([Name]) |
| ]) |
| |
| dnl Determine the platform dependent parameters needed to use rpath: |
| dnl acl_libext, |
| dnl acl_shlibext, |
| dnl acl_libname_spec, |
| dnl acl_library_names_spec, |
| dnl acl_hardcode_libdir_flag_spec, |
| dnl acl_hardcode_libdir_separator, |
| dnl acl_hardcode_direct, |
| dnl acl_hardcode_minus_L. |
| AC_DEFUN([AC_LIB_RPATH], |
| [ |
| dnl Complain if config.rpath is missing. |
| AC_REQUIRE_AUX_FILE([config.rpath]) |
| AC_REQUIRE([AC_PROG_CC]) dnl we use $CC, $GCC, $LDFLAGS |
| AC_REQUIRE([AC_LIB_PROG_LD]) dnl we use $LD, $with_gnu_ld |
| AC_REQUIRE([AC_CANONICAL_HOST]) dnl we use $host |
| AC_REQUIRE([AC_CONFIG_AUX_DIR_DEFAULT]) dnl we use $ac_aux_dir |
| AC_CACHE_CHECK([for shared library run path origin], [acl_cv_rpath], [ |
| CC="$CC" GCC="$GCC" LDFLAGS="$LDFLAGS" LD="$LD" with_gnu_ld="$with_gnu_ld" \ |
| ${CONFIG_SHELL-/bin/sh} "$ac_aux_dir/config.rpath" "$host" > conftest.sh |
| . ./conftest.sh |
| rm -f ./conftest.sh |
| acl_cv_rpath=done |
| ]) |
| wl="$acl_cv_wl" |
| acl_libext="$acl_cv_libext" |
| acl_shlibext="$acl_cv_shlibext" |
| acl_libname_spec="$acl_cv_libname_spec" |
| acl_library_names_spec="$acl_cv_library_names_spec" |
| acl_hardcode_libdir_flag_spec="$acl_cv_hardcode_libdir_flag_spec" |
| acl_hardcode_libdir_separator="$acl_cv_hardcode_libdir_separator" |
| acl_hardcode_direct="$acl_cv_hardcode_direct" |
| acl_hardcode_minus_L="$acl_cv_hardcode_minus_L" |
| dnl Determine whether the user wants rpath handling at all. |
| AC_ARG_ENABLE([rpath], |
| [ --disable-rpath do not hardcode runtime library paths], |
| :, enable_rpath=yes) |
| ]) |
| |
| dnl AC_LIB_FROMPACKAGE(name, package) |
| dnl declares that libname comes from the given package. The configure file |
| dnl will then not have a --with-libname-prefix option but a |
| dnl --with-package-prefix option. Several libraries can come from the same |
| dnl package. This declaration must occur before an AC_LIB_LINKFLAGS or similar |
| dnl macro call that searches for libname. |
| AC_DEFUN([AC_LIB_FROMPACKAGE], |
| [ |
| pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-], |
| [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])]) |
| define([acl_frompackage_]NAME, [$2]) |
| popdef([NAME]) |
| pushdef([PACK],[$2]) |
| pushdef([PACKUP],[m4_translit(PACK,[abcdefghijklmnopqrstuvwxyz./+-], |
| [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])]) |
| define([acl_libsinpackage_]PACKUP, |
| m4_ifdef([acl_libsinpackage_]PACKUP, [m4_defn([acl_libsinpackage_]PACKUP)[, ]],)[lib$1]) |
| popdef([PACKUP]) |
| popdef([PACK]) |
| ]) |
| |
| dnl AC_LIB_LINKFLAGS_BODY(name [, dependencies]) searches for libname and |
| dnl the libraries corresponding to explicit and implicit dependencies. |
| dnl Sets the LIB${NAME}, LTLIB${NAME} and INC${NAME} variables. |
| dnl Also, sets the LIB${NAME}_PREFIX variable to nonempty if libname was found |
| dnl in ${LIB${NAME}_PREFIX}/$acl_libdirstem. |
| AC_DEFUN([AC_LIB_LINKFLAGS_BODY], |
| [ |
| AC_REQUIRE([AC_LIB_PREPARE_MULTILIB]) |
| pushdef([NAME],[m4_translit([$1],[abcdefghijklmnopqrstuvwxyz./+-], |
| [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])]) |
| pushdef([PACK],[m4_ifdef([acl_frompackage_]NAME, [acl_frompackage_]NAME, lib[$1])]) |
| pushdef([PACKUP],[m4_translit(PACK,[abcdefghijklmnopqrstuvwxyz./+-], |
| [ABCDEFGHIJKLMNOPQRSTUVWXYZ____])]) |
| pushdef([PACKLIBS],[m4_ifdef([acl_frompackage_]NAME, [acl_libsinpackage_]PACKUP, lib[$1])]) |
| dnl By default, look in $includedir and $libdir. |
| use_additional=yes |
| AC_LIB_WITH_FINAL_PREFIX([ |
| eval additional_includedir=\"$includedir\" |
| eval additional_libdir=\"$libdir\" |
| eval additional_libdir2=\"$exec_prefix/$acl_libdirstem2\" |
| eval additional_libdir3=\"$exec_prefix/$acl_libdirstem3\" |
| ]) |
| AC_ARG_WITH(PACK[-prefix], |
| [[ --with-]]PACK[[-prefix[=DIR] search for ]PACKLIBS[ in DIR/include and DIR/lib |
| --without-]]PACK[[-prefix don't search for ]PACKLIBS[ in includedir and libdir]], |
| [ |
| if test "X$withval" = "Xno"; then |
| use_additional=no |
| else |
| if test "X$withval" = "X"; then |
| AC_LIB_WITH_FINAL_PREFIX([ |
| eval additional_includedir=\"$includedir\" |
| eval additional_libdir=\"$libdir\" |
| eval additional_libdir2=\"$exec_prefix/$acl_libdirstem2\" |
| eval additional_libdir3=\"$exec_prefix/$acl_libdirstem3\" |
| ]) |
| else |
| additional_includedir="$withval/include" |
| additional_libdir="$withval/$acl_libdirstem" |
| additional_libdir2="$withval/$acl_libdirstem2" |
| additional_libdir3="$withval/$acl_libdirstem3" |
| fi |
| fi |
| ]) |
| if test "X$additional_libdir2" = "X$additional_libdir"; then |
| additional_libdir2= |
| fi |
| if test "X$additional_libdir3" = "X$additional_libdir"; then |
| additional_libdir3= |
| fi |
| dnl Search the library and its dependencies in $additional_libdir and |
| dnl $LDFLAGS. Using breadth-first-seach. |
| LIB[]NAME= |
| LTLIB[]NAME= |
| INC[]NAME= |
| LIB[]NAME[]_PREFIX= |
| dnl HAVE_LIB${NAME} is an indicator that LIB${NAME}, LTLIB${NAME} have been |
| dnl computed. So it has to be reset here. |
| HAVE_LIB[]NAME= |
| rpathdirs= |
| ltrpathdirs= |
| names_already_handled= |
| names_next_round='$1 $2' |
| while test -n "$names_next_round"; do |
| names_this_round="$names_next_round" |
| names_next_round= |
| for name in $names_this_round; do |
| already_handled= |
| for n in $names_already_handled; do |
| if test "$n" = "$name"; then |
| already_handled=yes |
| break |
| fi |
| done |
| if test -z "$already_handled"; then |
| names_already_handled="$names_already_handled $name" |
| dnl See if it was already located by an earlier AC_LIB_LINKFLAGS |
| dnl or AC_LIB_HAVE_LINKFLAGS call. |
| uppername=`echo "$name" | sed -e 'y|abcdefghijklmnopqrstuvwxyz./+-|ABCDEFGHIJKLMNOPQRSTUVWXYZ____|'` |
| eval value=\"\$HAVE_LIB$uppername\" |
| if test -n "$value"; then |
| if test "$value" = yes; then |
| eval value=\"\$LIB$uppername\" |
| test -z "$value" || LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$value" |
| eval value=\"\$LTLIB$uppername\" |
| test -z "$value" || LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }$value" |
| else |
| dnl An earlier call to AC_LIB_HAVE_LINKFLAGS has determined |
| dnl that this library doesn't exist. So just drop it. |
| : |
| fi |
| else |
| dnl Search the library lib$name in $additional_libdir and $LDFLAGS |
| dnl and the already constructed $LIBNAME/$LTLIBNAME. |
| found_dir= |
| found_la= |
| found_so= |
| found_a= |
| eval libname=\"$acl_libname_spec\" # typically: libname=lib$name |
| if test -n "$acl_shlibext"; then |
| shrext=".$acl_shlibext" # typically: shrext=.so |
| else |
| shrext= |
| fi |
| if test $use_additional = yes; then |
| for additional_libdir_variable in additional_libdir additional_libdir2 additional_libdir3; do |
| if test "X$found_dir" = "X"; then |
| eval dir=\$$additional_libdir_variable |
| if test -n "$dir"; then |
| dnl The same code as in the loop below: |
| dnl First look for a shared library. |
| if test -n "$acl_shlibext"; then |
| if test -f "$dir/$libname$shrext" && acl_is_expected_elfclass < "$dir/$libname$shrext"; then |
| found_dir="$dir" |
| found_so="$dir/$libname$shrext" |
| else |
| if test "$acl_library_names_spec" = '$libname$shrext$versuffix'; then |
| ver=`(cd "$dir" && \ |
| for f in "$libname$shrext".*; do echo "$f"; done \ |
| | sed -e "s,^$libname$shrext\\\\.,," \ |
| | sort -t '.' -n -r -k1,1 -k2,2 -k3,3 -k4,4 -k5,5 \ |
| | sed 1q ) 2>/dev/null` |
| if test -n "$ver" && test -f "$dir/$libname$shrext.$ver" && acl_is_expected_elfclass < "$dir/$libname$shrext.$ver"; then |
| found_dir="$dir" |
| found_so="$dir/$libname$shrext.$ver" |
| fi |
| else |
| eval library_names=\"$acl_library_names_spec\" |
| for f in $library_names; do |
| if test -f "$dir/$f" && acl_is_expected_elfclass < "$dir/$f"; then |
| found_dir="$dir" |
| found_so="$dir/$f" |
| break |
| fi |
| done |
| fi |
| fi |
| fi |
| dnl Then look for a static library. |
| if test "X$found_dir" = "X"; then |
| if test -f "$dir/$libname.$acl_libext" && ${AR-ar} -p "$dir/$libname.$acl_libext" | acl_is_expected_elfclass; then |
| found_dir="$dir" |
| found_a="$dir/$libname.$acl_libext" |
| fi |
| fi |
| if test "X$found_dir" != "X"; then |
| if test -f "$dir/$libname.la"; then |
| found_la="$dir/$libname.la" |
| fi |
| fi |
| fi |
| fi |
| done |
| fi |
| if test "X$found_dir" = "X"; then |
| for x in $LDFLAGS $LTLIB[]NAME; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| case "$x" in |
| -L*) |
| dir=`echo "X$x" | sed -e 's/^X-L//'` |
| dnl First look for a shared library. |
| if test -n "$acl_shlibext"; then |
| if test -f "$dir/$libname$shrext" && acl_is_expected_elfclass < "$dir/$libname$shrext"; then |
| found_dir="$dir" |
| found_so="$dir/$libname$shrext" |
| else |
| if test "$acl_library_names_spec" = '$libname$shrext$versuffix'; then |
| ver=`(cd "$dir" && \ |
| for f in "$libname$shrext".*; do echo "$f"; done \ |
| | sed -e "s,^$libname$shrext\\\\.,," \ |
| | sort -t '.' -n -r -k1,1 -k2,2 -k3,3 -k4,4 -k5,5 \ |
| | sed 1q ) 2>/dev/null` |
| if test -n "$ver" && test -f "$dir/$libname$shrext.$ver" && acl_is_expected_elfclass < "$dir/$libname$shrext.$ver"; then |
| found_dir="$dir" |
| found_so="$dir/$libname$shrext.$ver" |
| fi |
| else |
| eval library_names=\"$acl_library_names_spec\" |
| for f in $library_names; do |
| if test -f "$dir/$f" && acl_is_expected_elfclass < "$dir/$f"; then |
| found_dir="$dir" |
| found_so="$dir/$f" |
| break |
| fi |
| done |
| fi |
| fi |
| fi |
| dnl Then look for a static library. |
| if test "X$found_dir" = "X"; then |
| if test -f "$dir/$libname.$acl_libext" && ${AR-ar} -p "$dir/$libname.$acl_libext" | acl_is_expected_elfclass; then |
| found_dir="$dir" |
| found_a="$dir/$libname.$acl_libext" |
| fi |
| fi |
| if test "X$found_dir" != "X"; then |
| if test -f "$dir/$libname.la"; then |
| found_la="$dir/$libname.la" |
| fi |
| fi |
| ;; |
| esac |
| if test "X$found_dir" != "X"; then |
| break |
| fi |
| done |
| fi |
| if test "X$found_dir" != "X"; then |
| dnl Found the library. |
| LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }-L$found_dir -l$name" |
| if test "X$found_so" != "X"; then |
| dnl Linking with a shared library. We attempt to hardcode its |
| dnl directory into the executable's runpath, unless it's the |
| dnl standard /usr/lib. |
| if test "$enable_rpath" = no \ |
| || test "X$found_dir" = "X/usr/$acl_libdirstem" \ |
| || test "X$found_dir" = "X/usr/$acl_libdirstem2" \ |
| || test "X$found_dir" = "X/usr/$acl_libdirstem3"; then |
| dnl No hardcoding is needed. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$found_so" |
| else |
| dnl Use an explicit option to hardcode DIR into the resulting |
| dnl binary. |
| dnl Potentially add DIR to ltrpathdirs. |
| dnl The ltrpathdirs will be appended to $LTLIBNAME at the end. |
| haveit= |
| for x in $ltrpathdirs; do |
| if test "X$x" = "X$found_dir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| ltrpathdirs="$ltrpathdirs $found_dir" |
| fi |
| dnl The hardcoding into $LIBNAME is system dependent. |
| if test "$acl_hardcode_direct" = yes; then |
| dnl Using DIR/libNAME.so during linking hardcodes DIR into the |
| dnl resulting binary. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$found_so" |
| else |
| if test -n "$acl_hardcode_libdir_flag_spec" && test "$acl_hardcode_minus_L" = no; then |
| dnl Use an explicit option to hardcode DIR into the resulting |
| dnl binary. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$found_so" |
| dnl Potentially add DIR to rpathdirs. |
| dnl The rpathdirs will be appended to $LIBNAME at the end. |
| haveit= |
| for x in $rpathdirs; do |
| if test "X$x" = "X$found_dir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| rpathdirs="$rpathdirs $found_dir" |
| fi |
| else |
| dnl Rely on "-L$found_dir". |
| dnl But don't add it if it's already contained in the LDFLAGS |
| dnl or the already constructed $LIBNAME |
| haveit= |
| for x in $LDFLAGS $LIB[]NAME; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| if test "X$x" = "X-L$found_dir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }-L$found_dir" |
| fi |
| if test "$acl_hardcode_minus_L" != no; then |
| dnl FIXME: Not sure whether we should use |
| dnl "-L$found_dir -l$name" or "-L$found_dir $found_so" |
| dnl here. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$found_so" |
| else |
| dnl We cannot use $acl_hardcode_runpath_var and LD_RUN_PATH |
| dnl here, because this doesn't fit in flags passed to the |
| dnl compiler. So give up. No hardcoding. This affects only |
| dnl very old systems. |
| dnl FIXME: Not sure whether we should use |
| dnl "-L$found_dir -l$name" or "-L$found_dir $found_so" |
| dnl here. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }-l$name" |
| fi |
| fi |
| fi |
| fi |
| else |
| if test "X$found_a" != "X"; then |
| dnl Linking with a static library. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$found_a" |
| else |
| dnl We shouldn't come here, but anyway it's good to have a |
| dnl fallback. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }-L$found_dir -l$name" |
| fi |
| fi |
| dnl Assume the include files are nearby. |
| additional_includedir= |
| case "$found_dir" in |
| */$acl_libdirstem | */$acl_libdirstem/) |
| basedir=`echo "X$found_dir" | sed -e 's,^X,,' -e "s,/$acl_libdirstem/"'*$,,'` |
| if test "$name" = '$1'; then |
| LIB[]NAME[]_PREFIX="$basedir" |
| fi |
| additional_includedir="$basedir/include" |
| ;; |
| */$acl_libdirstem2 | */$acl_libdirstem2/) |
| basedir=`echo "X$found_dir" | sed -e 's,^X,,' -e "s,/$acl_libdirstem2/"'*$,,'` |
| if test "$name" = '$1'; then |
| LIB[]NAME[]_PREFIX="$basedir" |
| fi |
| additional_includedir="$basedir/include" |
| ;; |
| */$acl_libdirstem3 | */$acl_libdirstem3/) |
| basedir=`echo "X$found_dir" | sed -e 's,^X,,' -e "s,/$acl_libdirstem3/"'*$,,'` |
| if test "$name" = '$1'; then |
| LIB[]NAME[]_PREFIX="$basedir" |
| fi |
| additional_includedir="$basedir/include" |
| ;; |
| esac |
| if test "X$additional_includedir" != "X"; then |
| dnl Potentially add $additional_includedir to $INCNAME. |
| dnl But don't add it |
| dnl 1. if it's the standard /usr/include, |
| dnl 2. if it's /usr/local/include and we are using GCC on Linux, |
| dnl 3. if it's already present in $CPPFLAGS or the already |
| dnl constructed $INCNAME, |
| dnl 4. if it doesn't exist as a directory. |
| if test "X$additional_includedir" != "X/usr/include"; then |
| haveit= |
| if test "X$additional_includedir" = "X/usr/local/include"; then |
| if test -n "$GCC"; then |
| case $host_os in |
| linux* | gnu* | k*bsd*-gnu) haveit=yes;; |
| esac |
| fi |
| fi |
| if test -z "$haveit"; then |
| for x in $CPPFLAGS $INC[]NAME; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| if test "X$x" = "X-I$additional_includedir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| if test -d "$additional_includedir"; then |
| dnl Really add $additional_includedir to $INCNAME. |
| INC[]NAME="${INC[]NAME}${INC[]NAME:+ }-I$additional_includedir" |
| fi |
| fi |
| fi |
| fi |
| fi |
| dnl Look for dependencies. |
| if test -n "$found_la"; then |
| dnl Read the .la file. It defines the variables |
| dnl dlname, library_names, old_library, dependency_libs, current, |
| dnl age, revision, installed, dlopen, dlpreopen, libdir. |
| save_libdir="$libdir" |
| case "$found_la" in |
| */* | *\\*) . "$found_la" ;; |
| *) . "./$found_la" ;; |
| esac |
| libdir="$save_libdir" |
| dnl We use only dependency_libs. |
| for dep in $dependency_libs; do |
| case "$dep" in |
| -L*) |
| dependency_libdir=`echo "X$dep" | sed -e 's/^X-L//'` |
| dnl Potentially add $dependency_libdir to $LIBNAME and $LTLIBNAME. |
| dnl But don't add it |
| dnl 1. if it's the standard /usr/lib, |
| dnl 2. if it's /usr/local/lib and we are using GCC on Linux, |
| dnl 3. if it's already present in $LDFLAGS or the already |
| dnl constructed $LIBNAME, |
| dnl 4. if it doesn't exist as a directory. |
| if test "X$dependency_libdir" != "X/usr/$acl_libdirstem" \ |
| && test "X$dependency_libdir" != "X/usr/$acl_libdirstem2" \ |
| && test "X$dependency_libdir" != "X/usr/$acl_libdirstem3"; then |
| haveit= |
| if test "X$dependency_libdir" = "X/usr/local/$acl_libdirstem" \ |
| || test "X$dependency_libdir" = "X/usr/local/$acl_libdirstem2" \ |
| || test "X$dependency_libdir" = "X/usr/local/$acl_libdirstem3"; then |
| if test -n "$GCC"; then |
| case $host_os in |
| linux* | gnu* | k*bsd*-gnu) haveit=yes;; |
| esac |
| fi |
| fi |
| if test -z "$haveit"; then |
| haveit= |
| for x in $LDFLAGS $LIB[]NAME; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| if test "X$x" = "X-L$dependency_libdir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| if test -d "$dependency_libdir"; then |
| dnl Really add $dependency_libdir to $LIBNAME. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }-L$dependency_libdir" |
| fi |
| fi |
| haveit= |
| for x in $LDFLAGS $LTLIB[]NAME; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| if test "X$x" = "X-L$dependency_libdir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| if test -d "$dependency_libdir"; then |
| dnl Really add $dependency_libdir to $LTLIBNAME. |
| LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }-L$dependency_libdir" |
| fi |
| fi |
| fi |
| fi |
| ;; |
| -R*) |
| dir=`echo "X$dep" | sed -e 's/^X-R//'` |
| if test "$enable_rpath" != no; then |
| dnl Potentially add DIR to rpathdirs. |
| dnl The rpathdirs will be appended to $LIBNAME at the end. |
| haveit= |
| for x in $rpathdirs; do |
| if test "X$x" = "X$dir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| rpathdirs="$rpathdirs $dir" |
| fi |
| dnl Potentially add DIR to ltrpathdirs. |
| dnl The ltrpathdirs will be appended to $LTLIBNAME at the end. |
| haveit= |
| for x in $ltrpathdirs; do |
| if test "X$x" = "X$dir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| ltrpathdirs="$ltrpathdirs $dir" |
| fi |
| fi |
| ;; |
| -l*) |
| dnl Handle this in the next round. |
| names_next_round="$names_next_round "`echo "X$dep" | sed -e 's/^X-l//'` |
| ;; |
| *.la) |
| dnl Handle this in the next round. Throw away the .la's |
| dnl directory; it is already contained in a preceding -L |
| dnl option. |
| names_next_round="$names_next_round "`echo "X$dep" | sed -e 's,^X.*/,,' -e 's,^lib,,' -e 's,\.la$,,'` |
| ;; |
| *) |
| dnl Most likely an immediate library name. |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$dep" |
| LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }$dep" |
| ;; |
| esac |
| done |
| fi |
| else |
| dnl Didn't find the library; assume it is in the system directories |
| dnl known to the linker and runtime loader. (All the system |
| dnl directories known to the linker should also be known to the |
| dnl runtime loader, otherwise the system is severely misconfigured.) |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }-l$name" |
| LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }-l$name" |
| fi |
| fi |
| fi |
| done |
| done |
| if test "X$rpathdirs" != "X"; then |
| if test -n "$acl_hardcode_libdir_separator"; then |
| dnl Weird platform: only the last -rpath option counts, the user must |
| dnl pass all path elements in one option. We can arrange that for a |
| dnl single library, but not when more than one $LIBNAMEs are used. |
| alldirs= |
| for found_dir in $rpathdirs; do |
| alldirs="${alldirs}${alldirs:+$acl_hardcode_libdir_separator}$found_dir" |
| done |
| dnl Note: acl_hardcode_libdir_flag_spec uses $libdir and $wl. |
| acl_save_libdir="$libdir" |
| libdir="$alldirs" |
| eval flag=\"$acl_hardcode_libdir_flag_spec\" |
| libdir="$acl_save_libdir" |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$flag" |
| else |
| dnl The -rpath options are cumulative. |
| for found_dir in $rpathdirs; do |
| acl_save_libdir="$libdir" |
| libdir="$found_dir" |
| eval flag=\"$acl_hardcode_libdir_flag_spec\" |
| libdir="$acl_save_libdir" |
| LIB[]NAME="${LIB[]NAME}${LIB[]NAME:+ }$flag" |
| done |
| fi |
| fi |
| if test "X$ltrpathdirs" != "X"; then |
| dnl When using libtool, the option that works for both libraries and |
| dnl executables is -R. The -R options are cumulative. |
| for found_dir in $ltrpathdirs; do |
| LTLIB[]NAME="${LTLIB[]NAME}${LTLIB[]NAME:+ }-R$found_dir" |
| done |
| fi |
| popdef([PACKLIBS]) |
| popdef([PACKUP]) |
| popdef([PACK]) |
| popdef([NAME]) |
| ]) |
| |
| dnl AC_LIB_APPENDTOVAR(VAR, CONTENTS) appends the elements of CONTENTS to VAR, |
| dnl unless already present in VAR. |
| dnl Works only for CPPFLAGS, not for LIB* variables because that sometimes |
| dnl contains two or three consecutive elements that belong together. |
| AC_DEFUN([AC_LIB_APPENDTOVAR], |
| [ |
| for element in [$2]; do |
| haveit= |
| for x in $[$1]; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| if test "X$x" = "X$element"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| [$1]="${[$1]}${[$1]:+ }$element" |
| fi |
| done |
| ]) |
| |
| dnl For those cases where a variable contains several -L and -l options |
| dnl referring to unknown libraries and directories, this macro determines the |
| dnl necessary additional linker options for the runtime path. |
| dnl AC_LIB_LINKFLAGS_FROM_LIBS([LDADDVAR], [LIBSVALUE], [USE-LIBTOOL]) |
| dnl sets LDADDVAR to linker options needed together with LIBSVALUE. |
| dnl If USE-LIBTOOL evaluates to non-empty, linking with libtool is assumed, |
| dnl otherwise linking without libtool is assumed. |
| AC_DEFUN([AC_LIB_LINKFLAGS_FROM_LIBS], |
| [ |
| AC_REQUIRE([AC_LIB_RPATH]) |
| AC_REQUIRE([AC_LIB_PREPARE_MULTILIB]) |
| $1= |
| if test "$enable_rpath" != no; then |
| if test -n "$acl_hardcode_libdir_flag_spec" && test "$acl_hardcode_minus_L" = no; then |
| dnl Use an explicit option to hardcode directories into the resulting |
| dnl binary. |
| rpathdirs= |
| next= |
| for opt in $2; do |
| if test -n "$next"; then |
| dir="$next" |
| dnl No need to hardcode the standard /usr/lib. |
| if test "X$dir" != "X/usr/$acl_libdirstem" \ |
| && test "X$dir" != "X/usr/$acl_libdirstem2" \ |
| && test "X$dir" != "X/usr/$acl_libdirstem3"; then |
| rpathdirs="$rpathdirs $dir" |
| fi |
| next= |
| else |
| case $opt in |
| -L) next=yes ;; |
| -L*) dir=`echo "X$opt" | sed -e 's,^X-L,,'` |
| dnl No need to hardcode the standard /usr/lib. |
| if test "X$dir" != "X/usr/$acl_libdirstem" \ |
| && test "X$dir" != "X/usr/$acl_libdirstem2" \ |
| && test "X$dir" != "X/usr/$acl_libdirstem3"; then |
| rpathdirs="$rpathdirs $dir" |
| fi |
| next= ;; |
| *) next= ;; |
| esac |
| fi |
| done |
| if test "X$rpathdirs" != "X"; then |
| if test -n ""$3""; then |
| dnl libtool is used for linking. Use -R options. |
| for dir in $rpathdirs; do |
| $1="${$1}${$1:+ }-R$dir" |
| done |
| else |
| dnl The linker is used for linking directly. |
| if test -n "$acl_hardcode_libdir_separator"; then |
| dnl Weird platform: only the last -rpath option counts, the user |
| dnl must pass all path elements in one option. |
| alldirs= |
| for dir in $rpathdirs; do |
| alldirs="${alldirs}${alldirs:+$acl_hardcode_libdir_separator}$dir" |
| done |
| acl_save_libdir="$libdir" |
| libdir="$alldirs" |
| eval flag=\"$acl_hardcode_libdir_flag_spec\" |
| libdir="$acl_save_libdir" |
| $1="$flag" |
| else |
| dnl The -rpath options are cumulative. |
| for dir in $rpathdirs; do |
| acl_save_libdir="$libdir" |
| libdir="$dir" |
| eval flag=\"$acl_hardcode_libdir_flag_spec\" |
| libdir="$acl_save_libdir" |
| $1="${$1}${$1:+ }$flag" |
| done |
| fi |
| fi |
| fi |
| fi |
| fi |
| AC_SUBST([$1]) |
| ]) |
| |
| # lib-prefix.m4 serial 17 |
| dnl Copyright (C) 2001-2005, 2008-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| |
| dnl From Bruno Haible. |
| |
| dnl AC_LIB_PREFIX adds to the CPPFLAGS and LDFLAGS the flags that are needed |
| dnl to access previously installed libraries. The basic assumption is that |
| dnl a user will want packages to use other packages he previously installed |
| dnl with the same --prefix option. |
| dnl This macro is not needed if only AC_LIB_LINKFLAGS is used to locate |
| dnl libraries, but is otherwise very convenient. |
| AC_DEFUN([AC_LIB_PREFIX], |
| [ |
| AC_BEFORE([$0], [AC_LIB_LINKFLAGS]) |
| AC_REQUIRE([AC_PROG_CC]) |
| AC_REQUIRE([AC_CANONICAL_HOST]) |
| AC_REQUIRE([AC_LIB_PREPARE_MULTILIB]) |
| AC_REQUIRE([AC_LIB_PREPARE_PREFIX]) |
| dnl By default, look in $includedir and $libdir. |
| use_additional=yes |
| AC_LIB_WITH_FINAL_PREFIX([ |
| eval additional_includedir=\"$includedir\" |
| eval additional_libdir=\"$libdir\" |
| ]) |
| AC_ARG_WITH([lib-prefix], |
| [[ --with-lib-prefix[=DIR] search for libraries in DIR/include and DIR/lib |
| --without-lib-prefix don't search for libraries in includedir and libdir]], |
| [ |
| if test "X$withval" = "Xno"; then |
| use_additional=no |
| else |
| if test "X$withval" = "X"; then |
| AC_LIB_WITH_FINAL_PREFIX([ |
| eval additional_includedir=\"$includedir\" |
| eval additional_libdir=\"$libdir\" |
| ]) |
| else |
| additional_includedir="$withval/include" |
| additional_libdir="$withval/$acl_libdirstem" |
| fi |
| fi |
| ]) |
| if test $use_additional = yes; then |
| dnl Potentially add $additional_includedir to $CPPFLAGS. |
| dnl But don't add it |
| dnl 1. if it's the standard /usr/include, |
| dnl 2. if it's already present in $CPPFLAGS, |
| dnl 3. if it's /usr/local/include and we are using GCC on Linux, |
| dnl 4. if it doesn't exist as a directory. |
| if test "X$additional_includedir" != "X/usr/include"; then |
| haveit= |
| for x in $CPPFLAGS; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| if test "X$x" = "X-I$additional_includedir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| if test "X$additional_includedir" = "X/usr/local/include"; then |
| if test -n "$GCC"; then |
| case $host_os in |
| linux* | gnu* | k*bsd*-gnu) haveit=yes;; |
| esac |
| fi |
| fi |
| if test -z "$haveit"; then |
| if test -d "$additional_includedir"; then |
| dnl Really add $additional_includedir to $CPPFLAGS. |
| CPPFLAGS="${CPPFLAGS}${CPPFLAGS:+ }-I$additional_includedir" |
| fi |
| fi |
| fi |
| fi |
| dnl Potentially add $additional_libdir to $LDFLAGS. |
| dnl But don't add it |
| dnl 1. if it's the standard /usr/lib, |
| dnl 2. if it's already present in $LDFLAGS, |
| dnl 3. if it's /usr/local/lib and we are using GCC on Linux, |
| dnl 4. if it doesn't exist as a directory. |
| if test "X$additional_libdir" != "X/usr/$acl_libdirstem"; then |
| haveit= |
| for x in $LDFLAGS; do |
| AC_LIB_WITH_FINAL_PREFIX([eval x=\"$x\"]) |
| if test "X$x" = "X-L$additional_libdir"; then |
| haveit=yes |
| break |
| fi |
| done |
| if test -z "$haveit"; then |
| if test "X$additional_libdir" = "X/usr/local/$acl_libdirstem"; then |
| if test -n "$GCC"; then |
| case $host_os in |
| linux*) haveit=yes;; |
| esac |
| fi |
| fi |
| if test -z "$haveit"; then |
| if test -d "$additional_libdir"; then |
| dnl Really add $additional_libdir to $LDFLAGS. |
| LDFLAGS="${LDFLAGS}${LDFLAGS:+ }-L$additional_libdir" |
| fi |
| fi |
| fi |
| fi |
| fi |
| ]) |
| |
| dnl AC_LIB_PREPARE_PREFIX creates variables acl_final_prefix, |
| dnl acl_final_exec_prefix, containing the values to which $prefix and |
| dnl $exec_prefix will expand at the end of the configure script. |
| AC_DEFUN([AC_LIB_PREPARE_PREFIX], |
| [ |
| dnl Unfortunately, prefix and exec_prefix get only finally determined |
| dnl at the end of configure. |
| if test "X$prefix" = "XNONE"; then |
| acl_final_prefix="$ac_default_prefix" |
| else |
| acl_final_prefix="$prefix" |
| fi |
| if test "X$exec_prefix" = "XNONE"; then |
| acl_final_exec_prefix='${prefix}' |
| else |
| acl_final_exec_prefix="$exec_prefix" |
| fi |
| acl_save_prefix="$prefix" |
| prefix="$acl_final_prefix" |
| eval acl_final_exec_prefix=\"$acl_final_exec_prefix\" |
| prefix="$acl_save_prefix" |
| ]) |
| |
| dnl AC_LIB_WITH_FINAL_PREFIX([statement]) evaluates statement, with the |
| dnl variables prefix and exec_prefix bound to the values they will have |
| dnl at the end of the configure script. |
| AC_DEFUN([AC_LIB_WITH_FINAL_PREFIX], |
| [ |
| acl_save_prefix="$prefix" |
| prefix="$acl_final_prefix" |
| acl_save_exec_prefix="$exec_prefix" |
| exec_prefix="$acl_final_exec_prefix" |
| $1 |
| exec_prefix="$acl_save_exec_prefix" |
| prefix="$acl_save_prefix" |
| ]) |
| |
| dnl AC_LIB_PREPARE_MULTILIB creates |
| dnl - a function acl_is_expected_elfclass, that tests whether standard input |
| dn; has a 32-bit or 64-bit ELF header, depending on the host CPU ABI, |
| dnl - 3 variables acl_libdirstem, acl_libdirstem2, acl_libdirstem3, containing |
| dnl the basename of the libdir to try in turn, either "lib" or "lib64" or |
| dnl "lib/64" or "lib32" or "lib/sparcv9" or "lib/amd64" or similar. |
| AC_DEFUN([AC_LIB_PREPARE_MULTILIB], |
| [ |
| dnl There is no formal standard regarding lib, lib32, and lib64. |
| dnl On most glibc systems, the current practice is that on a system supporting |
| dnl 32-bit and 64-bit instruction sets or ABIs, 64-bit libraries go under |
| dnl $prefix/lib64 and 32-bit libraries go under $prefix/lib. However, on |
| dnl Arch Linux based distributions, it's the opposite: 32-bit libraries go |
| dnl under $prefix/lib32 and 64-bit libraries go under $prefix/lib. |
| dnl We determine the compiler's default mode by looking at the compiler's |
| dnl library search path. If at least one of its elements ends in /lib64 or |
| dnl points to a directory whose absolute pathname ends in /lib64, we use that |
| dnl for 64-bit ABIs. Similarly for 32-bit ABIs. Otherwise we use the default, |
| dnl namely "lib". |
| dnl On Solaris systems, the current practice is that on a system supporting |
| dnl 32-bit and 64-bit instruction sets or ABIs, 64-bit libraries go under |
| dnl $prefix/lib/64 (which is a symlink to either $prefix/lib/sparcv9 or |
| dnl $prefix/lib/amd64) and 32-bit libraries go under $prefix/lib. |
| AC_REQUIRE([AC_CANONICAL_HOST]) |
| AC_REQUIRE([gl_HOST_CPU_C_ABI_32BIT]) |
| |
| AC_CACHE_CHECK([for ELF binary format], [gl_cv_elf], |
| [AC_EGREP_CPP([Extensible Linking Format], |
| [#ifdef __ELF__ |
| Extensible Linking Format |
| #endif |
| ], |
| [gl_cv_elf=yes], |
| [gl_cv_elf=no]) |
| ]) |
| if test $gl_cv_elf; then |
| # Extract the ELF class of a file (5th byte) in decimal. |
| # Cf. https://en.wikipedia.org/wiki/Executable_and_Linkable_Format#File_header |
| if od -A x < /dev/null >/dev/null 2>/dev/null; then |
| # Use POSIX od. |
| func_elfclass () |
| { |
| od -A n -t d1 -j 4 -N 1 |
| } |
| else |
| # Use BSD hexdump. |
| func_elfclass () |
| { |
| dd bs=1 count=1 skip=4 2>/dev/null | hexdump -e '1/1 "%3d "' |
| echo |
| } |
| fi |
| changequote(,)dnl |
| case $HOST_CPU_C_ABI_32BIT in |
| yes) |
| # 32-bit ABI. |
| acl_is_expected_elfclass () |
| { |
| test "`func_elfclass | sed -e 's/[ ]//g'`" = 1 |
| } |
| ;; |
| no) |
| # 64-bit ABI. |
| acl_is_expected_elfclass () |
| { |
| test "`func_elfclass | sed -e 's/[ ]//g'`" = 2 |
| } |
| ;; |
| *) |
| # Unknown. |
| acl_is_expected_elfclass () |
| { |
| : |
| } |
| ;; |
| esac |
| changequote([,])dnl |
| else |
| acl_is_expected_elfclass () |
| { |
| : |
| } |
| fi |
| |
| dnl Allow the user to override the result by setting acl_cv_libdirstems. |
| AC_CACHE_CHECK([for the common suffixes of directories in the library search path], |
| [acl_cv_libdirstems], |
| [dnl Try 'lib' first, because that's the default for libdir in GNU, see |
| dnl <https://www.gnu.org/prep/standards/html_node/Directory-Variables.html>. |
| acl_libdirstem=lib |
| acl_libdirstem2= |
| acl_libdirstem3= |
| case "$host_os" in |
| solaris*) |
| dnl See Solaris 10 Software Developer Collection > Solaris 64-bit Developer's Guide > The Development Environment |
| dnl <https://docs.oracle.com/cd/E19253-01/816-5138/dev-env/index.html>. |
| dnl "Portable Makefiles should refer to any library directories using the 64 symbolic link." |
| dnl But we want to recognize the sparcv9 or amd64 subdirectory also if the |
| dnl symlink is missing, so we set acl_libdirstem2 too. |
| if test $HOST_CPU_C_ABI_32BIT = no; then |
| acl_libdirstem2=lib/64 |
| case "$host_cpu" in |
| sparc*) acl_libdirstem3=lib/sparcv9 ;; |
| i*86 | x86_64) acl_libdirstem3=lib/amd64 ;; |
| esac |
| fi |
| ;; |
| *) |
| dnl If $CC generates code for a 32-bit ABI, the libraries are |
| dnl surely under $prefix/lib or $prefix/lib32, not $prefix/lib64. |
| dnl Similarly, if $CC generates code for a 64-bit ABI, the libraries |
| dnl are surely under $prefix/lib or $prefix/lib64, not $prefix/lib32. |
| dnl Find the compiler's search path. However, non-system compilers |
| dnl sometimes have odd library search paths. But we can't simply invoke |
| dnl '/usr/bin/gcc -print-search-dirs' because that would not take into |
| dnl account the -m32/-m31 or -m64 options from the $CC or $CFLAGS. |
| searchpath=`(LC_ALL=C $CC $CPPFLAGS $CFLAGS -print-search-dirs) 2>/dev/null \ |
| | sed -n -e 's,^libraries: ,,p' | sed -e 's,^=,,'` |
| if test $HOST_CPU_C_ABI_32BIT != no; then |
| # 32-bit or unknown ABI. |
| if test -d /usr/lib32; then |
| acl_libdirstem2=lib32 |
| fi |
| fi |
| if test $HOST_CPU_C_ABI_32BIT != yes; then |
| # 64-bit or unknown ABI. |
| if test -d /usr/lib64; then |
| acl_libdirstem3=lib64 |
| fi |
| fi |
| if test -n "$searchpath"; then |
| acl_save_IFS="${IFS= }"; IFS=":" |
| for searchdir in $searchpath; do |
| if test -d "$searchdir"; then |
| case "$searchdir" in |
| */lib32/ | */lib32 ) acl_libdirstem2=lib32 ;; |
| */lib64/ | */lib64 ) acl_libdirstem3=lib64 ;; |
| */../ | */.. ) |
| # Better ignore directories of this form. They are misleading. |
| ;; |
| *) searchdir=`cd "$searchdir" && pwd` |
| case "$searchdir" in |
| */lib32 ) acl_libdirstem2=lib32 ;; |
| */lib64 ) acl_libdirstem3=lib64 ;; |
| esac ;; |
| esac |
| fi |
| done |
| IFS="$acl_save_IFS" |
| if test $HOST_CPU_C_ABI_32BIT = yes; then |
| # 32-bit ABI. |
| acl_libdirstem3= |
| fi |
| if test $HOST_CPU_C_ABI_32BIT = no; then |
| # 64-bit ABI. |
| acl_libdirstem2= |
| fi |
| fi |
| ;; |
| esac |
| test -n "$acl_libdirstem2" || acl_libdirstem2="$acl_libdirstem" |
| test -n "$acl_libdirstem3" || acl_libdirstem3="$acl_libdirstem" |
| acl_cv_libdirstems="$acl_libdirstem,$acl_libdirstem2,$acl_libdirstem3" |
| ]) |
| dnl Decompose acl_cv_libdirstems into acl_libdirstem, acl_libdirstem2, and |
| dnl acl_libdirstem3. |
| changequote(,)dnl |
| acl_libdirstem=`echo "$acl_cv_libdirstems" | sed -e 's/,.*//'` |
| acl_libdirstem2=`echo "$acl_cv_libdirstems" | sed -e 's/^[^,]*,//' -e 's/,.*//'` |
| acl_libdirstem3=`echo "$acl_cv_libdirstems" | sed -e 's/^[^,]*,[^,]*,//' -e 's/,.*//'` |
| changequote([,])dnl |
| ]) |
| |
| # nls.m4 serial 6 (gettext-0.20.2) |
| dnl Copyright (C) 1995-2003, 2005-2006, 2008-2014, 2016, 2019-2020 Free |
| dnl Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| dnl |
| dnl This file can be used in projects which are not available under |
| dnl the GNU General Public License or the GNU Lesser General Public |
| dnl License but which still want to provide support for the GNU gettext |
| dnl functionality. |
| dnl Please note that the actual code of the GNU gettext library is covered |
| dnl by the GNU Lesser General Public License, and the rest of the GNU |
| dnl gettext package is covered by the GNU General Public License. |
| dnl They are *not* in the public domain. |
| |
| dnl Authors: |
| dnl Ulrich Drepper <drepper@cygnus.com>, 1995-2000. |
| dnl Bruno Haible <haible@clisp.cons.org>, 2000-2003. |
| |
| AC_PREREQ([2.50]) |
| |
| AC_DEFUN([AM_NLS], |
| [ |
| AC_MSG_CHECKING([whether NLS is requested]) |
| dnl Default is enabled NLS |
| AC_ARG_ENABLE([nls], |
| [ --disable-nls do not use Native Language Support], |
| USE_NLS=$enableval, USE_NLS=yes) |
| AC_MSG_RESULT([$USE_NLS]) |
| AC_SUBST([USE_NLS]) |
| ]) |
| |
| # pkg.m4 - Macros to locate and utilise pkg-config. -*- Autoconf -*- |
| # serial 12 (pkg-config-0.29.2) |
| |
| dnl Copyright © 2004 Scott James Remnant <scott@netsplit.com>. |
| dnl Copyright © 2012-2015 Dan Nicholson <dbn.lists@gmail.com> |
| dnl |
| dnl This program is free software; you can redistribute it and/or modify |
| dnl it under the terms of the GNU General Public License as published by |
| dnl the Free Software Foundation; either version 2 of the License, or |
| dnl (at your option) any later version. |
| dnl |
| dnl This program is distributed in the hope that it will be useful, but |
| dnl WITHOUT ANY WARRANTY; without even the implied warranty of |
| dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU |
| dnl General Public License for more details. |
| dnl |
| dnl You should have received a copy of the GNU General Public License |
| dnl along with this program; if not, write to the Free Software |
| dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA |
| dnl 02111-1307, USA. |
| dnl |
| dnl As a special exception to the GNU General Public License, if you |
| dnl distribute this file as part of a program that contains a |
| dnl configuration script generated by Autoconf, you may include it under |
| dnl the same distribution terms that you use for the rest of that |
| dnl program. |
| |
| dnl PKG_PREREQ(MIN-VERSION) |
| dnl ----------------------- |
| dnl Since: 0.29 |
| dnl |
| dnl Verify that the version of the pkg-config macros are at least |
| dnl MIN-VERSION. Unlike PKG_PROG_PKG_CONFIG, which checks the user's |
| dnl installed version of pkg-config, this checks the developer's version |
| dnl of pkg.m4 when generating configure. |
| dnl |
| dnl To ensure that this macro is defined, also add: |
| dnl m4_ifndef([PKG_PREREQ], |
| dnl [m4_fatal([must install pkg-config 0.29 or later before running autoconf/autogen])]) |
| dnl |
| dnl See the "Since" comment for each macro you use to see what version |
| dnl of the macros you require. |
| m4_defun([PKG_PREREQ], |
| [m4_define([PKG_MACROS_VERSION], [0.29.2]) |
| m4_if(m4_version_compare(PKG_MACROS_VERSION, [$1]), -1, |
| [m4_fatal([pkg.m4 version $1 or higher is required but ]PKG_MACROS_VERSION[ found])]) |
| ])dnl PKG_PREREQ |
| |
| dnl PKG_PROG_PKG_CONFIG([MIN-VERSION]) |
| dnl ---------------------------------- |
| dnl Since: 0.16 |
| dnl |
| dnl Search for the pkg-config tool and set the PKG_CONFIG variable to |
| dnl first found in the path. Checks that the version of pkg-config found |
| dnl is at least MIN-VERSION. If MIN-VERSION is not specified, 0.9.0 is |
| dnl used since that's the first version where most current features of |
| dnl pkg-config existed. |
| AC_DEFUN([PKG_PROG_PKG_CONFIG], |
| [m4_pattern_forbid([^_?PKG_[A-Z_]+$]) |
| m4_pattern_allow([^PKG_CONFIG(_(PATH|LIBDIR|SYSROOT_DIR|ALLOW_SYSTEM_(CFLAGS|LIBS)))?$]) |
| m4_pattern_allow([^PKG_CONFIG_(DISABLE_UNINSTALLED|TOP_BUILD_DIR|DEBUG_SPEW)$]) |
| AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility]) |
| AC_ARG_VAR([PKG_CONFIG_PATH], [directories to add to pkg-config's search path]) |
| AC_ARG_VAR([PKG_CONFIG_LIBDIR], [path overriding pkg-config's built-in search path]) |
| |
| if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then |
| AC_PATH_TOOL([PKG_CONFIG], [pkg-config]) |
| fi |
| if test -n "$PKG_CONFIG"; then |
| _pkg_min_version=m4_default([$1], [0.9.0]) |
| AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version]) |
| if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then |
| AC_MSG_RESULT([yes]) |
| else |
| AC_MSG_RESULT([no]) |
| PKG_CONFIG="" |
| fi |
| fi[]dnl |
| ])dnl PKG_PROG_PKG_CONFIG |
| |
| dnl PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND]) |
| dnl ------------------------------------------------------------------- |
| dnl Since: 0.18 |
| dnl |
| dnl Check to see whether a particular set of modules exists. Similar to |
| dnl PKG_CHECK_MODULES(), but does not set variables or print errors. |
| dnl |
| dnl Please remember that m4 expands AC_REQUIRE([PKG_PROG_PKG_CONFIG]) |
| dnl only at the first occurence in configure.ac, so if the first place |
| dnl it's called might be skipped (such as if it is within an "if", you |
| dnl have to call PKG_CHECK_EXISTS manually |
| AC_DEFUN([PKG_CHECK_EXISTS], |
| [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl |
| if test -n "$PKG_CONFIG" && \ |
| AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then |
| m4_default([$2], [:]) |
| m4_ifvaln([$3], [else |
| $3])dnl |
| fi]) |
| |
| dnl _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES]) |
| dnl --------------------------------------------- |
| dnl Internal wrapper calling pkg-config via PKG_CONFIG and setting |
| dnl pkg_failed based on the result. |
| m4_define([_PKG_CONFIG], |
| [if test -n "$$1"; then |
| pkg_cv_[]$1="$$1" |
| elif test -n "$PKG_CONFIG"; then |
| PKG_CHECK_EXISTS([$3], |
| [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null` |
| test "x$?" != "x0" && pkg_failed=yes ], |
| [pkg_failed=yes]) |
| else |
| pkg_failed=untried |
| fi[]dnl |
| ])dnl _PKG_CONFIG |
| |
| dnl _PKG_SHORT_ERRORS_SUPPORTED |
| dnl --------------------------- |
| dnl Internal check to see if pkg-config supports short errors. |
| AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED], |
| [AC_REQUIRE([PKG_PROG_PKG_CONFIG]) |
| if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then |
| _pkg_short_errors_supported=yes |
| else |
| _pkg_short_errors_supported=no |
| fi[]dnl |
| ])dnl _PKG_SHORT_ERRORS_SUPPORTED |
| |
| |
| dnl PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND], |
| dnl [ACTION-IF-NOT-FOUND]) |
| dnl -------------------------------------------------------------- |
| dnl Since: 0.4.0 |
| dnl |
| dnl Note that if there is a possibility the first call to |
| dnl PKG_CHECK_MODULES might not happen, you should be sure to include an |
| dnl explicit call to PKG_PROG_PKG_CONFIG in your configure.ac |
| AC_DEFUN([PKG_CHECK_MODULES], |
| [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl |
| AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl |
| AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl |
| |
| pkg_failed=no |
| AC_MSG_CHECKING([for $2]) |
| |
| _PKG_CONFIG([$1][_CFLAGS], [cflags], [$2]) |
| _PKG_CONFIG([$1][_LIBS], [libs], [$2]) |
| |
| m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS |
| and $1[]_LIBS to avoid the need to call pkg-config. |
| See the pkg-config man page for more details.]) |
| |
| if test $pkg_failed = yes; then |
| AC_MSG_RESULT([no]) |
| _PKG_SHORT_ERRORS_SUPPORTED |
| if test $_pkg_short_errors_supported = yes; then |
| $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors --cflags --libs "$2" 2>&1` |
| else |
| $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors --cflags --libs "$2" 2>&1` |
| fi |
| # Put the nasty error message in config.log where it belongs |
| echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD |
| |
| m4_default([$4], [AC_MSG_ERROR( |
| [Package requirements ($2) were not met: |
| |
| $$1_PKG_ERRORS |
| |
| Consider adjusting the PKG_CONFIG_PATH environment variable if you |
| installed software in a non-standard prefix. |
| |
| _PKG_TEXT])[]dnl |
| ]) |
| elif test $pkg_failed = untried; then |
| AC_MSG_RESULT([no]) |
| m4_default([$4], [AC_MSG_FAILURE( |
| [The pkg-config script could not be found or is too old. Make sure it |
| is in your PATH or set the PKG_CONFIG environment variable to the full |
| path to pkg-config. |
| |
| _PKG_TEXT |
| |
| To get pkg-config, see <http://pkg-config.freedesktop.org/>.])[]dnl |
| ]) |
| else |
| $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS |
| $1[]_LIBS=$pkg_cv_[]$1[]_LIBS |
| AC_MSG_RESULT([yes]) |
| $3 |
| fi[]dnl |
| ])dnl PKG_CHECK_MODULES |
| |
| |
| dnl PKG_CHECK_MODULES_STATIC(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND], |
| dnl [ACTION-IF-NOT-FOUND]) |
| dnl --------------------------------------------------------------------- |
| dnl Since: 0.29 |
| dnl |
| dnl Checks for existence of MODULES and gathers its build flags with |
| dnl static libraries enabled. Sets VARIABLE-PREFIX_CFLAGS from --cflags |
| dnl and VARIABLE-PREFIX_LIBS from --libs. |
| dnl |
| dnl Note that if there is a possibility the first call to |
| dnl PKG_CHECK_MODULES_STATIC might not happen, you should be sure to |
| dnl include an explicit call to PKG_PROG_PKG_CONFIG in your |
| dnl configure.ac. |
| AC_DEFUN([PKG_CHECK_MODULES_STATIC], |
| [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl |
| _save_PKG_CONFIG=$PKG_CONFIG |
| PKG_CONFIG="$PKG_CONFIG --static" |
| PKG_CHECK_MODULES($@) |
| PKG_CONFIG=$_save_PKG_CONFIG[]dnl |
| ])dnl PKG_CHECK_MODULES_STATIC |
| |
| |
| dnl PKG_INSTALLDIR([DIRECTORY]) |
| dnl ------------------------- |
| dnl Since: 0.27 |
| dnl |
| dnl Substitutes the variable pkgconfigdir as the location where a module |
| dnl should install pkg-config .pc files. By default the directory is |
| dnl $libdir/pkgconfig, but the default can be changed by passing |
| dnl DIRECTORY. The user can override through the --with-pkgconfigdir |
| dnl parameter. |
| AC_DEFUN([PKG_INSTALLDIR], |
| [m4_pushdef([pkg_default], [m4_default([$1], ['${libdir}/pkgconfig'])]) |
| m4_pushdef([pkg_description], |
| [pkg-config installation directory @<:@]pkg_default[@:>@]) |
| AC_ARG_WITH([pkgconfigdir], |
| [AS_HELP_STRING([--with-pkgconfigdir], pkg_description)],, |
| [with_pkgconfigdir=]pkg_default) |
| AC_SUBST([pkgconfigdir], [$with_pkgconfigdir]) |
| m4_popdef([pkg_default]) |
| m4_popdef([pkg_description]) |
| ])dnl PKG_INSTALLDIR |
| |
| |
| dnl PKG_NOARCH_INSTALLDIR([DIRECTORY]) |
| dnl -------------------------------- |
| dnl Since: 0.27 |
| dnl |
| dnl Substitutes the variable noarch_pkgconfigdir as the location where a |
| dnl module should install arch-independent pkg-config .pc files. By |
| dnl default the directory is $datadir/pkgconfig, but the default can be |
| dnl changed by passing DIRECTORY. The user can override through the |
| dnl --with-noarch-pkgconfigdir parameter. |
| AC_DEFUN([PKG_NOARCH_INSTALLDIR], |
| [m4_pushdef([pkg_default], [m4_default([$1], ['${datadir}/pkgconfig'])]) |
| m4_pushdef([pkg_description], |
| [pkg-config arch-independent installation directory @<:@]pkg_default[@:>@]) |
| AC_ARG_WITH([noarch-pkgconfigdir], |
| [AS_HELP_STRING([--with-noarch-pkgconfigdir], pkg_description)],, |
| [with_noarch_pkgconfigdir=]pkg_default) |
| AC_SUBST([noarch_pkgconfigdir], [$with_noarch_pkgconfigdir]) |
| m4_popdef([pkg_default]) |
| m4_popdef([pkg_description]) |
| ])dnl PKG_NOARCH_INSTALLDIR |
| |
| |
| dnl PKG_CHECK_VAR(VARIABLE, MODULE, CONFIG-VARIABLE, |
| dnl [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND]) |
| dnl ------------------------------------------- |
| dnl Since: 0.28 |
| dnl |
| dnl Retrieves the value of the pkg-config variable for the given module. |
| AC_DEFUN([PKG_CHECK_VAR], |
| [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl |
| AC_ARG_VAR([$1], [value of $3 for $2, overriding pkg-config])dnl |
| |
| _PKG_CONFIG([$1], [variable="][$3]["], [$2]) |
| AS_VAR_COPY([$1], [pkg_cv_][$1]) |
| |
| AS_VAR_IF([$1], [""], [$5], [$4])dnl |
| ])dnl PKG_CHECK_VAR |
| |
| # po.m4 serial 31 (gettext-0.20.2) |
| dnl Copyright (C) 1995-2014, 2016, 2018-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| dnl |
| dnl This file can be used in projects which are not available under |
| dnl the GNU General Public License or the GNU Lesser General Public |
| dnl License but which still want to provide support for the GNU gettext |
| dnl functionality. |
| dnl Please note that the actual code of the GNU gettext library is covered |
| dnl by the GNU Lesser General Public License, and the rest of the GNU |
| dnl gettext package is covered by the GNU General Public License. |
| dnl They are *not* in the public domain. |
| |
| dnl Authors: |
| dnl Ulrich Drepper <drepper@cygnus.com>, 1995-2000. |
| dnl Bruno Haible <haible@clisp.cons.org>, 2000-2003. |
| |
| AC_PREREQ([2.60]) |
| |
| dnl Checks for all prerequisites of the po subdirectory. |
| AC_DEFUN([AM_PO_SUBDIRS], |
| [ |
| AC_REQUIRE([AC_PROG_MAKE_SET])dnl |
| AC_REQUIRE([AC_PROG_INSTALL])dnl |
| AC_REQUIRE([AC_PROG_MKDIR_P])dnl |
| AC_REQUIRE([AC_PROG_SED])dnl |
| AC_REQUIRE([AM_NLS])dnl |
| |
| dnl Release version of the gettext macros. This is used to ensure that |
| dnl the gettext macros and po/Makefile.in.in are in sync. |
| AC_SUBST([GETTEXT_MACRO_VERSION], [0.20]) |
| |
| dnl Perform the following tests also if --disable-nls has been given, |
| dnl because they are needed for "make dist" to work. |
| |
| dnl Search for GNU msgfmt in the PATH. |
| dnl The first test excludes Solaris msgfmt and early GNU msgfmt versions. |
| dnl The second test excludes FreeBSD msgfmt. |
| AM_PATH_PROG_WITH_TEST(MSGFMT, msgfmt, |
| [$ac_dir/$ac_word --statistics /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 && |
| (if $ac_dir/$ac_word --statistics /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)], |
| :) |
| AC_PATH_PROG([GMSGFMT], [gmsgfmt], [$MSGFMT]) |
| |
| dnl Test whether it is GNU msgfmt >= 0.15. |
| changequote(,)dnl |
| case `$GMSGFMT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in |
| '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) GMSGFMT_015=: ;; |
| *) GMSGFMT_015=$GMSGFMT ;; |
| esac |
| changequote([,])dnl |
| AC_SUBST([GMSGFMT_015]) |
| |
| dnl Search for GNU xgettext 0.12 or newer in the PATH. |
| dnl The first test excludes Solaris xgettext and early GNU xgettext versions. |
| dnl The second test excludes FreeBSD xgettext. |
| AM_PATH_PROG_WITH_TEST(XGETTEXT, xgettext, |
| [$ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1 && |
| (if $ac_dir/$ac_word --omit-header --copyright-holder= --msgid-bugs-address= /dev/null 2>&1 >/dev/null | grep usage >/dev/null; then exit 1; else exit 0; fi)], |
| :) |
| dnl Remove leftover from FreeBSD xgettext call. |
| rm -f messages.po |
| |
| dnl Test whether it is GNU xgettext >= 0.15. |
| changequote(,)dnl |
| case `$XGETTEXT --version | sed 1q | sed -e 's,^[^0-9]*,,'` in |
| '' | 0.[0-9] | 0.[0-9].* | 0.1[0-4] | 0.1[0-4].*) XGETTEXT_015=: ;; |
| *) XGETTEXT_015=$XGETTEXT ;; |
| esac |
| changequote([,])dnl |
| AC_SUBST([XGETTEXT_015]) |
| |
| dnl Search for GNU msgmerge 0.11 or newer in the PATH. |
| AM_PATH_PROG_WITH_TEST(MSGMERGE, msgmerge, |
| [$ac_dir/$ac_word --update -q /dev/null /dev/null >&]AS_MESSAGE_LOG_FD[ 2>&1], :) |
| |
| dnl Test whether it is GNU msgmerge >= 0.20. |
| if LC_ALL=C $MSGMERGE --help | grep ' --for-msgfmt ' >/dev/null; then |
| MSGMERGE_FOR_MSGFMT_OPTION='--for-msgfmt' |
| else |
| dnl Test whether it is GNU msgmerge >= 0.12. |
| if LC_ALL=C $MSGMERGE --help | grep ' --no-fuzzy-matching ' >/dev/null; then |
| MSGMERGE_FOR_MSGFMT_OPTION='--no-fuzzy-matching --no-location --quiet' |
| else |
| dnl With these old versions, $(MSGMERGE) $(MSGMERGE_FOR_MSGFMT_OPTION) is |
| dnl slow. But this is not a big problem, as such old gettext versions are |
| dnl hardly in use any more. |
| MSGMERGE_FOR_MSGFMT_OPTION='--no-location --quiet' |
| fi |
| fi |
| AC_SUBST([MSGMERGE_FOR_MSGFMT_OPTION]) |
| |
| dnl Support for AM_XGETTEXT_OPTION. |
| test -n "${XGETTEXT_EXTRA_OPTIONS+set}" || XGETTEXT_EXTRA_OPTIONS= |
| AC_SUBST([XGETTEXT_EXTRA_OPTIONS]) |
| |
| AC_CONFIG_COMMANDS([po-directories], [[ |
| for ac_file in $CONFIG_FILES; do |
| # Support "outfile[:infile[:infile...]]" |
| case "$ac_file" in |
| *:*) ac_file=`echo "$ac_file"|sed 's%:.*%%'` ;; |
| esac |
| # PO directories have a Makefile.in generated from Makefile.in.in. |
| case "$ac_file" in */Makefile.in) |
| # Adjust a relative srcdir. |
| ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'` |
| ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'` |
| ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'` |
| # In autoconf-2.13 it is called $ac_given_srcdir. |
| # In autoconf-2.50 it is called $srcdir. |
| test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir" |
| case "$ac_given_srcdir" in |
| .) top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;; |
| /*) top_srcdir="$ac_given_srcdir" ;; |
| *) top_srcdir="$ac_dots$ac_given_srcdir" ;; |
| esac |
| # Treat a directory as a PO directory if and only if it has a |
| # POTFILES.in file. This allows packages to have multiple PO |
| # directories under different names or in different locations. |
| if test -f "$ac_given_srcdir/$ac_dir/POTFILES.in"; then |
| rm -f "$ac_dir/POTFILES" |
| test -n "$as_me" && echo "$as_me: creating $ac_dir/POTFILES" || echo "creating $ac_dir/POTFILES" |
| gt_tab=`printf '\t'` |
| cat "$ac_given_srcdir/$ac_dir/POTFILES.in" | sed -e "/^#/d" -e "/^[ ${gt_tab}]*\$/d" -e "s,.*, $top_srcdir/& \\\\," | sed -e "\$s/\(.*\) \\\\/\1/" > "$ac_dir/POTFILES" |
| POMAKEFILEDEPS="POTFILES.in" |
| # ALL_LINGUAS, POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES depend |
| # on $ac_dir but don't depend on user-specified configuration |
| # parameters. |
| if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then |
| # The LINGUAS file contains the set of available languages. |
| if test -n "$OBSOLETE_ALL_LINGUAS"; then |
| test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete" |
| fi |
| ALL_LINGUAS=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"` |
| POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS" |
| else |
| # The set of available languages was given in configure.in. |
| ALL_LINGUAS=$OBSOLETE_ALL_LINGUAS |
| fi |
| # Compute POFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po) |
| # Compute UPDATEPOFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(lang).po-update) |
| # Compute DUMMYPOFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(lang).nop) |
| # Compute GMOFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo) |
| case "$ac_given_srcdir" in |
| .) srcdirpre= ;; |
| *) srcdirpre='$(srcdir)/' ;; |
| esac |
| POFILES= |
| UPDATEPOFILES= |
| DUMMYPOFILES= |
| GMOFILES= |
| for lang in $ALL_LINGUAS; do |
| POFILES="$POFILES $srcdirpre$lang.po" |
| UPDATEPOFILES="$UPDATEPOFILES $lang.po-update" |
| DUMMYPOFILES="$DUMMYPOFILES $lang.nop" |
| GMOFILES="$GMOFILES $srcdirpre$lang.gmo" |
| done |
| # CATALOGS depends on both $ac_dir and the user's LINGUAS |
| # environment variable. |
| INST_LINGUAS= |
| if test -n "$ALL_LINGUAS"; then |
| for presentlang in $ALL_LINGUAS; do |
| useit=no |
| if test "%UNSET%" != "$LINGUAS"; then |
| desiredlanguages="$LINGUAS" |
| else |
| desiredlanguages="$ALL_LINGUAS" |
| fi |
| for desiredlang in $desiredlanguages; do |
| # Use the presentlang catalog if desiredlang is |
| # a. equal to presentlang, or |
| # b. a variant of presentlang (because in this case, |
| # presentlang can be used as a fallback for messages |
| # which are not translated in the desiredlang catalog). |
| case "$desiredlang" in |
| "$presentlang"*) useit=yes;; |
| esac |
| done |
| if test $useit = yes; then |
| INST_LINGUAS="$INST_LINGUAS $presentlang" |
| fi |
| done |
| fi |
| CATALOGS= |
| if test -n "$INST_LINGUAS"; then |
| for lang in $INST_LINGUAS; do |
| CATALOGS="$CATALOGS $lang.gmo" |
| done |
| fi |
| test -n "$as_me" && echo "$as_me: creating $ac_dir/Makefile" || echo "creating $ac_dir/Makefile" |
| sed -e "/^POTFILES =/r $ac_dir/POTFILES" -e "/^# Makevars/r $ac_given_srcdir/$ac_dir/Makevars" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@POMAKEFILEDEPS@|$POMAKEFILEDEPS|g" "$ac_dir/Makefile.in" > "$ac_dir/Makefile" |
| for f in "$ac_given_srcdir/$ac_dir"/Rules-*; do |
| if test -f "$f"; then |
| case "$f" in |
| *.orig | *.bak | *~) ;; |
| *) cat "$f" >> "$ac_dir/Makefile" ;; |
| esac |
| fi |
| done |
| fi |
| ;; |
| esac |
| done]], |
| [# Capture the value of obsolete ALL_LINGUAS because we need it to compute |
| # POFILES, UPDATEPOFILES, DUMMYPOFILES, GMOFILES, CATALOGS. |
| OBSOLETE_ALL_LINGUAS="$ALL_LINGUAS" |
| # Capture the value of LINGUAS because we need it to compute CATALOGS. |
| LINGUAS="${LINGUAS-%UNSET%}" |
| ]) |
| ]) |
| |
| dnl Postprocesses a Makefile in a directory containing PO files. |
| AC_DEFUN([AM_POSTPROCESS_PO_MAKEFILE], |
| [ |
| # When this code is run, in config.status, two variables have already been |
| # set: |
| # - OBSOLETE_ALL_LINGUAS is the value of LINGUAS set in configure.in, |
| # - LINGUAS is the value of the environment variable LINGUAS at configure |
| # time. |
| |
| changequote(,)dnl |
| # Adjust a relative srcdir. |
| ac_dir=`echo "$ac_file"|sed 's%/[^/][^/]*$%%'` |
| ac_dir_suffix=/`echo "$ac_dir"|sed 's%^\./%%'` |
| ac_dots=`echo "$ac_dir_suffix"|sed 's%/[^/]*%../%g'` |
| # In autoconf-2.13 it is called $ac_given_srcdir. |
| # In autoconf-2.50 it is called $srcdir. |
| test -n "$ac_given_srcdir" || ac_given_srcdir="$srcdir" |
| case "$ac_given_srcdir" in |
| .) top_srcdir=`echo $ac_dots|sed 's%/$%%'` ;; |
| /*) top_srcdir="$ac_given_srcdir" ;; |
| *) top_srcdir="$ac_dots$ac_given_srcdir" ;; |
| esac |
| |
| # Find a way to echo strings without interpreting backslash. |
| if test "X`(echo '\t') 2>/dev/null`" = 'X\t'; then |
| gt_echo='echo' |
| else |
| if test "X`(printf '%s\n' '\t') 2>/dev/null`" = 'X\t'; then |
| gt_echo='printf %s\n' |
| else |
| echo_func () { |
| cat <<EOT |
| $* |
| EOT |
| } |
| gt_echo='echo_func' |
| fi |
| fi |
| |
| # A sed script that extracts the value of VARIABLE from a Makefile. |
| tab=`printf '\t'` |
| sed_x_variable=' |
| # Test if the hold space is empty. |
| x |
| s/P/P/ |
| x |
| ta |
| # Yes it was empty. Look if we have the expected variable definition. |
| /^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=/{ |
| # Seen the first line of the variable definition. |
| s/^['"${tab}"' ]*VARIABLE['"${tab}"' ]*=// |
| ba |
| } |
| bd |
| :a |
| # Here we are processing a line from the variable definition. |
| # Remove comment, more precisely replace it with a space. |
| s/#.*$/ / |
| # See if the line ends in a backslash. |
| tb |
| :b |
| s/\\$// |
| # Print the line, without the trailing backslash. |
| p |
| tc |
| # There was no trailing backslash. The end of the variable definition is |
| # reached. Clear the hold space. |
| s/^.*$// |
| x |
| bd |
| :c |
| # A trailing backslash means that the variable definition continues in the |
| # next line. Put a nonempty string into the hold space to indicate this. |
| s/^.*$/P/ |
| x |
| :d |
| ' |
| changequote([,])dnl |
| |
| # Set POTFILES to the value of the Makefile variable POTFILES. |
| sed_x_POTFILES=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/POTFILES/g'` |
| POTFILES=`sed -n -e "$sed_x_POTFILES" < "$ac_file"` |
| # Compute POTFILES_DEPS as |
| # $(foreach file, $(POTFILES), $(top_srcdir)/$(file)) |
| POTFILES_DEPS= |
| for file in $POTFILES; do |
| POTFILES_DEPS="$POTFILES_DEPS "'$(top_srcdir)/'"$file" |
| done |
| POMAKEFILEDEPS="" |
| |
| if test -n "$OBSOLETE_ALL_LINGUAS"; then |
| test -n "$as_me" && echo "$as_me: setting ALL_LINGUAS in configure.in is obsolete" || echo "setting ALL_LINGUAS in configure.in is obsolete" |
| fi |
| if test -f "$ac_given_srcdir/$ac_dir/LINGUAS"; then |
| # The LINGUAS file contains the set of available languages. |
| ALL_LINGUAS=`sed -e "/^#/d" -e "s/#.*//" "$ac_given_srcdir/$ac_dir/LINGUAS"` |
| POMAKEFILEDEPS="$POMAKEFILEDEPS LINGUAS" |
| else |
| # Set ALL_LINGUAS to the value of the Makefile variable LINGUAS. |
| sed_x_LINGUAS=`$gt_echo "$sed_x_variable" | sed -e '/^ *#/d' -e 's/VARIABLE/LINGUAS/g'` |
| ALL_LINGUAS=`sed -n -e "$sed_x_LINGUAS" < "$ac_file"` |
| fi |
| # Compute POFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).po) |
| # Compute UPDATEPOFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(lang).po-update) |
| # Compute DUMMYPOFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(lang).nop) |
| # Compute GMOFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).gmo) |
| # Compute PROPERTIESFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(DOMAIN)_$(lang).properties) |
| # Compute CLASSFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(DOMAIN)_$(lang).class) |
| # Compute QMFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(lang).qm) |
| # Compute MSGFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang)).msg) |
| # Compute RESOURCESDLLFILES |
| # as $(foreach lang, $(ALL_LINGUAS), $(srcdir)/$(frob $(lang))/$(DOMAIN).resources.dll) |
| case "$ac_given_srcdir" in |
| .) srcdirpre= ;; |
| *) srcdirpre='$(srcdir)/' ;; |
| esac |
| POFILES= |
| UPDATEPOFILES= |
| DUMMYPOFILES= |
| GMOFILES= |
| PROPERTIESFILES= |
| CLASSFILES= |
| QMFILES= |
| MSGFILES= |
| RESOURCESDLLFILES= |
| for lang in $ALL_LINGUAS; do |
| POFILES="$POFILES $srcdirpre$lang.po" |
| UPDATEPOFILES="$UPDATEPOFILES $lang.po-update" |
| DUMMYPOFILES="$DUMMYPOFILES $lang.nop" |
| GMOFILES="$GMOFILES $srcdirpre$lang.gmo" |
| PROPERTIESFILES="$PROPERTIESFILES \$(srcdir)/\$(DOMAIN)_$lang.properties" |
| CLASSFILES="$CLASSFILES \$(srcdir)/\$(DOMAIN)_$lang.class" |
| QMFILES="$QMFILES $srcdirpre$lang.qm" |
| frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'` |
| MSGFILES="$MSGFILES $srcdirpre$frobbedlang.msg" |
| frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'` |
| RESOURCESDLLFILES="$RESOURCESDLLFILES $srcdirpre$frobbedlang/\$(DOMAIN).resources.dll" |
| done |
| # CATALOGS depends on both $ac_dir and the user's LINGUAS |
| # environment variable. |
| INST_LINGUAS= |
| if test -n "$ALL_LINGUAS"; then |
| for presentlang in $ALL_LINGUAS; do |
| useit=no |
| if test "%UNSET%" != "$LINGUAS"; then |
| desiredlanguages="$LINGUAS" |
| else |
| desiredlanguages="$ALL_LINGUAS" |
| fi |
| for desiredlang in $desiredlanguages; do |
| # Use the presentlang catalog if desiredlang is |
| # a. equal to presentlang, or |
| # b. a variant of presentlang (because in this case, |
| # presentlang can be used as a fallback for messages |
| # which are not translated in the desiredlang catalog). |
| case "$desiredlang" in |
| "$presentlang"*) useit=yes;; |
| esac |
| done |
| if test $useit = yes; then |
| INST_LINGUAS="$INST_LINGUAS $presentlang" |
| fi |
| done |
| fi |
| CATALOGS= |
| JAVACATALOGS= |
| QTCATALOGS= |
| TCLCATALOGS= |
| CSHARPCATALOGS= |
| if test -n "$INST_LINGUAS"; then |
| for lang in $INST_LINGUAS; do |
| CATALOGS="$CATALOGS $lang.gmo" |
| JAVACATALOGS="$JAVACATALOGS \$(DOMAIN)_$lang.properties" |
| QTCATALOGS="$QTCATALOGS $lang.qm" |
| frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'` |
| TCLCATALOGS="$TCLCATALOGS $frobbedlang.msg" |
| frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'` |
| CSHARPCATALOGS="$CSHARPCATALOGS $frobbedlang/\$(DOMAIN).resources.dll" |
| done |
| fi |
| |
| sed -e "s|@POTFILES_DEPS@|$POTFILES_DEPS|g" -e "s|@POFILES@|$POFILES|g" -e "s|@UPDATEPOFILES@|$UPDATEPOFILES|g" -e "s|@DUMMYPOFILES@|$DUMMYPOFILES|g" -e "s|@GMOFILES@|$GMOFILES|g" -e "s|@PROPERTIESFILES@|$PROPERTIESFILES|g" -e "s|@CLASSFILES@|$CLASSFILES|g" -e "s|@QMFILES@|$QMFILES|g" -e "s|@MSGFILES@|$MSGFILES|g" -e "s|@RESOURCESDLLFILES@|$RESOURCESDLLFILES|g" -e "s|@CATALOGS@|$CATALOGS|g" -e "s|@JAVACATALOGS@|$JAVACATALOGS|g" -e "s|@QTCATALOGS@|$QTCATALOGS|g" -e "s|@TCLCATALOGS@|$TCLCATALOGS|g" -e "s|@CSHARPCATALOGS@|$CSHARPCATALOGS|g" -e 's,^#distdir:,distdir:,' < "$ac_file" > "$ac_file.tmp" |
| tab=`printf '\t'` |
| if grep -l '@TCLCATALOGS@' "$ac_file" > /dev/null; then |
| # Add dependencies that cannot be formulated as a simple suffix rule. |
| for lang in $ALL_LINGUAS; do |
| frobbedlang=`echo $lang | sed -e 's/\..*$//' -e 'y/ABCDEFGHIJKLMNOPQRSTUVWXYZ/abcdefghijklmnopqrstuvwxyz/'` |
| cat >> "$ac_file.tmp" <<EOF |
| $frobbedlang.msg: $lang.po |
| ${tab}@echo "\$(MSGFMT) -c --tcl -d \$(srcdir) -l $lang $srcdirpre$lang.po"; \ |
| ${tab}\$(MSGFMT) -c --tcl -d "\$(srcdir)" -l $lang $srcdirpre$lang.po || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; } |
| EOF |
| done |
| fi |
| if grep -l '@CSHARPCATALOGS@' "$ac_file" > /dev/null; then |
| # Add dependencies that cannot be formulated as a simple suffix rule. |
| for lang in $ALL_LINGUAS; do |
| frobbedlang=`echo $lang | sed -e 's/_/-/g' -e 's/^sr-CS/sr-SP/' -e 's/@latin$/-Latn/' -e 's/@cyrillic$/-Cyrl/' -e 's/^sr-SP$/sr-SP-Latn/' -e 's/^uz-UZ$/uz-UZ-Latn/'` |
| cat >> "$ac_file.tmp" <<EOF |
| $frobbedlang/\$(DOMAIN).resources.dll: $lang.po |
| ${tab}@echo "\$(MSGFMT) -c --csharp -d \$(srcdir) -l $lang $srcdirpre$lang.po -r \$(DOMAIN)"; \ |
| ${tab}\$(MSGFMT) -c --csharp -d "\$(srcdir)" -l $lang $srcdirpre$lang.po -r "\$(DOMAIN)" || { rm -f "\$(srcdir)/$frobbedlang.msg"; exit 1; } |
| EOF |
| done |
| fi |
| if test -n "$POMAKEFILEDEPS"; then |
| cat >> "$ac_file.tmp" <<EOF |
| Makefile: $POMAKEFILEDEPS |
| EOF |
| fi |
| mv "$ac_file.tmp" "$ac_file" |
| ]) |
| |
| dnl Initializes the accumulator used by AM_XGETTEXT_OPTION. |
| AC_DEFUN([AM_XGETTEXT_OPTION_INIT], |
| [ |
| XGETTEXT_EXTRA_OPTIONS= |
| ]) |
| |
| dnl Registers an option to be passed to xgettext in the po subdirectory. |
| AC_DEFUN([AM_XGETTEXT_OPTION], |
| [ |
| AC_REQUIRE([AM_XGETTEXT_OPTION_INIT]) |
| XGETTEXT_EXTRA_OPTIONS="$XGETTEXT_EXTRA_OPTIONS $1" |
| ]) |
| |
| # progtest.m4 serial 8 (gettext-0.20.2) |
| dnl Copyright (C) 1996-2003, 2005, 2008-2020 Free Software Foundation, Inc. |
| dnl This file is free software; the Free Software Foundation |
| dnl gives unlimited permission to copy and/or distribute it, |
| dnl with or without modifications, as long as this notice is preserved. |
| dnl |
| dnl This file can be used in projects which are not available under |
| dnl the GNU General Public License or the GNU Lesser General Public |
| dnl License but which still want to provide support for the GNU gettext |
| dnl functionality. |
| dnl Please note that the actual code of the GNU gettext library is covered |
| dnl by the GNU Lesser General Public License, and the rest of the GNU |
| dnl gettext package is covered by the GNU General Public License. |
| dnl They are *not* in the public domain. |
| |
| dnl Authors: |
| dnl Ulrich Drepper <drepper@cygnus.com>, 1996. |
| |
| AC_PREREQ([2.50]) |
| |
| # Search path for a program which passes the given test. |
| |
| dnl AM_PATH_PROG_WITH_TEST(VARIABLE, PROG-TO-CHECK-FOR, |
| dnl TEST-PERFORMED-ON-FOUND_PROGRAM [, VALUE-IF-NOT-FOUND [, PATH]]) |
| AC_DEFUN([AM_PATH_PROG_WITH_TEST], |
| [ |
| # Prepare PATH_SEPARATOR. |
| # The user is always right. |
| if test "${PATH_SEPARATOR+set}" != set; then |
| # Determine PATH_SEPARATOR by trying to find /bin/sh in a PATH which |
| # contains only /bin. Note that ksh looks also at the FPATH variable, |
| # so we have to set that as well for the test. |
| PATH_SEPARATOR=: |
| (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \ |
| && { (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 \ |
| || PATH_SEPARATOR=';' |
| } |
| fi |
| |
| # Find out how to test for executable files. Don't use a zero-byte file, |
| # as systems may use methods other than mode bits to determine executability. |
| cat >conf$$.file <<_ASEOF |
| #! /bin/sh |
| exit 0 |
| _ASEOF |
| chmod +x conf$$.file |
| if test -x conf$$.file >/dev/null 2>&1; then |
| ac_executable_p="test -x" |
| else |
| ac_executable_p="test -f" |
| fi |
| rm -f conf$$.file |
| |
| # Extract the first word of "$2", so it can be a program name with args. |
| set dummy $2; ac_word=[$]2 |
| AC_MSG_CHECKING([for $ac_word]) |
| AC_CACHE_VAL([ac_cv_path_$1], |
| [case "[$]$1" in |
| [[\\/]]* | ?:[[\\/]]*) |
| ac_cv_path_$1="[$]$1" # Let the user override the test with a path. |
| ;; |
| *) |
| ac_save_IFS="$IFS"; IFS=$PATH_SEPARATOR |
| for ac_dir in ifelse([$5], , $PATH, [$5]); do |
| IFS="$ac_save_IFS" |
| test -z "$ac_dir" && ac_dir=. |
| for ac_exec_ext in '' $ac_executable_extensions; do |
| if $ac_executable_p "$ac_dir/$ac_word$ac_exec_ext"; then |
| echo "$as_me: trying $ac_dir/$ac_word..." >&AS_MESSAGE_LOG_FD |
| if [$3]; then |
| ac_cv_path_$1="$ac_dir/$ac_word$ac_exec_ext" |
| break 2 |
| fi |
| fi |
| done |
| done |
| IFS="$ac_save_IFS" |
| dnl If no 4th arg is given, leave the cache variable unset, |
| dnl so AC_PATH_PROGS will keep looking. |
| ifelse([$4], , , [ test -z "[$]ac_cv_path_$1" && ac_cv_path_$1="$4" |
| ])dnl |
| ;; |
| esac])dnl |
| $1="$ac_cv_path_$1" |
| if test ifelse([$4], , [-n "[$]$1"], ["[$]$1" != "$4"]); then |
| AC_MSG_RESULT([$][$1]) |
| else |
| AC_MSG_RESULT([no]) |
| fi |
| AC_SUBST([$1])dnl |
| ]) |
| |
| m4_include([acinclude.m4]) |