| # Copyright 1999-2015 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI=5 |
| PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy ) |
| |
| inherit distutils-r1 flag-o-matic |
| |
| MY_PN=${PN/-/.} |
| MY_P=${MY_PN}-${PV} |
| |
| DESCRIPTION="Interfaces for Python" |
| HOMEPAGE="https://pypi.python.org/pypi/zope.interface" |
| SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz" |
| |
| LICENSE="ZPL" |
| SLOT="0" |
| KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris" |
| IUSE="" |
| |
| DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]" |
| RDEPEND="" |
| |
| S=${WORKDIR}/${MY_P} |
| |
| # until all deps are in the tree (bug #442794) |
| RESTRICT="test" |
| |
| python_compile() { |
| if ! python_is_python3; then |
| local CFLAGS="${CFLAGS}" CXXFLAGS="${CXXFLAGS}" |
| append-flags -fno-strict-aliasing |
| fi |
| |
| distutils-r1_python_compile |
| } |
| |
| python_test() { |
| esetup.py test |
| } |
