| # Copyright 1999-2015 Gentoo Foundation |
| # Distributed under the terms of the GNU General Public License v2 |
| # $Id$ |
| |
| EAPI=5 |
| PYTHON_COMPAT=( python{2_7,3_3,3_4} pypy ) |
| |
| inherit distutils-r1 |
| |
| DESCRIPTION="Replace real objects with fakes (mocks, stubs, etc) while testing" |
| HOMEPAGE="http://farmdev.com/projects/fudge/ https://pypi.python.org/pypi/fudge" |
| SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz" |
| |
| LICENSE="MIT" |
| SLOT="0" |
| KEYWORDS="amd64 x86" |
| IUSE="doc test" |
| |
| RDEPEND="" |
| DEPEND="dev-python/setuptools[${PYTHON_USEDEP}] |
| doc? ( dev-python/sphinx[${PYTHON_USEDEP}] ) |
| test? ( dev-python/nose[${PYTHON_USEDEP}] )" |
| |
| python_prepare_all() { |
| find -name "._*" -delete || die |
| distutils-r1_python_prepare_all |
| } |
| |
| python_compile_all() { |
| use doc && emake -C docs html |
| } |
| |
| python_test() { |
| nosetests -w "${BUILD_DIR}"/lib \ |
| || die "Tests fail with ${EPYTHON}" |
| } |
| |
| python_install_all() { |
| use doc && local HTML_DOCS=( docs/_build/html/. ) |
| distutils-r1_python_install_all |
| } |