compose/runtime/runtime/build.gradle

/*
 * Copyright 2019 The Android Open Source Project
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

/**
 * This file was created using the `createProject` gradle task (./gradlew createProject)
 *
 * Please use the task when creating a new project, rather than copying an existing project and
 * modifying its settings.
 */

import androidx.build.SoftwareType
import androidx.build.PlatformIdentifier
import com.android.build.api.dsl.KotlinMultiplatformAndroidHostTestCompilation
import org.jetbrains.kotlin.gradle.tasks.KotlinCompile

plugins {
    id("AndroidXPlugin")
    id("AndroidXComposePlugin")
}

androidXMultiplatform {
    androidLibrary {
        namespace = "androidx.compose.runtime"
        optimization {
            it.consumerKeepRules.publish = true
            it.consumerKeepRules.files.add(new File("proguard-rules.pro"))
        }
        compilations.withType(KotlinMultiplatformAndroidHostTestCompilation) {
            it.returnDefaultValues = true
        }
    }
    desktop()
    mingwX64()
    linux()
    mac()
    ios()
    tvos()
    watchos()
    js()
    wasmJs()

    defaultPlatform(PlatformIdentifier.ANDROID)

    sourceSets {
        commonMain.dependencies {
            api(libs.kotlinCoroutinesCore)
            api(project(":compose:runtime:runtime-annotation"))
            implementation("androidx.collection:collection:1.5.0")
        }

        commonTest.dependencies {
            implementation(libs.kotlinTest)
            implementation(libs.kotlinCoroutinesTest)
            implementation(libs.kotlinReflect)
            implementation(project(":compose:runtime:runtime-test-utils"))
        }

        create("nonEmulatorCommonTest").dependsOn(commonTest)
        create("nonEmulatorJvmTest").dependsOn(nonEmulatorCommonTest)

        androidMain.dependencies {
            api(libs.kotlinCoroutinesAndroid)
            api("androidx.annotation:annotation-experimental:1.4.1")
        }

        androidDeviceTest.dependencies {
            implementation(libs.testExtJunit)
            implementation(libs.testRules)
            implementation(libs.testRunner)
            implementation(libs.espressoCore)
            implementation(libs.truth)
        }

        androidHostTest.dependsOn(nonEmulatorJvmTest)

        create("nonAndroidMain").dependsOn(commonMain)
        create("nonAndroidTest").dependsOn(commonTest)

        desktopMain.dependsOn(nonAndroidMain)

        desktopTest {
            dependsOn(nonEmulatorJvmTest)
            dependsOn(nonAndroidTest)
        }

        nonJvmMain {
            dependsOn(nonAndroidMain)
            dependencies {
                implementation(libs.atomicFu)
            }
        }

        nativeMain.dependsOn(nonAndroidMain)

        nativeTest {
            dependsOn(nonAndroidTest)
            dependsOn(nonEmulatorCommonTest)
        }

        webTest.dependsOn(nonEmulatorCommonTest)

        wasmJsMain.dependencies {
            implementation(libs.kotlinXw3c)
        }
    }
}

dependencies {
    lintChecks(project(":compose:runtime:runtime-lint"))
    lintPublish(project(":compose:runtime:runtime-lint"))

    constraints {
        // Prevents symbols duplication with old versions of JetBrains' fork.
        // Starting with version 1.9.0, this module is published as empty artifact
        // with dependency to this androidx module.
        commonMainImplementation("org.jetbrains.compose.runtime:runtime:1.9.0") {
            because "prevents symbols duplication"
        }
    }
}

androidx {
    name = "Compose Runtime"
    type = SoftwareType.PUBLISHED_LIBRARY_ONLY_USED_BY_KOTLIN_CONSUMERS
    inceptionYear = "2019"
    description = "Tree composition support for code generated by the Compose compiler plugin and corresponding public API"
    samples(project(":compose:runtime:runtime:runtime-samples"))
}

// TODO(b/408516034): Workaround Kotlin incremental issue
tasks.withType(KotlinCompile).configureEach {
    incremental = false
}