// Copyright (C) 2020 The Android Open Source Project
//
// Licensed under the Apache License, Version 2.0 (the "License");
// you may not use this file except in compliance with the License.
// You may obtain a copy of the License at
//
//      http://www.apache.org/licenses/LICENSE-2.0
//
// Unless required by applicable law or agreed to in writing, software
// distributed under the License is distributed on an "AS IS" BASIS,
// WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
// See the License for the specific language governing permissions and
// limitations under the License.

cpuinfo_arm_common_src_files = [
    "src/arm/uarch.c",
    "src/arm/cache.c",
    "src/arm/linux/init.c",
    "src/arm/linux/cpuinfo.c",
    "src/arm/linux/clusters.c",
    "src/arm/linux/chipset.c",
    "src/arm/linux/midr.c",
    "src/arm/linux/hwcap.c",
    "src/arm/android/properties.c",
]

cpuinfo_x86_common_src_files = [
    "src/x86/init.c",
    "src/x86/info.c",
    "src/x86/name.c",
    "src/x86/isa.c",
    "src/x86/vendor.c",
    "src/x86/uarch.c",
    "src/x86/topology.c",
    "src/x86/cache/init.c",
    "src/x86/cache/descriptor.c",
    "src/x86/cache/deterministic.c",
    "src/x86/linux/cpuinfo.c",
    "src/x86/linux/init.c",
]

cc_library_static {
    name: "libcpuinfo",
    export_include_dirs: ["include"],
    vendor_available: true,
    sdk_version: "current",
    local_include_dirs: [
        "src",
    ],
    srcs: [
        "src/init.c",
        "src/api.c",
        "src/cache.c",
        "src/linux/current.c",
        "src/linux/processors.c",
        "src/linux/smallfile.c",
        "src/linux/multiline.c",
        "src/linux/cpulist.c",
    ],
    arch: {
        arm: {
            srcs: cpuinfo_arm_common_src_files + [
                "src/arm/linux/aarch32-isa.c",
            ],
            cflags: [
                "-march=armv7-a",
            ],
       },
        arm64: {
            srcs: cpuinfo_arm_common_src_files + [
                "src/arm/linux/aarch64-isa.c",
            ],
        },
        x86: {
            srcs: cpuinfo_x86_common_src_files,
        },
        x86_64: {
            srcs: cpuinfo_x86_common_src_files,
        },
    },
    cflags: [
        "-std=c99",
        "-Oz",
        "-D_GNU_SOURCE=1",
        "-Wno-unused-function",
        "-Wno-unused-parameter",
        "-Wno-missing-field-initializers",
    ],
    whole_static_libs: [
        "libclog",
    ],
}