build.gradle

plugins {
    id 'groovy-gradle-plugin'
    id 'idea'
    id 'maven-publish'
    id 'jvm-toolchains'
}

repositories {
    maven { url = "$rootDir/../../prebuilts/tools/common/m2/repository" }
}

String injectedMavenRepo = project.providers.gradleProperty('injectedMavenRepo').getOrNull()
if (injectedMavenRepo != null) {
    println("injected: $injectedMavenRepo")
    repositories {
        maven { url = injectedMavenRepo }
    }
}

buildDir = "../../out/build/buildSrc/build"

apply from: 'base/version.gradle'

dependencies {
    implementation gradleApi()
    implementation localGroovy()

    implementation libs.jarjar
    implementation libs.apache_commons_io
    implementation libs.guava
    implementation libs.gson
    implementation libs.protobuf_gradle_plugin
    implementation libs.apache_commons_lang
    implementation libs.jsoup
    implementation libs.kotlin_gradle_plugin

    testImplementation libs.junit
}

validatePlugins {
    getFailOnWarning().set(false)
}

// Make sure that we are compiling with a valid JDK. This can be overridden by setting the
// 'JAVA_FOR_TESTS' environment variable (to, e.g., '1.6')
task('checkJavaVersion').doLast {

    def requiredJdkVersion = JavaVersion.VERSION_17
    def javaForTests = System.getenv("JAVA_FOR_TESTS")
    if (javaForTests != null) {
        requiredJdkVersion = JavaVersion.toVersion(javaForTests)
    }

    def jvmVersion = JavaVersion.current()
    if (jvmVersion != requiredJdkVersion) {
        throw new RuntimeException("Tools need to be compiled with Java $requiredJdkVersion, you are using Java $jvmVersion.\nIf you are trying to open the project in IntelliJ, go to Settings and search for \"Gradle JVM\"")
    }
}

tasks.withType(ProcessResources) {
    // Gradle 7.0 requires specifying this explicitly, and this value is what pre 7.0 versions did
    duplicatesStrategy = DuplicatesStrategy.INCLUDE
}

assemble.dependsOn checkJavaVersion