mojo/examples/surfaces_app/BUILD.gn

# Copyright 2014 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

group("surfaces_app") {
  deps = [
    ":child_app",
    ":child_gl_app",
    ":parent_app",
  ]
}

# GYP version: mojo/mojo_examples.gypi:mojo_surfaces_app
shared_library("parent_app") {
  output_name = "mojo_surfaces_app"

  deps = [
    ":bindings",
    ":util",
    "//base",
    "//cc",
    "//cc/surfaces",
    "//skia",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//mojo/application",
    "//mojo/common",
    "//mojo/environment:chromium",
    "//mojo/public/c/system:for_shared_library",
    "//mojo/services/public/interfaces/geometry",
    "//mojo/services/public/cpp/geometry",
    "//mojo/services/public/interfaces/surfaces",
    "//mojo/services/public/cpp/surfaces",
  ]

  sources = [
    "embedder.cc",
    "embedder.h",
    "surfaces_app.cc",
  ]
}


# GYP version: mojo/mojo_examples.gypi:mojo_surfaces_child_app
shared_library("child_app") {
  output_name = "mojo_surfaces_child_app"

  deps = [
    ":bindings",
    ":util",
    "//base",
    "//cc",
    "//cc/surfaces",
    "//skia",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//mojo/application",
    "//mojo/common",
    "//mojo/environment:chromium",
    "//mojo/public/c/system:for_shared_library",
    "//mojo/services/public/interfaces/geometry",
    "//mojo/services/public/cpp/geometry",
    "//mojo/services/public/interfaces/surfaces",
    "//mojo/services/public/cpp/surfaces",
  ]

  sources = [
    "child_app.cc",
    "child_impl.cc",
    "child_impl.h",
  ]
}

# GYP version: mojo/mojo_examples.gypi:mojo_surfaces_child_gl_app
shared_library("child_gl_app") {
  output_name = "mojo_surfaces_child_gl_app"

  deps = [
    ":bindings",
    ":util",
    "//base",
    "//cc",
    "//cc/surfaces",
    "//skia",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//mojo/common",
    "//mojo/application",
    "//mojo/environment:chromium",
    "//mojo/examples/sample_app:spinning_cube",
    "//mojo/public/c/system:for_shared_library",
    "//mojo/public/gles2:for_shared_library",
    "//mojo/services/public/interfaces/geometry",
    "//mojo/services/public/cpp/geometry",
    "//mojo/services/public/interfaces/surfaces",
    "//mojo/services/public/cpp/surfaces",
  ]

  sources = [
    "child_gl_app.cc",
    "child_gl_impl.cc",
    "child_gl_impl.h",
  ]
}

source_set("util") {
  deps = [
    "//cc",
    "//skia",
  ]

  sources = [
    "surfaces_util.cc",
    "surfaces_util.h",
  ]
}

# GYP version: mojo/mojo_examples.gypi:mojo_surfaces_app_bindings
mojom("bindings") {
  deps = [
    "//mojo/services/public/interfaces/geometry",
    "//mojo/services/public/interfaces/surfaces",
  ]

  sources = [ "child.mojom" ]
}