libs/analytics/WordPressAnalytics/build.gradle

buildscript {
    repositories {
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.2.0'
    }
}

apply plugin: 'com.android.library'
apply plugin: 'maven'
apply plugin: 'signing'

repositories {
    jcenter()
}

dependencies {
    compile 'com.automattic:tracks:1.1.0'
    compile 'com.mixpanel.android:mixpanel-android:4.6.4'
    compile 'org.wordpress:utils:1.11.0'
}

android {
    publishNonDefault true

    compileSdkVersion 24
    buildToolsVersion "24.0.2"

    defaultConfig {
        versionName "1.2.0"
        minSdkVersion 16
        targetSdkVersion 24
    }
}

version android.defaultConfig.versionName
group = "org.wordpress"
archivesBaseName = "analytics"

signing {
    required {
        project.properties.containsKey("signing.keyId") && project.properties.containsKey("signing.secretKeyRingFile")
    }
    sign configurations.archives
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: project.properties.ossrhUsername, password: project.properties.ossrhPassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: project.properties.ossrhUsername, password: project.properties.ossrhPassword)
            }

            pom.project {
                name 'WordPressCom-Analytics-Android'
                packaging 'aar'
                description 'Analytics lib for WordPress-Android'
                url 'https://github.com/wordpress-mobile/WordPressCom-Analytics-Android'
                scm {
                    connection 'scm:git:https://github.com/wordpress-mobile/WordPressCom-Analytics-Android.git'
                    developerConnection 'scm:git:https://github.com/wordpress-mobile/WordPressCom-Analytics-Android.git'
                    url 'https://github.com/wordpress-mobile/WordPressCom-Analytics-Android'
                }

                licenses {
                    license {
                        name 'The MIT License (MIT)'
                        url 'http://opensource.org/licenses/MIT'
                    }
                }

                developers {
                    developer {
                        id 'maxme'
                        name 'Maxime Biais'
                        email 'maxime@automattic.com'
                    }
                }
            }
        }
    }
}