libs/utils/WordPressUtils/build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.2.0'
        classpath 'com.novoda:bintray-release:0.3.4'
    }
}

apply plugin: 'com.android.library'
apply plugin: 'com.novoda.bintray-release'

repositories {
    jcenter()
}

dependencies {
    compile('commons-lang:commons-lang:2.6') {
        exclude group: 'commons-logging'
    }
    compile 'com.mcxiaoke.volley:library:1.0.18'
    compile 'com.android.support:support-v13:24.2.1'
}

android {
    useLibrary 'org.apache.http.legacy'

    publishNonDefault true

    compileSdkVersion 24
    buildToolsVersion "24.0.2"

    defaultConfig {
        versionName "1.14.0"
        minSdkVersion 14
        targetSdkVersion 24
    }
}

android.libraryVariants.all { variant ->
    task("generate${variant.name}Javadoc", type: Javadoc) {
        description "Generates Javadoc for $variant.name."
        source = variant.javaCompile.source
        classpath = files(variant.javaCompile.classpath.files, android.getBootClasspath())

        options {
            links "http://docs.oracle.com/javase/7/docs/api/"
        }
        exclude '**/R.java'
    }
}

publish {
    artifactId = 'utils'
    userOrg = 'wordpress-mobile'
    groupId = 'org.wordpress'
    uploadName = 'utils'
    description = 'Utils library for Android'
    publishVersion = android.defaultConfig.versionName
    licences = ['MIT', 'GPL']
    website = 'https://github.com/wordpress-mobile/WordPress-Utils-Android/'
    dryRun = 'false'
    autoPublish = 'true'
}