| dnl These m4 macros are whitespace sensitive and break if moved around much. |
| m4_define([LU_VERSION_H], m4_include([libusb/version.h])) |
| m4_define([LU_DEFINE_VERSION_ATOM], |
| [m4_define([$1], m4_bregexp(LU_VERSION_H, |
| [^#define\s*$1\s*\([0-9]*\).*], [\1]))]) |
| m4_define([LU_DEFINE_VERSION_RC_ATOM], |
| [m4_define([$1], m4_bregexp(LU_VERSION_H, |
| [^#define\s*$1\s*"\(-rc[0-9]*\)".*], [\1]))]) |
| dnl The m4_bregexp() returns (only) the numbers following the #define named |
| dnl in the first macro parameter. m4_define() then defines the name for use |
| dnl in AC_INIT(). |
| |
| LU_DEFINE_VERSION_ATOM([LIBUSB_MAJOR]) |
| LU_DEFINE_VERSION_ATOM([LIBUSB_MINOR]) |
| LU_DEFINE_VERSION_ATOM([LIBUSB_MICRO]) |
| LU_DEFINE_VERSION_RC_ATOM([LIBUSB_RC]) |
| |
| AC_INIT([libusb], LIBUSB_MAJOR[.]LIBUSB_MINOR[.]LIBUSB_MICRO[]LIBUSB_RC, [libusb-devel@lists.sourceforge.net], [libusb], [http://www.libusb.org/]) |
| |
| # Library versioning |
| # These numbers should be tweaked on every release. Read carefully: |
| # http://www.gnu.org/software/libtool/manual/html_node/Updating-version-info.html |
| # http://sourceware.org/autobook/autobook/autobook_91.html |
| lt_current="1" |
| lt_revision="0" |
| lt_age="1" |
| LTLDFLAGS="-version-info ${lt_current}:${lt_revision}:${lt_age}" |
| |
| AM_INIT_AUTOMAKE |
| AM_MAINTAINER_MODE |
| |
| AC_CONFIG_SRCDIR([libusb/core.c]) |
| AC_CONFIG_MACRO_DIR([m4]) |
| AM_CONFIG_HEADER([config.h]) |
| m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])]) |
| |
| AC_PREREQ([2.50]) |
| AC_PROG_CC |
| AC_PROG_LIBTOOL |
| LT_LANG([Windows Resource]) |
| AC_C_INLINE |
| AM_PROG_CC_C_O |
| AC_DEFINE([_GNU_SOURCE], 1, [Use GNU extensions]) |
| |
| LTLDFLAGS="${LTLDFLAGS} -no-undefined" |
| |
| AC_MSG_CHECKING([operating system]) |
| case $host in |
| *-linux*) |
| AC_MSG_RESULT([Linux]) |
| backend="linux" |
| ;; |
| *-darwin*) |
| AC_MSG_RESULT([Darwin/Mac OS X]) |
| backend="darwin" |
| ;; |
| *-openbsd*) |
| AC_MSG_RESULT([OpenBSD]) |
| backend="openbsd" |
| ;; |
| *-netbsd*) |
| AC_MSG_RESULT([NetBSD (using OpenBSD backend)]) |
| backend="openbsd" |
| ;; |
| *-mingw*) |
| AC_MSG_RESULT([Windows]) |
| backend="windows" |
| ;; |
| *-cygwin*) |
| AC_MSG_RESULT([Cygwin (using Windows backend)]) |
| backend="windows" |
| threads="posix" |
| ;; |
| *) |
| AC_MSG_ERROR([unsupported operating system]) |
| esac |
| case $backend in |
| linux) |
| AC_DEFINE(OS_LINUX, 1, [Linux backend]) |
| AC_SUBST(OS_LINUX) |
| AC_CHECK_LIB(rt, clock_gettime, PC_LIBS_PRIVATE="-lrt") |
| threads="posix" |
| THREAD_CFLAGS="-pthread" |
| PC_LIBS_PRIVATE="${PC_LIBS_PRIVATE} -pthread" |
| AC_CHECK_HEADERS([poll.h]) |
| AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument]) |
| ;; |
| darwin) |
| AC_DEFINE(OS_DARWIN, 1, [Darwin backend]) |
| AC_SUBST(OS_DARWIN) |
| threads="posix" |
| PC_LIBS_PRIVATE="-lobjc -Wl,-framework,IOKit -Wl,-framework,CoreFoundation" |
| LTLDFLAGS="${LTLDFLAGS} -Wl,-prebind" |
| AC_CHECK_HEADERS([poll.h]) |
| AC_CHECK_TYPE([nfds_t], |
| [AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument])], |
| [AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument])], |
| [#include <poll.h>]) |
| ;; |
| openbsd) |
| AC_DEFINE(OS_OPENBSD, 1, [OpenBSD backend]) |
| AC_SUBST(OS_OPENBSD) |
| threads="posix" |
| THREAD_CFLAGS="-pthread" |
| PC_LIBS_PRIVATE="-pthread" |
| AC_CHECK_HEADERS([poll.h]) |
| AC_DEFINE([POLL_NFDS_TYPE],[nfds_t],[type of second poll() argument]) |
| ;; |
| windows) |
| AC_DEFINE(OS_WINDOWS, 1, [Windows backend]) |
| AC_SUBST(OS_WINDOWS) |
| PC_LIBS_PRIVATE="" |
| LTLDFLAGS="${LTLDFLAGS} -avoid-version -Wl,--add-stdcall-alias" |
| AC_DEFINE([POLL_NFDS_TYPE],[unsigned int],[type of second poll() argument]) |
| ;; |
| esac |
| AC_SUBST(THREAD_CFLAGS) |
| AC_SUBST(PC_LIBS_PRIVATE) |
| LIBS="${LIBS} ${PC_LIBS_PRIVATE}" |
| |
| AM_CONDITIONAL(OS_LINUX, test "x$backend" = xlinux) |
| AM_CONDITIONAL(OS_DARWIN, test "x$backend" = xdarwin) |
| AM_CONDITIONAL(OS_OPENBSD, test "x$backend" = xopenbsd) |
| AM_CONDITIONAL(OS_WINDOWS, test "x$backend" = xwindows) |
| AM_CONDITIONAL(THREADS_POSIX, test "x$threads" = xposix) |
| if test "$threads" = posix; then |
| AC_DEFINE(THREADS_POSIX, 1, [Use POSIX Threads]) |
| fi |
| |
| # timerfd |
| AC_CHECK_HEADER([sys/timerfd.h], [timerfd_h=1], [timerfd_h=0]) |
| AC_ARG_ENABLE([timerfd], |
| [AS_HELP_STRING([--enable-timerfd], |
| [use timerfd for timing (default auto)])], |
| [use_timerfd=$enableval], [use_timerfd='auto']) |
| |
| if test "x$use_timerfd" = "xyes" -a "x$timerfd_h" = "x0"; then |
| AC_MSG_ERROR([timerfd header not available; glibc 2.9+ required]) |
| fi |
| |
| AC_CHECK_DECL([TFD_NONBLOCK], [tfd_hdr_ok=yes], [tfd_hdr_ok=no], [#include <sys/timerfd.h>]) |
| if test "x$use_timerfd" = "xyes" -a "x$tfd_hdr_ok" = "xno"; then |
| AC_MSG_ERROR([timerfd header not usable; glibc 2.9+ required]) |
| fi |
| |
| AC_MSG_CHECKING([whether to use timerfd for timing]) |
| if test "x$use_timerfd" = "xno"; then |
| AC_MSG_RESULT([no (disabled by user)]) |
| else |
| if test "x$timerfd_h" = "x1" -a "x$tfd_hdr_ok" = "xyes"; then |
| AC_MSG_RESULT([yes]) |
| AC_DEFINE(USBI_TIMERFD_AVAILABLE, 1, [timerfd headers available]) |
| else |
| AC_MSG_RESULT([no (header not available)]) |
| fi |
| fi |
| |
| AC_CHECK_TYPES(struct timespec) |
| |
| # Message logging |
| AC_ARG_ENABLE([log], [AS_HELP_STRING([--disable-log], [disable all logging])], |
| [log_enabled=$enableval], |
| [log_enabled='yes']) |
| if test "x$log_enabled" != "xno"; then |
| AC_DEFINE([ENABLE_LOGGING], 1, [Message logging]) |
| fi |
| |
| AC_ARG_ENABLE([debug-log], [AS_HELP_STRING([--enable-debug-log], |
| [enable debug logging (default n)])], |
| [debug_log_enabled=$enableval], |
| [debug_log_enabled='no']) |
| if test "x$debug_log_enabled" != "xno"; then |
| AC_DEFINE([ENABLE_DEBUG_LOGGING], 1, [Debug message logging]) |
| fi |
| |
| # Examples build |
| AC_ARG_ENABLE([examples-build], [AS_HELP_STRING([--enable-examples-build], |
| [build example applications (default n)])], |
| [build_examples=$enableval], |
| [build_examples='no']) |
| AM_CONDITIONAL([BUILD_EXAMPLES], [test "x$build_examples" != "xno"]) |
| |
| # check for -fvisibility=hidden compiler support (GCC >= 3.4) |
| saved_cflags="$CFLAGS" |
| # -Werror required for cygwin |
| CFLAGS="$CFLAGS -Werror -fvisibility=hidden" |
| AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], |
| [VISIBILITY_CFLAGS="-fvisibility=hidden" |
| AC_DEFINE([DEFAULT_VISIBILITY], [__attribute__((visibility("default")))], [Default visibility]) ], |
| [ VISIBILITY_CFLAGS="" |
| AC_DEFINE([DEFAULT_VISIBILITY], [], [Default visibility]) ], |
| ]) |
| CFLAGS="$saved_cflags" |
| |
| # check for -Wno-pointer-sign compiler support (GCC >= 4) |
| saved_cflags="$CFLAGS" |
| CFLAGS="$CFLAGS -Wno-pointer-sign" |
| AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])], |
| nopointersign_cflags="-Wno-pointer-sign", nopointersign_cflags="") |
| CFLAGS="$saved_cflags" |
| |
| # sigaction not available on MinGW |
| AC_CHECK_FUNC([sigaction], [have_sigaction=yes], [have_sigaction=no]) |
| AM_CONDITIONAL([HAVE_SIGACTION], [test "x$have_sigaction" = "xyes"]) |
| |
| # headers not available on all platforms but required on others |
| AC_CHECK_HEADERS([sys/time.h]) |
| AC_CHECK_FUNCS(gettimeofday) |
| |
| AM_CFLAGS="-std=gnu99 -Wall -Wundef -Wunused -Wstrict-prototypes -Werror-implicit-function-declaration $nopointersign_cflags -Wshadow" |
| |
| AC_SUBST(VISIBILITY_CFLAGS) |
| AC_SUBST(AM_CFLAGS) |
| AC_SUBST(LTLDFLAGS) |
| |
| AC_CONFIG_FILES([libusb-1.0.pc]) |
| AC_CONFIG_FILES([Makefile]) |
| AC_CONFIG_FILES([libusb/Makefile]) |
| AC_CONFIG_FILES([examples/Makefile]) |
| AC_CONFIG_FILES([doc/Makefile]) |
| AC_CONFIG_FILES([doc/doxygen.cfg]) |
| AC_OUTPUT |
