base/settings-real.gradle

rootProject.name = 'tools-gradle'

def projects = [
        [projectName: ':base:api-generator', projectPath: 'base/misc/api-generator'],
        [projectName: ':base:bazel:avd', projectPath: ''],
        [projectName: ':base:layoutlib-extensions', projectPath: ''],
        [projectName: ':base:lint', projectPath: ''],
        [projectName: ':base:manifest-merger', projectPath: 'base/build-system/manifest-merger'],
        [projectName: ':base:mlkit-common', projectPath: ''],
        [projectName: ':base:vector-drawable-tool', projectPath: ''],
        [projectName: ':base:profgen', projectPath: 'base/profgen/profgen'],
        [projectName: ':base:profgen-cli', projectPath: 'base/profgen/profgen-cli'],
        [projectName: ':base:profile', projectPath: 'base/build-system/profile'],
        [projectName: ':base:builder-model', projectPath: 'base/build-system/builder-model'],
        [projectName: ':base:builder-test-api', projectPath: 'base/build-system/builder-test-api'],
        [projectName: ':base:builder', projectPath: 'base/build-system/builder'],
        [projectName: ':base:gradle-api', projectPath: 'base/build-system/gradle-api'],
        [projectName: ':base:build-analyzer:common', projectPath: ''],
        [projectName: ':base:build-system:gradle-core', projectPath: ''],
        [projectName: ':base:build-system:gradle-kotlin', projectPath: ''],
        [projectName: ':base:build-system:gradle-dcl-ecosystem', projectPath: ''],
        [projectName: ':base:build-system:gradle-settings', projectPath: ''],
        [projectName: ':base:build-system:gradle-settings-api', projectPath: ''],
        [projectName: ':base:build-system:gradle-common-api', projectPath: ''],
        [projectName: ':base:build-system:aapt2', projectPath: ''],
        [projectName: ':base:build-system:aapt2-proto', projectPath: ''],
        [projectName: ':base:build-system:aaptcompiler', projectPath: ''],
        [projectName: ':base:build-system:docs', projectPath: ''],
        [projectName: ':base:build-system:integration-test', projectPath: ''],
        [projectName: ':base:build-system:integration-test:framework', projectPath: ''],
        [projectName: ':base:build-system:integration-test:api', projectPath: ''],
        [projectName: ':base:build-system:integration-test:application', projectPath: ''],
        [projectName: ':base:build-system:integration-test:connected', projectPath: ''],
        [projectName: ':base:build-system:integration-test:databinding', projectPath: ''],
        [projectName: ':base:build-system:integration-test:databinding:incremental', projectPath: ''],
        [projectName: ':base:build-system:integration-test:lint', projectPath: ''],
        [projectName: ':base:build-system:integration-test:managed-devices', projectPath: ''],
        [projectName: ':base:build-system:integration-test:native', projectPath: ''],
        [projectName: ':base:build-system:integration-test:utp', projectPath: ''],
        [projectName: ':base:build-system:builder-r8', projectPath: ''],
        [projectName: ':base:build-system:shrinker', projectPath: ''],
        [projectName: ':base:project-test-lib', projectPath: 'base/build-system/project-test-lib'],
        [projectName: ':base:project-test', projectPath: 'base/build-system/project-test'],
        [projectName: ':base:kotlin-multiplatform-models', projectPath: ''],
        [projectName: ':base:testing-infrastructure:device-pool:device-provider', projectPath: ''],
        [projectName: ':external:fat32lib', projectPath: ''],
        [projectName: ':data-binding', projectPath: ''],
        [projectName: ':base:utp', projectPath: ''],
        [projectName: ':base:utp:android-device-provider-ddmlib', projectPath: ''],
        [projectName: ':base:utp:android-device-provider-profile', projectPath: ''],
        [projectName: ':base:utp:android-test-plugin-host-additional-test-output', projectPath: ''],
        [projectName: ':base:utp:android-test-plugin-host-apk-installer', projectPath: ''],
        [projectName: ':base:utp:android-test-plugin-host-coverage', projectPath: ''],
        [projectName: ':base:utp:android-test-plugin-host-device-info', projectPath: ''],
        [projectName: ':base:utp:android-test-plugin-host-logcat', projectPath: ''],
        [projectName: ':base:utp:android-test-plugin-host-emulator-control', projectPath: ''],
        [projectName: ':base:utp:android-test-plugin-result-listener-gradle', projectPath: ''],
        [projectName: ':base:utp:utp-common', projectPath: ''],
        [projectName: ':base:perf-logger', projectPath: ''],
        [projectName: ':base:firebase:testlab:testlab-gradle-plugin', projectPath: ''],
        [projectName: ':base:compose-preview-detector', projectPath: 'base/multipreview-asm'],
        [projectName: ':base:preview:screenshot:screenshot-test-gradle-plugin', projectPath: ''],
        [projectName: ':base:preview:screenshot:screenshot-validation-api', projectPath: ''],
        [projectName: ':base:preview:screenshot:screenshot-validation-junit-engine', projectPath: ''],
        [projectName: ':base:backup-test:android-backup-runner', projectPath: ''],
        [projectName: ':base:backup-test:backup-junit-engine', projectPath: ''],
        [projectName: ':base:backup-test:backup-test-api', projectPath: ''],
]

/**
 * Gradle 9.0 requires directories for project to be explicitly created.
 */
projects.each { proj ->

    def finalPath
    // Check if projectPath is non-empty
    if (proj.projectPath) {
        finalPath = proj.projectPath
    } else {
        // If path is empty, derive it from the name.
        // ':base:journeys:journeys-junit-engine' -> 'base/journeys/journeys-junit-engine'
        finalPath = proj.projectName.substring(1).replace(':', '/')
    }

    // Define the project directory using the final path
    def projectDir = new File(settingsDir, finalPath)
    projectDir.mkdirs()
    include(proj.projectName)
    project(proj.projectName).projectDir = projectDir
}